[stuff] Flexible Formular Klasse

[Linowitch]

Hallo,

ich habe eine kleine Formular Klasse gebaut, da ich flexibilität über alles liebe und stundenlange tipperei nicht ausstehen kann.

Ich hab hier schon diverse Formulare gesehen, bei denen man zur Anpassung aber trotzdem noch in den Quelltext eingreifen musste, deswegen gebe ich sie jetzt mal frei und hoffe auf rege Kritik, Wünsche, Verbesserungen, Lob oder was man einem sonst noch so alles an den Kopf schmeißen kann. :-)

Die Textfelder müssen selbstverständlich selbst auf der Bühne platziert werden, es geht hier nur um den Progammierten Teil.

class cFormular
{
    //----------------------------------------------
    // Vars
    //----------------------------------------------
    private var ScriptPath:String;
    private var ItemName:Array;
    private var ItemValue:Array;
    private var Enter:Array;
    private var Tab:Array;
    private var InfoText:TextField;
    public var checkEmail:Boolean;
    
    //----------------------------------------------
    // Constructor
    //----------------------------------------------
    public function cFormular()
    {
        if(arguments[0].toString()!=undefined){
            this.ScriptPath = arguments[0].toString();
        } else {
            this.ScriptPath = "formular.php";
        }
        this.ItemName = new Array();
        this.ItemValue = new Array();
        this.Enter = new Array();
        this.Tab = new Array();
        this.checkEmail = true;
    }
    
    //----------------------------------------------
    // Set Path to php script
    //----------------------------------------------
    public function setScriptPath(ScriptPath:String):Void
    {
        this.ScriptPath = ScriptPath;
    }
    
    //----------------------------------------------
    // add new Item
    //----------------------------------------------
    public function addItem(Name:String, Value:TextField, Enter:Boolean, Tab:Number):Void
    {
        this.ItemName.push(Name);
        this.ItemValue.push(Value);
        this.Enter.push(Enter);
        this.Tab.push(Tab);
        this.allocateTab();
    }
    
    //----------------------------------------------
    // allocate Tabindex
    //----------------------------------------------
    private function allocateTab():Void
    {
        for(var i=0;i<this.ItemName.length;i++){
            if(this.Tab[i]!=null){
                this.ItemValue[i].tabEnabled = true;
                this.ItemValue[i].tabIndex = this.Tab[i];
                this.selectItem(1);
            }
        }
    }
    
    //----------------------------------------------
    // Selection.setFocus 
    //----------------------------------------------
    public function selectItem(Tab:Number):Void
    {
        for(var i=0;i<this.ItemName.length;i++){
            if(this.Tab[i]!=null){
                if(this.Tab[i]==Tab) Selection.setFocus(this.ItemValue[i]);
            }
        }
    }
    
    //----------------------------------------------
    // add InfoTextField
    //----------------------------------------------
    public function addInfoTextField(InfoText:TextField):Void
    {
        this.InfoText = InfoText;
    }
    
    //----------------------------------------------
    // send formular
    //----------------------------------------------
    public function send(To:String, Subject:String):Void
    {
        if(!this.check()) return;
        var Send:LoadVars = new LoadVars();
        var Load:LoadVars = new LoadVars();
        
        Send.To = escape(To);
        Send.Subject = escape(Subject);
        if(arguments[2].toString()!=undefined) Send.Caption = escape(arguments[2].toString());
        else Send.Caption = escape(Subject);
        
        for(var i=0;i<this.ItemName.length;i++){
            Send["name"+i] = escape(this.ItemName[i]);
            Send["value"+i] = escape(this.ItemValue[i].text);
        }
        var scope = this;
        Load.onLoad = Delegate.createPacked(this, onLoad, Load);
        Send.sendAndLoad(this.ScriptPath, Load, "_POST");
        if(this.InfoText!=undefined) this.InfoText.text = "Daten werden gesendet!";
    }
    
