Flashforum - Die Community zu Adobe Flash, Flex AIR. Web Design und Inspiration.

public · 27-03-2006, 12:04

vieleicht kanns ja jemand gebrauchen

PHP-Code:

  class MovieClipAction {

    // programmed by Public 

    /*-------------------Methoden--------------------

                                                                                                                            

    mcSlideTo(MovieClip, _x, _y, Speed, Interval)

                                                                                                                            

    mcScalePercentTo(MovieClip, _xscale, _yscale, Speed, Interval)

                                                                                                                            

    mcScaleTo(MovieClip, _width, _height, Speed, Interval)

                                                                                                                            

    mcAlphaTo(MovieClip, _alpha, Speed, Interval)

                                                                                                                

    mcSetColor(MovieClip, Color)

                                                                                                                

    mcDrawRect(MovieClip, neuer Name, Tiefe, _x, _y, _width, _height, Lienendicke, Farbe, _alpha)

                                                                                

    mcSetColorTransform(MovieClip, red, green, blue, alpha)

                                                                        

    mcRandomColor(MovieClip)

                                                            

    mcSetNagativeColor(MovieClip)

                                                

    mcSlideColorTransform(MovieClip, red, green, blue, Speed, Interval)

                    

    mcKillMC(MovieClip)

                    

    mcPreload(Container, holderMC, url, Tiefe, _x, _y, _width, _height, Color, Counter, Text, Speed, Interval)*/

    //

    // Konstruktor

    //

    function MovieClipAction() {

    }

    //

    // mcSlideTo(MovieClip, _x, _y, Speed, Interval)

    //

    public function mcSlideTo(pMC:MovieClip, pX:Number, pY:Number, pSpeed:Number, pInterval:Number):Void {

        function interval() {

            var diffX:Number = pX-pMC._x;

            var diffY:Number = pY-pMC._y;

            pMC._x += diffX/pSpeed;

            pMC._y += diffY/pSpeed;

            updateAfterEvent();

            if (Math.round(pMC._x) == pX && Math.round(pMC._y) == pY) {

                pMC._x = pX;

                pMC._y = pY;

                clearInterval(id);

            }

        }

        var id = setInterval(interval, pInterval);

    }

    //

    // mcScalePercentTo(MovieClip, _xscale, _yscale, Speed, Interval)

    //

    public function mcScalePercentTo(pMC:MovieClip, pXS:Number, pYS:Number, pSpeed:Number, pInterval:Number):Void {

        function interval() {

            var diffXS:Number = pXS-pMC._xscale;

            var diffYS:Number = pYS-pMC._yscale;

            pMC._xscale += diffXS/pSpeed;

            pMC._yscale += diffYS/pSpeed;

            updateAfterEvent();

            if (Math.round(pMC._xscale) == pXS && Math.round(pMC._yscale) == pYS) {

                pMC._xscale = pXS;

                pMC._yscale = pYS;

                clearInterval(id);

            }

        }

        var id = setInterval(interval, pInterval);

    }

    //

    // mcScaleTo(MovieClip, _width, _height, Speed, Interval)

    //

    public function mcScaleTo(pMC:MovieClip, pW:Number, pH:Number, pSpeed:Number, pInterval:Number):Void {

        function interval() {

            var diffW:Number = pW-pMC._width;

            var diffH:Number = pH-pMC._height;

            pMC._width += diffW/pSpeed;

            pMC._height += diffH/pSpeed;

            updateAfterEvent();

            if (Math.round(pMC._width) == pW && Math.round(pMC._height) == pH) {

                pMC._width = pW;

                pMC._height = pH;

                clearInterval(id);

            }

        }

        var id = setInterval(interval, pInterval);

    }

    //

    // mcAlphaTo(MovieClip, _alpha, Speed, Interval)

    //

    public function mcAlphaTo(pMC:MovieClip, pA:Number, pSpeed:Number, pInterval:Number):Void {

        function interval() {

            if (pMC._alpha<pA) {

                pMC._alpha += pSpeed;

                updateAfterEvent();

                if (pMC._alpha>=pA) {

                    clearInterval(id);

                    pMC._alpha = pA;

                }

            }

            if (pMC._alpha>pA) {

                pMC._alpha -= pSpeed;

                if (pMC._alpha<=pA) {

                    clearInterval(id);

                    updateAfterEvent();

                    pMC._alpha = pA;

                }

            }

        }

        var id = setInterval(interval, pInterval);

    }

    //

    // mcSetColor()

    //

    public function mcSetColor(pMC:MovieClip, pColor:Number):Void {

        var c:Color = new Color(pMC);

        c.setRGB(pColor);

    }

    //

    // mcDrawRect(MovieClip, neuer Name, Tiefe, _x, _y, _width, _height, Lienendicke, Farbe, _alpha)

    //

    public function mcDrawRect(pMC:MovieClip, pName:String, pDeep:Number, pX:Number, pY:Number, pW:Number, pH:Number, pLine:Number, pColor:Number, pAlpha:Number):Void {

        pMC.createEmptyMovieClip(pName, pDeep);

        with (pMC[pName]) {

            _x = pX;

            _y = pY;

            moveTo(0, 0);

            beginFill(pColor, pAlpha);

            lineStyle(pLine, pColor, pAlpha);

            lineTo(pW, 0);

            lineTo(pW, pH);

            lineTo(0, pH);

            lineTo(0, 0);

            endFill();

        }

    }

    //

    // mcDrawRectOutline(MovieClip, neuer Name, Tiefe, _x, _y, _width, _height, Lienendicke, Farbe, _alpha)

    //

    public function mcDrawRectOutline(pMC:MovieClip, pName:String, pDeep:Number, pX:Number, pY:Number, pW:Number, pH:Number, pLine:Number, pColor:Number, pAlpha:Number):Void {

        pMC.createEmptyMovieClip(pName, pDeep);

        with (pMC[pName]) {

            _x = pX;

            _y = pY;

            moveTo(0, 0);

            lineStyle(pLine, pColor, pAlpha);

            lineTo(pW, 0);

            lineTo(pW, pH);

            lineTo(0, pH);

            lineTo(0, 0);

        }

    }

    //

    // mcSetColorTransform(MovieClip, red, green, blue, alpha)

    //

    public function mcSetColorTransform(pMC:MovieClip, pRed:Number, pGreen:Number, pBlue:Number, pAlpha:Number):Void {

        MovieClipAction.colorTrans(pMC, pRed, pGreen, pBlue, pAlpha);

    }

    //

    // private  colorTrans(MovieClip, red, green, blue, alpha);

    //

    private static function colorTrans(pMC:MovieClip, pRed:Number, pGreen:Number, pBlue:Number, pAlpha:Number):Void {

        var c:Color = new Color(pMC);

        var ct:Object = {ra:100, ga:100, ba:100, aa:pAlpha, rb:pRed, gb:pGreen, bb:pBlue, ab:pAlpha};

        c.setTransform(ct);

    }

    //

    // mcRandomColor(MovieClip)

    //

    public function mcRandomColor(pMC:MovieClip):Void {

        this.mcSetColorTransform(pMC, random(255), random(255), random(255), 100);

    }

    //

    // mcSetNagativeColor(MovieClip);

    //

    public function mcSetNagativeColor(pMC:MovieClip):Void {

        var c:Color = new Color(pMC);

        var ct:Object = {ra:-100, ga:-100, ba:-100, aa:100, rb:255, gb:255, bb:255, ab:255};

        c.setTransform(ct);

    }

    //

    // mcSlideColorTransform(MovieClip, red, green, blue, Speed, Interval)

    //

    public function mcSlideColorTransform(pMC:MovieClip, pR:Number, pG:Number, pB:Number, pSpeed:Number, pInterval:Number):Void {

        var red:Number = 0;

        var green:Number = 0;

        var blue:Number = 0;

        function interval() {

            var diff_red:Number = pR-red;

            var diff_green:Number = pG-green;

            var diff_blue:Number = pB-blue;

            red += diff_red/pSpeed;

            green += diff_green/pSpeed;

            blue += diff_blue/pSpeed;

            MovieClipAction.colorTrans(pMC, red, green, blue, 100);

            updateAfterEvent();

            if (Math.round(red) == pR && Math.round(green) == pG && Math.round(blue) == pB) {

                MovieClipAction.colorTrans(pMC, pR, pG, pB, 100);

                clearInterval(id);

            }

        }

        var id = setInterval(interval, pInterval);

    }

    //

    // mcKillMC(MovieClip)

    //

    public function mcKillMC(pMC:MovieClip):Void {

        pMC.removeMovieClip();

    }

    //

    // mcGetPercentLoaded(MovieClip)

    //

    public function mcGetPercentLoaded(pMC):Number {

        var percent:Number = pMC.getBytesLoaded()/pMC.getBytesTotal()*100;

        return percent;

    }

    //

    // mcPreload(Container, holderMC, url, Tiefe, _x, _y, _width, _height, Color, Counter, Text, Speed, Interval)

    //

    public function mcPreload(pCont:MovieClip, pHolder:MovieClip, pURL:String, pDeep:Number, pX:Number, pY:Number, pW:Number, pH:Number, pColor:Number, pCount:Number, pText:String, pSpeed:Number, pInterval:Number):Void {

        var mca_load:MovieClipAction = new MovieClipAction();

        var count:Number = 0;

        var tf:TextFormat = new TextFormat();

        pCont._alpha = 0;

        mca_load.mcDrawRectOutline(pHolder, "outline_mc", pDeep, pX, pY, pW, pH, 1, pColor, 100);

        pHolder.createTextField("loader_txt", pDeep+2, pX-1, pY-17, 100, 10);

        pHolder.loader_txt.autoSize = true;

        pHolder.loader_txt.html = true;

        pHolder.loader_txt.selectable = false;

        tf.font = "Verdana";

        tf.color = pColor;

        tf.size = 10;

        pHolder.loader_txt.setNewTextFormat(tf);

        pHolder.loader_txt.text = pText;

        pCont.loadMovie(pURL);

        function interval() {

            var breite:Number = mca_load.mcGetPercentLoaded(pCont)/100*pW;

            mca_load.mcDrawRect(pHolder, "loader_mc", pDeep+1, pX, pY, breite, pH, undefined, pColor, 100);

            updateAfterEvent();

            if (mca_load.mcGetPercentLoaded(pCont) == 100) {

                count++;

                if (count == pCount) {

                    mca_load.mcKillMC(pHolder.outline_mc);

                    mca_load.mcKillMC(pHolder.loader_mc);

                    pHolder.loader_txt.removeTextField();

                    count = 0;

                    mca_load.mcAlphaTo(pCont, 100, pSpeed, pInterval);

                    clearInterval(id);

                }

            }

        }

        var id = setInterval(interval, pInterval);

    }

}

