[stuff] SelectManager

[atothek]

hab mal heute nen kleinen SelectManager gebastellt.
mit multi und single select

PHP-Code:

/**
* @class        SelectManager
* @version        0.1
* @author        Alex Kämmerer (alex@gengon.de)
* 
* @build          31.10.2004
* @update         31.10.2004
* @released     31.10.2004

* @return         Void
* @access        public
*
* @desc            Creates a SelectManager Object.
* 
* @history        31.10.2004    starting propgamming
*/
class de.gengon.fgui.manager.SelectManager{
    
    /** stores all registered elements */
    private var _elements : Array;
    
    /** stores a singleselect selected object or null */
    private var _selectedItem : Object = null;
    
    /** stores all selected objects */
    private var _selectedItems : Array;
    
    /** stores if manager worx in single or multiselect mode */
    private var _singleSelect : Boolean = true;
    
    /** stores if manager automaticly deselect the selected item in single select mode */
    private var _autoDeselect : Boolean = true;
    
    /**
    * constructor creates a new SelectManager object
    */
    public function SelectManager(){
        _elements = new Array();
        _selectedItems = new Array();
    }
    
    /** 
    * adds the specific element to the 
    * elements array if not exists
    * 
    * @param    element : Object
    */
    public function addElement(element : Object) : Void {
        
        if(exists(_elements, element) == -1){
            _elements.push(element);
            element.setSelectManager(this);            
        }
    }
    
    /** 
    * removes the specific element from the 
    * elements array if exists
    * 
    * @param    element : Object
    */
    public function removeElement(element : Object) : Void {
        
        var i : Number = exists(_elements, element);        
        if(i > -1){
            _elements.splice(i, 1);
            element.setSelectManager(null);
        }
    }
    
    /**
    * resets the selectManager
    */
    public function reset():Void{
        _elements = new Array();
    }
    
    
    /** setter and getter */
    public function setAutoDeselect(b : Boolean) : Void{
        _autoDeselect = b;
    }

    public function getAutoDeselect() : Boolean{
        return _autoDeselect;
    }
    
    public function setSingleSelect(b : Boolean) : Void{
        _singleSelect = b;
    }
    
    public function getSingleSelect() : Boolean{
        return _singleSelect;
    }
    /** end getter and setter */
    
    /**
    * cleares all selected items
    */
    public function clearSelected() : Void{
        if(_singleSelect)
            _selectedItem.onDeselect();
        else{
            for(var i = _selectedItems.length - 1; i >= 0; i--){
                _selectedItems[i].onDeselect();
                _selectedItems.splice(i, 1);
            }
        }
    }
    
    /**
    * setts the specified object 
    * to selected oder deselcted by invoking
    * the events onSelect or onDeselect
    * 
    * @param    o : Object
    */
    public function setSelected(o : Object) : Void{
        if(_singleSelect){            
            if(_selectedItem == null){
                _selectedItem = o;
                _selectedItem.onSelect();
            }else if(_autoDeselect && _selectedItem != null){
                if(_selectedItem == o){
                    _selectedItem.onDeselect();
                    _selectedItem = null;
                }else if(_selectedItem != o){                    
                    _selectedItem.onDeselect();
                    _selectedItem = o;
                    _selectedItem.onSelect();
                }
            }else if(!_autoDeselect && _selectedItem == o){
                _selectedItem.onDeselect();
                _selectedItem = null;
            }
        }else{            
            if(exists(_selectedItems, o) == -1){
                addObject(o);
                o.onSelect();                
            }else{
                removeObject(o);                
                o.onDeselect();
            }
        }
    }
    
    /**
    * if singleselect mode is used returns the single
    * selected item else returns a array with all selected items
    * in the selected order
    * 
    * @return     Object
    */
    public function getSelected() : Object{
        if(_singleSelect)
            return _selectedItem;
        else
            return _selectedItems;
    }
    
    /**
    * checks if the specified object o is
    * part of the array arr
    * 
    * @param    arr : Array
    * @param    o : Object
    * 
    * @return     Number
    */
    private function exists(arr : Array, o : Object) : Number{
        for(var i = arr.length - 1; i >= 0; i--)
            if(arr[i] === o)
                return i;
        return -1;
    }

    /**
    * adds the object to 
    * the array with selected objects
    * 
    * @param    o : Object
    */
    private function addObject(o : Object) : Void{
        if(exists(_selectedItems, o) == -1)
            _selectedItems.push(o);
    }
    
