[stuff] setClipInFreeLevel

[< priZma >]

Da ich öfters mit MovieClip Level setzen probleme habe habe ich mir eine simple Lösung überlegt, die das
zumindest bei createEmptyMovieClip umgeht.
Da ich hier im Forum noch nichts ähnliches gefunden habe poste ich mal den prototype.

Vieleicht kann ihn der ein oder andere ja gebrauchen.

MovieClip.prototype.setClipInFreeLevel = function (name) {
    this.level = 0;
    for (var info in this) {
        if (typeof this[info] == "movieclip") {
            this.level++;
        }
    }
    this.createEmptyMovieClip (name, this.level + 1);
};
 
// Test
this.setClipInFreeLevel ("a");
this.setClipInFreeLevel ("b");
this.setClipInFreeLevel ("c");
this.setClipInFreeLevel ("d");
this.setClipInFreeLevel ("e");
this.setClipInFreeLevel ("f");
this.setClipInFreeLevel ("g");
this.setClipInFreeLevel ("h");
//
for (var info in this) {
    if (typeof this[info] == "movieclip") {
        trace (this[info]);
    }
} 

schönen Sonntag noch.
.priZma

[tumetom]

hm...

MovieClip.prototype.setClipInFreeLevel = function (name) {
        this.level = 0;
        for (var info in this) {
                if (typeof this[info] == "movieclip") {
                        this.level++;
                }
        }
        this.createEmptyMovieClip (name, this.level + 1);
};
 
// Test
this.setClipInFreeLevel ("a");
this.setClipInFreeLevel ("b");
this.setClipInFreeLevel ("c");
this.setClipInFreeLevel ("d");
this.setClipInFreeLevel ("e");
//!!!!
this.c.removeMovieClip()
 
//
this.setClipInFreeLevel ("f");
this.setClipInFreeLevel ("g");
this.setClipInFreeLevel ("h");
//
 
 
for (var info in this) {
        if (typeof this[info] == "movieclip") {
                trace (this[info]);
        }
} 

Probier das mal aus.


du zählst die anzahl von MovieClips. du vergisst dabei, aber 2 wichtige dinge..

1. behält ein MovieClip seine Tiefe, auch wenn ein Mc vor ihm gelöscht wird,
seine tiefe kann nur per swapDepths geändert werden.


2. Die Tiefe von den MovieClips muss nicht vortlaufend sein...


das heißt wenn du auf

1,2,3,4,5 die mcs a,b,c,d,e liegen hast, und du löscht c, dann liegen a,b,d,e, auf 1,2,4,5 und nicht auf 1,2,3,4


das heißt dass dein script dem nächsten MOvieClip die tiefe 5 geben wird, und damit den e ersetzen wird.






Hast du dir schon überlegt, bei dem erstellen eines mcs, seine aktuelle tiefe in den neuen mc zu legen, und dann immer nach freien plätzen zu suchen??

MovieClip.prototype.getLevelList = function() {
    var result = [];
    for (var i in this) {
        if (typeof this[i] == "movieclip") {
            result[this[i].depths] = this[i].depths;
        }
    }
    return result.length == 0 ? [0] : result;
};
MovieClip.prototype.getGap = function(result, startIndex) {
    startIndex = (startindex == null) ? 0 : startIndex;
    var re = false;
    for (var i = startIndex+1; i<result.length; i++) {
        if (result[i] == null) {
            return i;
        }
    }
    return result.pop()+1;
};
var org = MovieClip.prototype.createEmptyMovieClip;
MovieClip.prototype.createEmptyMovieClip = function(name, depths) {
    var result = arguments.callee.org.apply(this, arguments);
    result.depths = depths;
    return result;
};
MovieClip.prototype.createEmptyMovieClip.org = org;
delete org;
 
 
this.createEmptyMovieClip("a", this.getGap(this.getLevelList()));
this.createEmptyMovieClip("b", this.getGap(this.getLevelList()));
this.createEmptyMovieClip("c", this.getGap(this.getLevelList()));
this.createEmptyMovieClip("d", this.getGap(this.getLevelList()));
this.c.removeMovieClip();
this.createEmptyMovieClip("f", this.getGap(this.getLevelList())); // belegt die frei gewordene stelle von c
this.createEmptyMovieClip("g", this.getGap(this.getLevelList()));  // ans ende
this.b.removeMovieClip();
this.d.removeMovieClip();
this.createEmptyMovieClip("h", this.getGap(this.getLevelList(),3));//  wird frühestens an stelle 3 angelegt 
 

Schnell ist das ganze natürlich nicht