verwenden:

PHP-Code:

  // bsp

 
var mca:MovieClipAction=new MovieClipAction();

mca.mcSlideTo(dein_mc,400,100,8,20);

Methoden

Zitat:

mcSlideTo(MovieClip, _x, _y, Speed, Interval)

mcScalePercentTo(MovieClip, _xscale, _yscale, Speed, Interval)

mcScaleTo(MovieClip, _width, _height, Speed, Interval)

mcAlphaTo(MovieClip, _alpha, Speed, Interval)

mcSetColor(MovieClip, Color)

mcDrawRect(MovieClip, neuer Name, Tiefe, _x, _y, _width, _height, Lienendicke, Farbe, _alpha)

mcSetColorTransform(MovieClip, red, green, blue, alpha)

mcRandomColor(MovieClip)

mcSetNagativeColor(MovieClip)

mcSlideColorTransform(MovieClip, red, green, blue, Speed, Interval)

mcKillMC(MovieClip)

mcPreload(Container, holderMC, url, Tiefe, _x, _y, _width, _height, Color, Counter, Text, Speed, Interval)

download

mfg Public

rendner[i] · 27-03-2006, 12:10

Kleiner Schönheitsfehler

PHP-Code:

  public function mcRandomColor(pMC:MovieClip):Void { 

        this.mcSetColorTransform(pMC, random(256), random(256), random(256), 100); 

    }