    /**
    * removes the object from
    * the array with selected objects
    * 
    * @param    o : Object
    */
    private function removeObject(o : Object) : Void{
        
        var i : Number = exists(_selectedItems, o);        
        if(i > -1)
            _selectedItems.splice(i, 1);
    }
} 


zum anwenden einfach nen kleinen mc machen 100x20 und verknüpfen mit clip als namen nun noch folgendes script und schon ist alles easy .

PHP-Code:


import de.gengon.fgui.manager.SelectManager;

/* neuer SelectManager */
var sm : SelectManager = new SelectManager();

/* für multiselect einfach false setzen */
sm.setSingleSelect(true);

/* erklärt sich selbst */
sm.setAutoDeselect(false);

init = function(){
    
    for(var i=0; i<5; i++){
        
        var mc = this.attachMovie("clip", "mc"+i, i);
        mc._x = 50 + (mc._width + 5) * i; 
        mc._y = 50;        
        mc.onRelease = function(){
            sm.setSelected(this);
        }
        /* event wenn ausgewählt */
        mc.onSelect = function(){
            var c = new Color(this);
            c.setRGB(0x00FF00);
        }
        /* event wenn abgewählt */
        mc.onDeselect = function(){
            var c = new Color(this);
            c.setRGB(0xFF0000);
        }
        /* anmelden beim manager */
        sm.addElement(mc);
    }
}

init(); 


Kritik, anregung und/oder Lob sind gern gesehen .

mfg
alex

[bokel]

Ich finds ganz gut. Folgendes ist mir aufgefallen:
1. Anstatt des s für Vielzahl würde ich List anhängen, das macht deutlicher, dass es eine Liste ist, also z.B. _elementList anstatt _elements
2. Die Typisierung mit Object solltest du weglassen, kaneda hat das mal analysiert, Flash macht da u.U. Probleme.
3. Die Elemente scheinen ein Interface (onSelect, onDeselect, setSelectManager) zu haben, das würde ich explizit machen
4. exists würde ich eher find nennen, von exists würde ich Boolean erwarten
5. Die Verwaltung des/der selektierten Objekte würde ich auslagern. Du könntest vielleicht zwei Klassen SingleSelection und MultipleSelection dafür benutzen, die dann vom Manager je nach Bedarf benutzt werden können.
6. Die ElementListe könnte man vielleicht zusaetzlich noch als abstrakten Datentyp auskoppeln, den man dann an anderer Stelle auch noch benutzen kann.
7. Die Logik in setSelected ist mir zu komplex. Das äußere if würde schon durch die Delegation von setSelected an SingleSelection/MultipleSelection verschwinden. Aber zusaetzlich würde ich setSelected noch in select und deselect aufteilen.

mfg r.

[atothek]

@bokel vielen dank für die klasse kritik hab mich auch dieser gerne angenommen und habe vieles davon umgesetzt. Freut mich mal eine so ausführliche beurteilung zu bekommen, da kann man ja nur lernen. Find auch alle punkte passend .

Anbei nun mal eine umsetzung des ganzen mit einer kleinen demo Anwendung

mfg
alex

[michael]

klasse, ein ganz tolles OOP-Lehrstück an dem man viel lernen kann.

zwei kleine frage kommen mir beim überfliegen auf die schnelle:

public function SelectManager(type : String){
        
        _type = type == undefined ? "single" : type;
        
        if(_type == undefined || _type == "single")
            _selection = new SingleSelection();
        else if(_type == "multi")
            _selection = new MultipleSelection();      
    } 

warum fragst du _type == undefined ab wenn du es vorher ausgeschlossen hast?

warum ist AbstractSelection eine klasse und kein interface?

was übersehe ich?


gruß
michael

[MiM]

Was passiert wenn type weder 'singel' noch 'multi' entspricht? Dann würde sich die Klasse in einem nicht erlaubtem Zustand befinden, da _selection undefined wäre.

Ich würde den Typ nicht als String sonder als Number übergeben. Die geeignete Nummer erhält man über Konstanten in der Klasse SelectManager. Bei Strings kann es leicht zu Fehlern bei der Eingabe kommen.

PHP-Code:

