[STUFF] DoubleClick || Doppelklick

[mojave]

ja ja, alles schon mal dagewesen

Vorteil: Singleton + onPress, onRelease werden nicht überschrieben.

PHP-Code:

import mx.utils.Delegate;

class de.sonntagsfarben.utils.DoubleClick
{
    private static var instance : DoubleClick;
    private var clickObj:Object;
    private var clickSpeed:Number = 200;
    
    private function DoubleClick ()
    {
        init ();
    }
    
    
    private function init () : Void
    {
        clickObj = new Object();
    }
    
    
    public function check(mc:MovieClip, /*optional*/ speed:Number):Boolean
    {
        
        speed = speed || this.clickSpeed;
        
        if(clickObj[mc] == undefined)
        {
            clickObj[mc] = new Object();
            clickObj[mc].time = 0;
            clickObj[mc].clickinterval = setInterval(Delegate.create(this,function(){clickObj[mc].time++; clearInterval(clickObj[mc].clickinterval);delete(clickObj[mc]);}),speed);
        }
        else
        {
            if(clickObj[mc].time==0)
            {
                clearInterval(clickObj[mc].clickinterval);
                delete(clickObj[mc]);
                return true;
            }
            return false;
        }
        return false;
    }
        
    
    public static function getInstance () : DoubleClick
    {
        if (instance == null)
            instance = new DoubleClick ();
        return instance;
    }
} 


@usage:

PHP-Code:

//bsp auf _root:

import de.sonntagsfarben.utils.DoubleClick;

function onMouseDown(){
    trace(DoubleClick.getInstance().check(this));    
} 


[muschko]

super :-)

sieht sehr gut aus... und der hit find ich das onPress + onRelease nicht überschrieben werden

endlich mal wieder schicker stuff

thx * thumbs up *

[Madokan]

@mojave: Neu ist das aber nicht und die Ereignisse muss man auch nicht überschreiben.

Kuckst du hier:
Doppelklick bei Flash 8

Das ändert jedoch nichts daran, dass die vorliegende Lösung sehr brauchbar ist.

Liebe Grüße,
Matze K.

[mojave]

da war im übrigen etwas überflüssiges dabei - allein der singleton war unnötig. so ist's besser:

PHP-Code:

class DoubleClick
{
    private static var clickObj:Object = new Object();
    private static var clickSpeed:Number = 200;
    public static function isDoubleClick(target:Object, /*optional*/ speed:Number):Boolean
    {
        speed = speed || clickSpeed;    
        if(clickObj[target] == undefined)
        {
            clickObj[target] = new Object();
            clickObj[target].clickinterval = setInterval(deleteClickObject, speed, target);
        }
        else
        {
            deleteClickObject(target);
            return true;
        }
        return false;
    }
    private static function deleteClickObject(target:Object):Void
    {
        clearInterval(clickObj[target].clickinterval);
        delete(clickObj[target]);
    }
}