[stuff] windows fenster --> größenverstell- und dragbar

[salazar]

hola,

hab hier noch dieses windows fenster like änliche teil gefunden. hab es mal ein bissal aufbereitet und teilweise dokumentiert. ist eigentlich ganz praktisch und vielseitig einsetzbar. diverse einstellungen wie farbe, größe etc können vorgenommen werden. das teil ist natürlich erweiterbar und noch lange nicht perfekt... habe auch ein paar features wieder rausgenommen die mir nicht so gefallen haben. für meine zwecke (im moment) hats gereicht. das teil kommt so änlich auch in der trace station zum einsatz und die ist ja schon was älter

fla und swf gibts unten zum saugen

PHP-Code:

//---------------------------------------------------

fscommand("allowscale", false);
fscommand("showMenu", false);

//---------------------------------------------------

stop();

//---------------------------------------------------

var _my = this;

//---------------------------------------------------

_my.initwindow = function(){
    
    //einstellungen
    _my.wsize = 500;//ausgangsgröße breite
    _my.hsize = 250;//ausgangsgröße höhe
    _my.mws = 250;//minimale fensterbreite
    _my.mhs = 90;//minimale fensterhöhe
    _my.maws = 650;//maximale fensterbreite
    _my.mahs = 500;//maximale fensterhöhe
    _my.bordercl = 0x666666;//fensterfarbe 
    _my.txtbgcl = 0xffffff;//fenster bg farbe 
    //---
    
    var setcl = function(){
        with(_my.mytr){
            var mytr_drag_cl = new Color(mytr_drag);
            var mytr_tools_cl = new Color(mytr_tools);
            var mytr_left_cl = new Color(mytr_left);
            var mytr_right_cl = new Color(mytr_right);
            var mytr_down_cl = new Color(mytr_down);
            var mytr_textbg_cl = new Color(mytr_textbg);
            mytr_drag_cl.setRGB(_my.bordercl);
            mytr_tools_cl.setRGB(_my.bordercl);
            mytr_left_cl.setRGB(_my.bordercl);
            mytr_right_cl.setRGB(_my.bordercl);
            mytr_down_cl.setRGB(_my.bordercl);
            mytr_textbg_cl.setRGB(_my.txtbgcl);
        }
    }
    
    var setmcs = function(){
        //platziert mcs
        _my.setsz(_my.wsize, _my.hsize);
        //---
        //init bts
        _my.mytr.mytr_drag.onPress = function(){
            this._parent.startDrag();
            //this._parent.startDrag(_my._x, 0, 600, 400)
        }
        _my.mytr.mytr_drag.onRelease = _my.mytr.mytr_drag.onReleaseOutside = function(){
            _my.stopDrag();
            _my._x = int(_my._x);
            _my._y = int(_my._y);
        }
        //---------------
        //horizontal
        _my.mytr.mytr_right.onPress = function(){
            _my.onMouseMove = function() {
                if(_my._xmouse > _my.mws && _my._xmouse <  _my.maws){
                    _my.mytr.mytr_right._x = _my._xmouse;
                    _my.setsz(_my.mytr.mytr_right._x, _my.mytr._height)
                }
            }
        }
        _my.mytr.mytr_right.onRelease = _my.mytr.mytr_right.onReleaseOutside = function(){
            delete _my.onMouseMove;
        }
        //---------------
        //vertikal
        _my.mytr.mytr_down.onPress = function(){
            _my.onMouseMove = function() {
                if(_my._ymouse > _my.mhs && _my._ymouse < _my.mahs){
                    _my.mytr.mytr_down._y = _my._ymouse;
                    _my.setsz(_my.mytr._width, _my.mytr.mytr_down._y)
                }
            }
        }
        _my.mytr.mytr_down.onRelease = _my.mytr.mytr_down.onReleaseOutside = function(){
            delete _my.onMouseMove;
        }
        //---------------
        //horizontal & vertikal
        _my.mytr.mytr_rsize.onPress = function(){
            _my.onMouseMove = function() {
                if(_my._xmouse > _my.mws && _my._xmouse <  _my.maws){
                    _my.mytr.mytr_right._x = _my._xmouse;
                    _my.setsz(_my.mytr.mytr_right._x, _my.mytr._height);
                }
                if(_my._ymouse > _my.mhs && _my._ymouse < _my.mahs){
                    _my.mytr.mytr_down._y = _my._ymouse;
                    _my.setsz(_my.mytr._width, _my.mytr.mytr_down._y);
                }
            }
        }
        _my.mytr.mytr_rsize.onRelease = _my.mytr.mytr_rsize.onReleaseOutside = function(){
            delete _my.onMouseMove;
        }
        //---------------
        _my.mytr.mytr_barbts.mytr_btmin.onPress = function(){
            _my.setsz(_my.mws, _my.mhs);
        }
        //---------------
        _my.mytr.mytr_barbts.mytr_btmax.onPress = function(){
            _my.setsz(_my.maws, _my.mahs);
        }
        //---------------
    }
    
    setcl();
    setmcs();
}

