[STUFF] MovieClipGroup - Klasse

[_crypto_]

Ist vllt nicht ganz perfekt udn man könnte noch weitere funktionen reinbauen
aber vllt helf ich jemanden damit

mit der klasse kann man MCs gruppiren und diese als gruppe bewegen und rotieren lassen.

class MovieClipGroup
{
    private var _group:Array;
    
    public function MovieClipGroup() {
        _group = [];
        
        var params:Object = arguments.length;
        if(params != 0) {
            for(var i:Number = 0; i < params; i++) {
                if(typeof(arguments[i]) == "movieclip") {
                    _group.push(arguments[i]);
                }
            }
        }
    }
    
    public function moveTo(x:Number,y:Number):Void {
        var lX:Number = _group[0]._x;
        var lY:Number = _group[0]._y;
        
        for(var i:Number = 0; i < _group.length; i++) {
            if(lX > _group[i]._x) {
                lX = _group[i]._x;
            }
            if(lY > _group[i]._y) {
                lY = _group[i]._y;
            }
        }
        
        for(var i:Number = 0; i < _group.length; i++) {
            _group[i]._x += (x - lX);
            _group[i]._y += (y - lY);
        }
    }
    
    public function rotateTo(m:Array, angle:Number):Void {    
        for(var i:Number = 0; i < _group.length; i++) {
            var a:Object = {x: m[0], y: m[1]};
            var obj:MovieClip = _group[i];
            
            obj.globalToLocal(a);
            obj._rotation += angle;
            obj.localToGlobal(a);
            obj._x += m[0] - a.x;
            obj._y += m[1] - a.y;
        }
    }
    
    public function addClip(clip:MovieClip):Void {
        _group.push(clip);
    }
    
    public function addClipAt(clip:MovieClip,i:Number):Void {
        var tmp:Array = [];
        for(var j:Number = 0; j < (_group.length + 1); j++){
            if(j < i) tmp.push(_group[j]);
            
            else if(j == i) tmp.push(clip);
            
            else tmp.push(_group[j-1]);
        }
        _group = tmp;
    }
    
    public function removeAt(i:Number):Void {
        var tmp:Array = [];
        for(var j:Number = 0; j < _group.length; j++) {
            if(j != i) {
                tmp.push(_group[j]);
            }
        }
        _group = tmp;
    }
    
    public function clear():Void {
        _group = [];
    }
    
    public function getClipAt(i:Number):MovieClip {
        return _group[i];
    }
    
    public function getGroup():Array {
        return _group;
    }
}; 

Funktionen:

// konstruktor
// parameter optional
new MovieClipGroup([para1,para2,...])
 
moveTo(x:Number, y:Number) : Void;
 
// [x,y] ist der Mittelpunkt um den rotiert wird.
rotateTo([x,y]:Array,angle:Number) : Void;
 
addClip(clip:MovieClip) : Void;
addClipAt(clip:MovieClip, index:Number) : Void;
 
removeAt(index:Number) : Void;
clear() : Void;
 
getClipAt(index:Number) : MovieClip;
// oder getGroup()[index:Number];
getGroup():Array; 

viel spaß damit

edit =>
so jetz sind aber hoffentlich keine fehler mehr drin ne

[Blax_ed]

Zitat von _crypto_

Ist vllt nicht ganz perfekt

PHP-Code:

moveTo(x:Number, y:Numver) : Void; 


erster!

haste noch ne demo fla ? oder ..

[rendner[i]]

Die Methode moveTo müsste man eventuell umschreiben da man dort auch mit "localToGLobal" und "globalToLocal" arbeiten muss.


Das würde ich auch ändern:

PHP-Code:

var params:Object = arguments.length;        
if(params != 0) 
{
//... 


in:

PHP-Code:

if( arguments.length ) 


Bei der Methode addClip sollte man eventuell prüfen ob der MC nicht schon vorhanden ist.

Für die Methoden "addClipAt" und "removeAt" solltest du dir mal die Methode "Array.splice" angucken.

Insgesamt würde ich anstelle von so einer Klasse, wenn man es anders machen kann, lieber alles so aufbauen das ich die Objekte in einem Container (MovieClip) lege und diesen rotiere/ verschiebe.

[_crypto_]

ja das mit dem container is schon richtig.
aber aus diesem grunde hab ihc ja mal so ansatzweise angefangen eben
einen gruppenMC dynmaishc erstellbar zu machen.

wenn du jetz 5 oder mehr MCs aufer bühne hast dann bekommst du die ja
nicht in einen Container rein oder? wenn ja dann wäre es mir neu und die
klasse wäre überflüssig

[rendner[i]]

wenn du jetz 5 oder mehr MCs aufer bühne hast dann bekommst du die ja
nicht in einen Container rein oder?

Richtig.
Darum vorher überlegen dann erst programmieren.