[STUFF] Sehr einfacher Bilderwechsel

[gaspode]

Hallo.

Und wo wir schon gerade dabei sind,
hier noch ein Bilderwechsel in AS2.

Dieser verwendet die AS2-Tweener-
Klasse. Über eine txt-Datei lassen
sich die Anzahl der Bilder und die
Anzeige- und Übergangszeit steuern.

gruß, gaspode

[DISO]

Hallo gaspode,

also ich habe mal die standardeinstellungen nach dem öffen beibehalten (wie unten zu sehen) und es nach dem öffnen gespeichert und direkt veröffentlicht.

Leider läuft nach dieser Aktion der Film nicht mehr



Was mache ich Falsch?

[gaspode]

Hast Du die Tweener-Klasse mit runtergeladen?

gruß, gaspode

[DISO]

ich denke nicht nein.
kannst du mir einen Link posten wo ich diese herunterladen kann?

und wo beschreiben ist wo diese dann unterzubringen ist.

importiert wird sie ja durch

import flash.external.*;
import caurina.transitions.Tweener;

http://code.google.com/p/tweener/
welche ist es dort?zu as2 hat es ja mehrere?

[gaspode]

Die hier sollte gehen.

http://tweener.googlecode.com/files/..._31_74_as2.zip

gruß, gaspode

[DISO]

ok die entpacke ich genau in dem verz in dem auch die swf und fla etc liegen oder?
sorry für die fragen, flash mache ich 1mal im jahr.

oder wie funkt das genau?

[RustyCake]

Genau

[DISO]

stark leute.vielen dank jetzt funktioniert es.


//als nachtrag evtl noch folgendes:
vielleicht kannst du dein ZIP File ja um die Klasse noch erweitern, dann haben andere nicht die selben probleme wie ich sie hatte.ansonsten tolle arbeit, kein zweifel

[DISO]

Hallo,

ich muß das Thema nun leider doch noch einmal nutzen.
Ich habe deine Gallery an meine Bedürfnisse angepasst und veröffentlicht.
Jetzt habe ich diese in meinem Typo3 Projekt eingefügt und dort läuft diese dann leider nicht mehr.

Wenn ich die swf aber über die komplette Adresse aufrufe dann funtioniert sie.
Nur wenn ich sie eingebunden habe, wie folgt,

<object type="application/x-shockwave-flash" data="/fileadmin/flash/news/gallery.swf" width="391" height="264">
  <param name="movie" value="/fileadmin/flash/news/gallery.swf" />
</object>

dann läuft sie nicht an.
Weiß jemand woran das liegen könnte?

[gaspode]

Falscher Bilderpfad? Hast Du das irgendwo online?

gruß, gaspode

[DISO]

ich kann das onlinebsp leider nicht veröffentlichen, da sich das projekt in der entwicklung befindet. ich hoffe ich kann es dir dennoch verdeutlichen.

also das swf liegt hier

http://www.foobar.de/fileadmin/flash/news/gallery.swf

es handelt sich um ein Typo3 projekt, daher die index.php direkt im root verzeichnis.

http://www.foobar.de/index.php

das ActionScript von Dir habe ich nicht verändert

/// imports
import flash.external.*;
import caurina.transitions.Tweener;


/// variables
var holders:Array = new Array();

var imageCount:Number = 0;
var imageLoadNr:Number = 1;

var imageLoaded:Boolean = false;
var imageNext:Boolean = true;

var checkInterval:Number;
var showInterval:Number;

var showTime:Number = 5;
var transTime:Number = 1;



/// functions
function loadImageData():Void {
   
   var getData:LoadVars = new LoadVars();
   getData.onLoad = function(success)
   {
      if(success)
      {
         imageCount = Number( getData.imageCount );
         showTime = Number( getData.showTime );
         transTime = Number( getData.transitionTime );

         createHolders();
         loadImage();
      }
   }
   getData.load( "data/info.txt" );
   
}


function createHolders():Void
{
   for( var i:Number = 1; i <= imageCount; i++ )
   {
      var holder:MovieClip = viewer.createEmptyMovieClip("holder"+i, i);
      holders.push( holder );
      setImageReset( holder );
   }
}


function loadImage():Void {
   
   var imageNr:Number = getImageLoadNr();

   var imageListener:Object = new Object();
   imageListener.onLoadInit = function( ref )
   {
      setImageReset( ref );
      setImageLoaded( true );
   }
   
   var imageLoader:MovieClipLoader = new MovieClipLoader();
   imageLoader.addListener( imageListener );
   imageLoader.loadClip( "data/" + imageNr + ".jpg", holders[ imageNr - 1 ]);
}


function startTimer():Void
{
   showInterval = setInterval( setImageNext, showTime * 1000, true );
}


function moveImageIn( imageNr_:Number ):Void
{
   Tweener.addTween( holders[ imageNr_ - 1 ], { _alpha:100, time:transTime, transition:"linear", onStart:function() { this._visible = true }, onComplete:startTimer } );
}


function moveImageOut( imageNr_:Number ):Void
{
   Tweener.addTween( holders[ imageNr_ - 1 ], { _alpha:0, time:transTime, delay:transTime, transition:"linear", onComplete:function() { setImageReset( this ) } } );
}


function nextImage():Void
{
   if( imageNext && imageLoaded )
   {
      clearInterval( showInterval );
      
      setImageNext( false );
      setImageLoaded( false );
      
      moveImageIn( getImageLoadNr() );
      moveImageOut( getImageActualNr() );
      
      imageLoadNr++;
      loadImage();
   }
}



/// set / get
function getImageLoadNr():Number
{
   ( imageLoadNr <= imageCount ) ? ( imageLoadNr ) : ( imageLoadNr = 1 )
   
   return imageLoadNr;
}


function getImageActualNr():Number
{
   var returnValue:Number;
   ( imageLoadNr > 1 ) ? ( returnValue = imageLoadNr - 1 ) : ( returnValue = imageCount )
   return returnValue;
}


function setImageReset( image_:MovieClip ):Void
{
   image_._visible = false;
   image_._alpha = 0;
   image_._x = 0;
}


function setImageNext( status_:Boolean ):Void
{
   imageNext = status_;
}


function setImageLoaded( status_:Boolean ):Void
{
   imageLoaded = status_;
}



/// init
function galleryINIT():Void
{
   loadImageData();
   checkInterval = setInterval( nextImage, 1000 );
}

komisch ist wenn ich die adresse vom swf direkt im browser eingebe, dann läuft der Film.


//es waren tatsächlich die Pfadangaben im AS.
ist ja auch klar.wenn ich mit im root befinde muß ich auf den ordner verweißen.

[DISO]

Hallo ich ein letztes mal noch,

warum funktionieren keine PNG Grafiken?

[RustyCake]

Wieso? die funktionieren doch, hast Du das script umgeschrieben?

[gaspode]

Deswegen.

imageLoader.loadClip( "data/" + imageNr + ".jpg", holders[ imageNr - 1 ]);

Das müsstest Du dann wohl anpassen.

gruß, gaspode

[DISO]

das hatte ich getan.
tat sich aber nichts. also wenn es kein grundsätzliches problem geben sollte, dann hatte ich wohl etwas anderes falsch gemacht.

ich teste es nochmal.

// ja es funktioniert. ich hatte vergessen die fla wieder zu veröffentlichen. so das war es dann wirklich jetzt.


vielen dank für eure Hilfe.

schöne feiertage