    //----------------------------------------------
    // check all Items and start error event
    //----------------------------------------------
    private function check():Boolean
    {
        var errorCode:Number = 0;
        var errorEmail:Number = 0;
        for(var i=0;i<this.ItemName.length;i++){
            
            // all fields filled?
            if(this.Enter[i]){
                if(this.ItemValue[i].text==""){
                    errorCode = 101;
                }
            }
            
            // email correct?
            if(this.checkEmail){
                if(this.ItemName[i].toString().toUpperCase()=="EMAIL"){
                    if(this.ItemValue[i].text.indexOf('@')<3||this.ItemValue[i].text.indexOf('.')<6){
                        errorEmail = 102;
                    }
                }
            }
        }
        if(errorCode!=0){
            this.onError(errorCode);
            return false;
        } else if(errorEmail!=0){
            this.onError(errorEmail);
            return false;
        }
        return true;
    }
 
    //----------------------------------------------
    // onLoad Event
    //----------------------------------------------
    public function clearItems():Void
    {
        for(var i=0;i<this.ItemName.length;i++){
            this.ItemValue[i].text = "";
        }
    }
    
    //----------------------------------------------
    // onLoad Event
    //----------------------------------------------
    public function onLoad(evt):Void
    {
        if(evt.back){
            this.clearItems();
            this.selectItem(1);
            this.InfoText.text = "Daten wurden erfolgreich gesendet";
        } else this.InfoText.text = "Daten konnten nicht gesendet werden";
    }
 
    //----------------------------------------------
    // error event
    //----------------------------------------------
    public function onError(target:Number):Void
    {
        if(this.InfoText!=undefined){
            switch(target){
                case 101:
                    this.InfoText.text = "Sie haben nicht alle felder Ausgefüllt!";
                break;
                case 102:
                    this.InfoText.text = "Sie müssen eine gültige Email eingeben!";
                break;
            }
        }
    }
    
/*###################################################
# error Code
# 101 = fields not filled
# 102 = invalid email address
###################################################*/
 
} 

PHP-Code:

<?php
    
$num = (count($_POST)-3) / 2;

$To = utf8_decode(urldecode($_POST['To']));
$Subject = utf8_decode(urldecode($_POST['Subject']));
$Message = utf8_decode(urldecode($_POST['Caption'])) . "\n";

for($i =0;$i<$num;$i++){
    $name = "name".$i;
    $value = "value".$i;
    $Message .= utf8_decode(urldecode($_POST[$name])) . ": ";
    $Message .= utf8_decode(urldecode($_POST[$value])) . "\n";
}

if(@mail($To, $Subject, $Message)){
    echo "&back=true";
} else {
    echo "&back=false";
}
?>

Anwendungsbeispiel:

var Formular:cFormular = new cFormular();
//Optional kann auch 
// var Formular:cFormular = new cFormular("PfadZumScript.php");
// oder
// Formular.setScriptPath("PfadZumScript.php");
//gewählt werden
 
Formular.addItem("Nachname", _root.InstanzName.TextFieldName, true, 1);
Formular.addItem("Vorname", _root.InstanzName.TextFieldName, true, 2);
Formular.addItem("Email", _root.InstanzName.TextFieldName, true, 3);
Formular.addItem("Anfrage", _root.InstanzName.TextFieldName, true, 4);
 
// syntax
//addItem(Name:String, Value:TextField, Enter:Boolean, Tab:Number):Void
// Enter steht für Pflichtfeld
// Tab für die Tabulator reihenfolge
 
// Zur anzeige der Info Texte
Formular.addInfoTextField(_root.InstanzName.TextFieldName);
 
_root.Btn_Send.onRelease = function()
{
    Formular.send("To", "Subject", "ÜberschriftDesFormulares");
}
 
_root.Btn_Reset.onRelease = function()
{
    Formular.clearItems();
    Formular.selectItem(1);
} 

Seid bitte gnädig das ist meine erste Veröffentlichung

Hoffe es gefällt, hilft, oder inspiriert

Gruß Linowitch

[Linowitch]

Hab noch was vergessen, ohne die Delegate klasse gehts natürlich auch nicht.

Interval in einer klasse mit fnkt -> geltungsbereich ?