//---------------------------------------------------

_my.setsz = function(_xpos, _ypos){
    with(_my.mytr){
        mytr_drag._width = int(_xpos);
        mytr_tools._width = mytr_drag._width;
        mytr_down._width = mytr_tools._width;
        mytr_right._x = int((mytr_drag._x + mytr_drag._width) - mytr_right._width);
        mytr_left._height = int(_ypos - (mytr_drag._height + mytr_tools._height));
        mytr_right._height = mytr_left._height;
        mytr_tools._y = int(mytr_left._y + mytr_left._height);
        mytr_down._y = int((mytr_tools._y + mytr_tools._height) - mytr_down._height);
        mytr_textbg._width = int(mytr_right._x - mytr_right._width);
        mytr_textbg._height = int(mytr_tools._y - mytr_drag._height);
        mytr_barbts._x = int((mytr_drag._x + mytr_drag._width) - (mytr_right._width + mytr_barbts._width));
        mytr_rsize._x = int((mytr_tools._x + mytr_drag._width) - (mytr_rsize._width));
        mytr_rsize._y = int((mytr_tools._y + mytr_tools._height) - (mytr_rsize._height));
    }
}

//---------------------------------------------------

_my.initwindow();

//--------------------------------------------------- 


viel spaß damit für die, die es gebrauchen können

cya, sal

hi also an sich ist die sache cool und auch schön verwirklicht usw. aber ich hätte mal zwei verbesserungsvorschläge und zwar also erstes geht es um die tatsache das wenn man das fenster vergrößert bzw. verkleinert die maus hoch bzw. zur seite oda so springt das heißt sie bleibt nicht an der stelle wo sie sein sollte, da ich allerdings keine idee habe woran das liegen könnte würde ich mal sagen das hier viele leute in forum mehr als ich drauf haben und das sicher beheben können soa dann kommen wir mal zum zweiten punkt meiner verbesserung ich finde du könntest wenigstens die maus verändern wenn man an den rand kommt wie bei einen windows fenster halt zu so einen doppelpfeil und zwar hab ich da was kleines geschrieben :

also als erstes brauchst du in diesem fall für den feil der nach unten vergrößert ein mc mit 2 frames im ersten frame ist nix nur ein stop(); und im zweiten ist der pfeil und wieder ein stop(); soa dann zihst du den mc auf die hauptfläche und wie du siehst siehst du ihn nicht naja jetzt wirds weiter jetzt nur noch eine instance für den mc vergeben (down_arrow) jetzt brauch man nur noch das hier einfügen

down_arrow.StartDrag(true);
        
        _my.mytr.mytr_down.onRollOver = function(){
            _root.down_arrow.gotoAndStop(2);
            mouse.hide();
        }
        _my.mytr.mytr_down.onRollOut = function(){
            _root.down_arrow.gotoAndStop(1);
            mouse.show();
        }
        _my.mytr.mytr_down.onRelease = function(){
            _root.down_arrow.gotoAndStop(1);
            mouse.show();
        } 

aber ohne die verbesserung eins wird der sich nicht zurückverändern des wegen ist verbesserung eins sehr wichtig also wenn das alles geschafft ist ist das ein fast ideales fenster

ich entschuldige mcih hier mal für meine schlechtes deutsch -,- und die groß und klein schreibung

psyko

[salazar]

dann verbesser mal
ich finde das mit der maus (mauszeiger wechseln) als idee okay, aber ich habs so nicht gebraucht und steh auch nicht so drauf. hier und da kommt das etwas 0850 . und fehler nr1 wie du ihn bezeichnest ist auch nicht wild zu beheben und hat mich auch nicht gestört. wie gesagt. das ist hier eine grundversion. in einer weiterentwickelten version von mir die auch ein textfeld mit scrollbar etc enthält ist der fehler übrigens gefixt... ein perfekt funktionierendes teil und auf die jeweiligen bedürnisse (z.B. deine)zugeschnitten wirds so nicht geben... das ist ja keine dienstleistung hier. wenn du also einen wechseldenen mauszeiger wilst dann bau dieses feature doch einfach ein anstatt deinen as schnipsel zu posten, denn wie das funktioniert brauchste mir nicht zu zeigen (zudem scheinste das mit dem _my nicht ganz kapiert zu haben... siehe das _root)... und wenn du das dann eingebaut hast kommste vielleicht auch drauf wieso der effekt mit der versetzten maus zu stande kommt. und falls nicht dann kannste ja einfach nochmal fragen, denn so funktioniert das hier im ff

cya, sal

[deeennis]

Hi!
Hab dazu mal ne Frage!
Was muss ich jetzt noch hinzufügen, damit das Fenster bei Klick auf X (Close) auch wirklich schließt?

[Der Frager]

Das hier:

_my.mytr.mytr_barbts.mytr_btclose.onRelease = function() {
    unloadMovie(_my);
    //oder
    unloadMovie(_my.mytr);
}; 

[deeennis]

ha! was wär ich ohne dich^^
Du hast mir von meinen tausend fragen so ziemlich alle beantwortet!
Danke