class de.gengon.manager.SelectManager{
  public static var TYPE_SINGLE:Number = 0;
  public static var TYPE_MULTI:Number = 1;
  .. 


AbstractSelection würde ich auch zu einem Interface machen, da es ja keinen auszuführenden Programmcode enthält und nur vorschreibt, welche Methoden implementiert werden sollen (und dies wird im jetzigen Fall auch nicht vom Compiler erzwungen wird).
Falls es dennoch eine abstrakte Klassen bleiben soll, würde ich zumindest in jeder Methode die überschrieben werden soll, eine AbstractOperationException werfen, damit wenigstens zur Laufzeit erkannt wird, das man vergessen hat eine Methode zu implementieren.

Der Name des Interfaces ISelectManager verwirrt mich ein wenig. Ich würde daraus schließen, dass dieses Interface vom SelectManger implementiert werden sollte und nicht vom SelectItem.

Ansonsten schöne Sache.

Gruß
Simon

[atothek]

@gutknut thx
das mit dem doppelten prüfen ist einer der klassiker, code proggen und nächsten tag überarbeiten und dabei übersehen danke für den Hinweis, has natürlich korrigiert. Die AbstractSelection ist nun das Interface Selection, hab verpeilt das man auf ein Interface Typesieren kann deshalb wars eine klasse. zudem eine kleine ergänzung im interface ISelectManager und im SelectManager wenn schon vorher ein mc per default selektiert ist wird dies nun auch erkannt.

mfg
alex

Edit:
@MiM haben wohl gleichzeitig gepostet
das mit dem Namen des interfaces ist wirklich verwirrend aber Selectable ist in dem fall auch nicht wirklich passend Managerable ist auch komisch hast du vielleicht eine Idee?

Das mit den Konstanten ist ne Gute Idee werde ich mal mit einbauen.

[bokel]

Warum Nummern, wenn man gleich eine ganze Klasse nehmen kann

class SelectionType {
       static var SINGLE:SelectionType = new SelectionType("single", 1);
       static var MULTIPLE:SelectionType = new SelectionType("multiple", 2);
 
       private var name:String;
       private var value:Number;
 
       private function SelectionType( name:String, value:Number){
              this.name = name;
              this.value = value;
       }  
 
       function getName(){
            return this.name
       }
 
       function getValue(){
            return this.value
       }
} 

Der Vorteil ist, dass der Compiler Typsicherheit herstellt.

Wg. des Konstruktors:
Normalerweise halte ich meine Konstruktoren immer so einfach wie möglich. So wie du es jetzt gemacht hast, legt es eigentlich nahe, zwei verschiedene ManagerKlassen zu schreiben, eine für Single und eine für Multi und vielleicht eine gemeinsame Oberklasse und ein ManagerInterface. Ich habe mich dann aber gefragt, was es letzlich in der Anwendung bedeutet. Wenn mein Manager ein IManager ist, dann muesste ich für die erweiterten Eigenschaften meines Managers immer casten. Dann ist es so vielleicht doch so besser, also dass der Manager praktisch zwei Klassen in sich vereint. Trotzdem würde ich das Auswerten des Typs in eine extra Routine packen.

mfg. r

[atothek]

so hab mich nun dafür entschieden das Interface Selectable zu nennen was noch am passendsten ist. habe auch die Konstanten eingebaut.
@bokel steh gerade auf dem schlauch und komm nicht ganz hinterher .

hab den 2. download aktualisiert damit es nicht zu viel wird ^^

mfg
alex

[bokel]

Oh sorry,
mit der Klasse SelectionType kannst du die Konstanten definieren. Dann kann dir nicht jemand eine falsche Nummer unterschieben. (Na ja, null und undefined würden immer noch durchgehen, so viel bringt es also nicht )

Im zweiten Absatz habe ich nur laut gedacht. Es scheint ja so zu sein, dass der SelectManager nur im Konstruktor initialisiert wird und dass der Typ dann nicht mehr geändert wird. Deshalb habe ich mich gefragt, was passiert wenn man gleich zwei verschiedene SelectManager definiert, einen für single- und einen für multi-select.

mfg .r

[mogli0815]

Hallo,
@bokel: gibt es dazu einen thread bzw. was ist das problem?

2. Die Typisierung mit Object solltest du weglassen, kaneda hat das mal analysiert, Flash macht da u.U. Probleme.

lg
mOgli

[MiM]

Wir haben darüber auf dem as2lib Weblog gepostet: :Object is Evil.
Die Typprobleme treten beim Gebrauch von Interfaces auf, weil diese laut Compiler nicht vom Typ Object seien.

[atothek]

Is zwar schon etwas älter hatte aber ne kleine ergänzung gemacht
und zwar CountableSelection fehlte noch

mann kann angeben wieviele elemente wählbar sind.
zudem ist das ganze nu in eine neue herachie gewandert und ne kleine Doc
mit dabei probier mich gerade an as2api

mfg
alex