[stuff] filtered cubic 3D

[Janoscharlipp]

Jep, der Schub ist heftig.

Aber ich denke mal, dass ein Großteil auf die abgeschaltete Transparenz und die veringerte BlurFilter-Qualtät zurück zu führen sind.

[pwdVergesser]

@sal
na dann lass´ uns das morgen mal ansehen...

[pwdVergesser]

was mich jetzt noch interessiert ist, ob cacheAsBitmap auf "buffer" verwendet
nochmal was rausreißt oder ob das in diesem Falle keine Auswirkung hat...

...werde ich heute abend mal rumspielen...


pwd

[salazar]

@pwd
"mi casa et su casa"

cya, sal

[[je]]

Also der BlurFilter und die Transparenz sorgen nicht für diesen Performanceeinbruch den man auch im Standalone hat.

Man darf auch nicht vergessen, dass Math.sin und Math.cos ja jedes mal ausgeführt werden und zwar viel zu oft. Auch bei mir entdecke ich noch eine Dummheit wo ich grade drüber gucke

var cax: Number = cos( angle_x );
        var sax: Number = sin( angle_x );
        var cay: Number = cos( angle_y );
        var say: Number = sin( angle_y );
        var caz: Number = cos( angle_z );
        var saz: Number = sin( angle_z ); 

Das gehört nicht in onEnterFrame sondern unter die Definition der Winkel. Da ändert sich ja nichts.

Noch etwas: screen.draw( buffer ). Müll in der for. Es reicht einmal den Buffer zu zeichnen, und nur einmal clear zu verwenden. Dann muss man nur einmal den lineStyle usw. setzen.

Wichtig sind auch viele kleine Geschichten die man schnell übersieht. Sachen wie "var bi: Array = bindings[ i ];" sind nicht zu unterschätzen wenn man es konsequent verfolgt.

[[je]]

Zitat von pwdVergesser

was mich jetzt noch interessiert ist, ob cacheAsBitmap auf "buffer" verwendet
nochmal was rausreißt oder ob das in diesem Falle keine Auswirkung hat...

...werde ich heute abend mal rumspielen...


pwd

Auf keinen Fall! Er muss ja immer neu Cachen. Wäre der Buffer vom visuellen Gesichtspunkt her statisch, dann wäre es sinnvoll, aber so nicht.

-- Edit --

Mit den restlichen optionalen Verbesserungen

PHP-Code:

/////////////////////////////////////////////////////
//  flat cubic burner
//  author : frank reitberger
//  site : http://www.dasprinzip.com
//  copyright 2006
/////////////////////////////////////////////////////

import flash.display.BitmapData;
import flash.filters.*;
import flash.geom.*;

//-- define points
var p0: Array = [
            { x: -100, y: -100, z: -100 },
            { x: +100, y: -100, z: -100 },
            { x: +100, y: -100, z: +100 },
            { x: -100, y: -100, z: +100 },
            { x: -100, y: +100, z: -100 },
            { x: +100, y: +100, z: -100 },
            { x: +100, y: +100, z: +100 },
            { x: -100, y: +100, z: +100 }];
            
//-- connect points
var b0:Array = new Array([0,1,0,1],[1,2,1,2],[2,3,2,3],[3,0,3,0],[4,5,4,0],[5,6,5,1],[6,7,6,2],[7,4,7,3]);

//-- cache angles
var ax:Number = .01;
var ay:Number = .0075;
var az:Number = .005;

var sin: Function = Math.sin;
var cos: Function = Math.cos;
        
var cax: Number = cos( ax );
var sax: Number = sin( ax );
var cay: Number = cos( ay );
var say: Number = sin( ay );
var caz: Number = cos( az );
var saz: Number = sin( az );

//-- stage
var w: Number = Stage.width;
var h: Number = Stage.height;
var screen: BitmapData = new BitmapData( w, h, false, 0 );
var rect: Rectangle = screen.rectangle;

//-- effect
var filter: BlurFilter = new BlurFilter( 2, 2, 1 );
var origin: Point = new Point;
var damp: ColorTransform = new ColorTransform( .91, .98, .99, 1, 0, 0, 0, 0 );
var fx: Matrix = new Matrix;
var tr: Matrix = new Matrix;
var buf: MovieClip = this.createEmptyMovieClip( '__buffer__', 0xff );

//-- setup screen
this.attachBitmap( screen, 1 );

//-- setup buffer
buf._visible = false;

//-- transform
tr.tx = tr.ty = 200;