public · 27-03-2006, 12:14

was meinsten genau?

lg public

rendner[i] · 27-03-2006, 12:18

Wenn du nur random(255) nimmst bekommst du nur Wete von 0 bis 254 aber es gibt ja 256 Werte also musste die 255 mit reinnehmen.

public · 27-03-2006, 12:23

aso...danke schön

public

27-03-2006, 12:10	#2 (permalink)
rendner[i] voidboy Registriert seit: Sep 2004 Ort: München Beiträge: 5.588	Kleiner Schönheitsfehler PHP-Code: `public function mcRandomColor(pMC:MovieClip):Void { this.mcSetColorTransform(pMC, random(256), random(256), random(256), 100); }` __________________ ERROR: Signature is too large

27-03-2006, 12:18	#4 (permalink)
rendner[i] voidboy Registriert seit: Sep 2004 Ort: München Beiträge: 5.588	Wenn du nur random(255) nimmst bekommst du nur Wete von 0 bis 254 aber es gibt ja 256 Werte also musste die 255 mit reinnehmen. __________________ ERROR: Signature is too large

Themen-Optionen
Druckbare Version zeigen Jemanden per E-Mail auf dieses Thema hinweisen
Ansicht
Linear-Darstellung Zur Hybrid-Darstellung wechseln Zur Baum-Darstellung wechseln

27-03-2006, 12:14	#3 (permalink)
public class public{} Registriert seit: Feb 2004 Ort: dessau Beiträge: 1.406	was meinsten genau? lg public

27-03-2006, 12:23	#5 (permalink)
public class public{} Registriert seit: Feb 2004 Ort: dessau Beiträge: 1.406	aso...danke schön public