[Stuff] Functions mit oEF nacheinander ausführen

[pape]

Hi!

Gestern habe ich sowas benötigt und dachte, dass es vllt auch andere gebrauchen könnten. Vielleicht gibt es auch eine elegantere Lösung, aber das hier ist meine - Verbesserungsvorschläge sind aber immer willkommen

Wenn man nacheinander ein paar Events ausführen möchte und die einzelnen Events unterschiedlich lang sind, muss man auf eine Variable zurückgreifen, die einem mitteilt, wann es weiter gehen kann.
Sobald man mehr als eine Aktion hintereinander ausführen möchte, wird das schnell sehr unübersichtlich:

macheDies();
this.onEnterFrame = function () {
  if(macheDies_ready) {
    delete this.onEnterFrame;
    macheJenes();
    this.onEnterFrame = function () {
      if(macheJenes_ready) {
        delete this.onEnterFrame;
        trace("fertig");
      }
    }
  }
} 

Denkbar wäre so etwas z.b. bei einem Animierten mehrdimensionalen Menü:
fadeSubSubMenuAus();
fadeSubMenuAus();
WechsleHauptMenu();
..

Um diese unübersichtliche Verschachtelung zu umgehen habe ich diese Funktion geschrieben:

_global.tl = this;
action = tl.createEmptyMovieClip("action", tl.getNextHighestDepth());
action.go = function (arr) {
    if(arr.length > 0) {
        this.arr = arr;
        tl[this.arr[0][0]].status = 0;
        eval(arr[0][0] + "." + arr[0][1])(arr[0][2]); // [Object]. [fn] ([parameter])
        this.onEnterFrame = function() {
            if(tl[this.arr[0][0]].status) {
                delete this.onEnterFrame;
//        trace(this.arr[0][0] + "." + this.arr[0][1] + " is ready"); //gibt die beendete Funktion aus
                this.arr.shift();
                this.go(this.arr);
            }
        }
    }
}; 

Sie geht davon aus, dass alle Funktionen die nacheinander ausgeführt werden sollen, einem (oder mehreren) Objekten (z.B. MovieClips) zugeordnet sind. Die Aktionen müssen also so deklariert werden:

_global.tl = this;
tl.createEmptyMovieClip("myObject", tl.getNextHighestDepth());
myObject.status = 0;
myObject.myFunction1 = function () {
    this.status = 0;
    //Aktionen
    this.status = 1;
}
myObject.myFunction2 = function (parameter) {
    this.status = 0;
    //Aktionen
    this.status = 1;
}
tl.createEmptyMovieClip("myObject2", tl.getNextHighestDepth());
myObject2.status = 0;
myObject2.myFunction1 = function (parameter) {
    this.status = 0;
    //Aktionen
    this.status = 1;
} 

die Status-variable gibt dabei an wann die nächste Aktion ausgeführt werden darf. Sobald sie auf 1 steht, gehts weiter.

Um nun mehrere Funktionen hintereinander auszuführen, übergibt man der Aktions-Funktion ein zweidimensionales Array, welches so aufgebaut ist:

action.go([
//    [Object, Function, Parameter],
//Bsp
    ["myObject", "myFunction1", undefined], //keine Parameter
    ["myObject", "myFunction2", 10], //einen Parameter
    ["myObject2", "myFunction1", ["hallo", 2]] //mehrere Parameter
]); 

Das Array mit den Parametern wird einfach als Array beim Aufruf der Funktion übergeben. Wenn es nur einen Parameter gibt, kann dieser auch einfach so übergeben werden.
Keine Parameter kann man einfach durch ein "undefined" eine 0 oder ähnliches angeben.

Ein komplettes Beispiel könnte so aussehen:

_global.tl = this;
 
var r = tl.createEmptyMovieClip("Restaurant", tl.getNextHighestDepth());
r.status = 0;
r.hinfahren = function (Uhrzeit) {
    this.status = 0;
    trace("Losgefahren um " + Uhrzeit);
    this.c = 0;
    this.onEnterFrame = function () {
        this.c++;
        if(this.c>30){
            trace("Nach "+this.c+" Minuten angekommen");
            delete this.onEnterFrame;
            this.status = 1;
        }
    }
}
r.bestellen = function (Bestellung) {
    this.status = 0;
    trace("Ich haette gerne " + Bestellung[0]+ " mit " + Bestellung[1]);
    this.c = 0;
    this.onEnterFrame = function () {
        this.c++;
        if(this.c>=20){
            trace("Der Ober bringt das Essen nach "+this.c+" Minuten \n Guten Hunger!");
            delete this.onEnterFrame;
            this.status = 1;
        }
    }
}
var z = tl.createEmptyMovieClip("ZuHause", tl.getNextHighestDepth());
z.status = 0;
z.daSein = function (Uhrzeit) {
    this.status = 0;
    trace("Um " + Uhrzeit +" zu Hause sein");
    trace("nix wie los...");
    this.status = 1;
}
 
action = tl.createEmptyMovieClip("action", tl.getNextHighestDepth());
action.go = function (arr) {
    if(arr.length > 0) {
        this.arr = arr;
        tl[this.arr[0][0]].status = 0;
        eval(arr[0][0] + "." + arr[0][1])(arr[0][2]); // [Object]. [fn] ([parameter])
        this.onEnterFrame = function() {
            if(tl[this.arr[0][0]].status) {
                delete this.onEnterFrame;
//        trace(this.arr[0][0] + "." + this.arr[0][1] + " is ready");
                this.arr.shift();
                this.go(this.arr);
            }
        }
    }
};
tmp_go = Array();
tmp_go.push(["Restaurant", "hinfahren", "20:00"]);
tmp_go.push(["Restaurant", "bestellen", ["Schnitzel", "Cola"]]);
tmp_go.push(["ZuHause", "daSein", "22:00"]);
action.go(tmp_go); 

Das Beispiel gibts auch im Anhang.

Viel Spaß damit!

[mojave]

mmmh ich weiß nicht ob das so viel sinn macht...?

wie wäre es denn einfach events zu werfen wenn eine aktion vorbei ist und einfach darauf zu reagieren..?

[pape]

Dann wäre es aber nicht mehr dynamisch, weil jedes Event ja nur einmal definiert werden kann. Man müsste dann um es dynamisch zu halten Unmengen von Parameterabfragen machen um den richtigen Handlungsstrang zu verfolgen.
Bei mir kann man es einfach so machen:

tmp_go.push(["Navi", "deaktivieren", undefined]);
if(SubMenuIstAusgefahren) {
  tmp_go.push(["Navi", "subMenuEinfahren", SubMenuId]);
}
tmp_go.push(["Navi", "subMenuAusfahren", newSubMenuId]);
tmp_go.push(["Navi", "aktivieren", undefined]);
action.go(tmp_go); 

Das kann man beliebig verschachteln und hat somit einen voll dynamischen Handlungsverlauf ohne dass die Aktionen sich gegenseitig in die Quere kommen.
Es ging ja darum, dass man dynamisch einen Handlungsstrang definieren kann und dieser abgearbeitet wird, ohne dass die Dinge gleichzeitig passieren.
Oder habe ich da irgendwas bei den Events verpasst ?