this.onEnterFrame = function( Void ): Void
{
    //-- fade and filter
    screen.draw( screen, fx, damp );
    screen.applyFilter( screen, rect, origin, filter );
    
    //-- draw next frame
    buf.clear();        
    buf.lineStyle( 1, 0xffffff, 100 );
        
    for ( var i: Number = 0; i < 8; i++ )
    {
        var bi: Array = b0[ i ];
                
        buf.moveTo( p0[ bi[ 0 ] ].x, p0[ bi[ 0 ] ].y );
        buf.lineTo( p0[ bi[ 1 ] ].x, p0[ bi[ 1 ] ].y );                
        buf.moveTo( p0[ bi[ 2 ] ].x, p0[ bi[ 2 ] ].y );
        buf.lineTo( p0[ bi[ 3 ] ].x, p0[ bi[ 3 ] ].y );        
    }
    
    screen.draw( buf, tr );
        
    for ( var i: Number = 0; i < 8; i++ )
    {
        var p: Object = p0[ i ];
        
        var px: Number = p.x;
        var py: Number = p.y;
        var pz: Number = p.z;
        
        p.y = py * cax - pz * sax;
        p.z = py * sax + pz * cax;

        py = p.y;
        pz = p.z;

        p.x =  px * cay + pz * say;
        p.z = -px * say + pz * cay;

        px = p.x;

        p.x = px * caz - py * saz;
        p.y = py * caz + px * saz;
    }
} 


[Aerks]

und du schiesst ihm eine volle Breitseite rein... aua.

Oh Sorry. Wusste gar nicht, daß man hier neuerdings nur noch *knuddel* *knuddel* schreibt, wenn jemand Feedback haben möchte.
Der Herr R. wird das schon überleben.

...der Hintergrund hat einen Verlauf - evtl. nicht auf deinem Monitor...

Oh.. stimmt ist mir gestern gar nicht aufgefallen.

..."Mensch Thoooooorsten" ...ist doch nur mal eben als Flash-Filter-Spaß gedacht.
Zum ansehen...

Dann darfst du aber keinen Source posten. Ist doch wohl klar, daß der dann hier zersägt wird.

Na schön. Dann bin ich eben ein Nickelprinz... und wehe [je] bekommt keine solche Ansage nachdem er das "nur zum Ansehen"-Beispiel komplett umgeschrieben hat.

Viele Gruesse
=:] Aerks

[pwdVergesser]

@Aerks

Oh Sorry. Wusste gar nicht, daß man hier neuerdings nur noch *knuddel* *knuddel* schreibt, wenn jemand Feedback haben möchte.
Der Herr R. wird das schon überleben.

...stimmt. der herr r. kommt drüber weg!

Na schön. Dann bin ich eben ein Nickelprinz...

..."Nickelprinz"??? Ich würde eher sagen Aerks == AOL-Fan for live...

und wehe [je] bekommt keine solche Ansage nachdem er das "nur zum Ansehen"-Beispiel komplett umgeschrieben hat.

...du weißt doch - solche ansagen sind speziel für "herrn W." reserviert!

...hatte ich doch bei der eröffnung des threads geschrieben:

Und hier mal was zum nachvollziehen und rumspielen

im übrigen ist das nächste "Bier trinken" schon mehr als überfällig?

@salazar

...nur um hier spanisch korrekte korrinten zu kacken,
es heißt:

mi casa es su casa

pwd

[Aerks]

im übrigen ist das nächste "Bier trinken" schon mehr als überfällig?

Ja. Wäre mal wieder fällig. Vielleicht nächstesmal irgendwo in Düsseldorf?

Viele Gruesse
=:] Aerks

[pwdVergesser]

in Düsseldorf - na juut...

pwd

[querkopf]

fand besonders den pseudo 3d part hier sehr inspirierend

hab' hier mal ein wenig damit gespielt....

/////////////////////////////////////////////////////
//  flat cubic burner
//  author : frank reitberger
//  site : http://www.dasprinzip.com
//  copyright 2006
/////////////////////////////////////////////////////
import flash.display.BitmapData;
import flash.filters.*;
import flash.geom.*;
//-- define points
// var p0:Array = [{x:-100, y:-100, z:-100}, {x:+100, y:-100, z:-100}, {x:+100, y:-100, z:+100}, {x:-100, y:-100, z:+100}, {x:-100, y:+100, z:-100}, {x:+100, y:+100, z:-100}, {x:+100, y:+100, z:+100}, {x:-100, y:+100, z:+100}];
// var p0:Array = [{x:-100, y:-100, z:-100}, {x:+100, y:-100, z:-100}, {x:+100, y:-100, z:+100}, {x:-100, y:-100, z:+100}, {x:0, y:+100, z:0}];
// var p0:Array = [{x:-100, y:0, z:-100}, {x:+100, y:0, z:-100}, {x:+100, y:0, z:+100}, {x:-100, y:0, z:+100}, {x:0, y:+200, z:0}, {x:0, y:-200, z:0}];
var p0:Array = [{x:-20, y:-20, z:-20}, {x:+20, y:-20, z:-20}, {x:+20, y:-20, z:+20}, {x:-20, y:-20, z:+20}, {x:-20, y:+20, z:-20}, {x:+20, y:+20, z:-20}, {x:+20, y:+20, z:+20}, {x:-20, y:+20, z:+20}, {x:0, y:0, z:-150}, {x:+150, y:0, z:0}, {x:0, y:0, z:+150}, {x:-150, y:0, z:0}, {x:0, y:-150, z:0}, {x:0, y:+150, z:0}];
//-- connect points
// var b0:Array = new Array([0, 1, 0, 1], [1, 2, 1, 2], [2, 3, 2, 3], [3, 0, 3, 0], [4, 5, 4, 0], [5, 6, 5, 1], [6, 7, 6, 2], [7, 4, 7, 3]);
// var b0:Array = new Array([0, 1, 0, 4], [1, 2, 1, 4], [2, 3, 2, 4], [3, 0, 3, 4], [4, 1, 4, 0]);
// var b0:Array = new Array([0, 1, 0, 4], [1, 2, 1, 4], [2, 3, 2, 5], [3, 0, 3, 5], [4, 2, 4, 3], [5, 0, 5, 1]);
var b0:Array = new Array([0, 1], [1, 2], [2, 3], [3, 0], [4, 5, 4, 0], [5, 6, 5, 1], [6, 7, 6, 2], [7, 4, 7, 3], [8, 0, 8, 1, 8, 4, 8, 5], [9, 1, 9, 2, 9, 5, 9, 6], [10, 2, 10, 3, 10, 6, 10, 7], [11, 0, 11, 3, 11, 4, 11, 7], [12, 0, 12, 1, 12, 3, 12, 2], [13, 4, 13, 5, 13, 6, 13, 7]);
//-- cache angles
var ax:Number = .01;
var ay:Number = .0075;
var az:Number = .005;
var sin:Function = Math.sin;
var cos:Function = Math.cos;
var cax:Number = cos(ax);
var sax:Number = sin(ax);
var cay:Number = cos(ay);
var say:Number = sin(ay);
var caz:Number = cos(az);
var saz:Number = sin(az);
//-- stage
var w:Number = Stage.width;
var h:Number = Stage.height;
var screen:BitmapData = new BitmapData(w, h, false, 0);
var rect:Rectangle = screen.rectangle;
//-- effect
var filter:BlurFilter = new BlurFilter(2, 2, 1);
var origin:Point = new Point();
var damp:ColorTransform = new ColorTransform(.95, .95, .95, 1, 0, 0, 0, 0);
var fx:Matrix = new Matrix();
var tr:Matrix = new Matrix();
var buf:MovieClip = this.createEmptyMovieClip('__buffer__', 0xff);
//-- setup screen
this.attachBitmap(screen, 1);
//-- setup buffer
buf._visible = false;
//-- transform
tr.tx = 300;
tr.ty = 190;
var p0L:Number = p0.length;
this.onEnterFrame = function(Void):Void 
{
	//-- fade and filter
	screen.draw(screen, fx, damp);
	screen.applyFilter(screen, rect, origin, filter);
	//-- draw next frame
	buf.clear();
	buf.lineStyle(1, 0xffffff, 80);
	for (var i:Number = 0; i < p0L; i++)
	{
		var bi:Array = b0[i];
		for (var j:Number = 0; j < bi.length; j += 2)
		{
			buf.moveTo(p0[bi[j]].x, p0[bi[j]].y);
			buf.lineTo(p0[bi[j + 1]].x, p0[bi[j + 1]].y);
		}
	}
	screen.draw(buf, tr);
	for (var i:Number = 0; i < p0L; i++)
	{
		var p:Object = p0[i];
		var px:Number = p.x;
		var py:Number = p.y;
		var pz:Number = p.z;
		p.y = py * cax - pz * sax;
		p.z = py * sax + pz * cax;
		py = p.y;
		pz = p.z;
		p.x = px * cay + pz * say;
		p.z = -px * say + pz * cay;
		px = p.x;
		p.x = px * caz - py * saz;
		p.y = py * caz + px * saz;
	}
};

Bis dann,
-querkopf-