[Stuff] Cooles Passwortscript

[Kandidat]

Hallo liebe Flasher,

ich habe ein Passwort-Script geschrieben, dass sehr flexibel ist. Es ist ausgerichtet für ganze Sätze. Das Script schnappt sich das Kennwort und zerteilt es in einzelne Buchstabenfelder, ähnlich wie bei einem Kreuzworträtsel. Ein Beispiel gibt es hier Die Lösung lautet: Ignorieren ist keine Toleranz

Am Anfang des Scriptes sind die wichtigsten Variablen und ganz am Ende des Scripts findet sich die "Was-wenn-richtig-Funktion".

Und im Anhang liegt das komplette Flash.

Gruß Paul

PHP-Code:

//
KENNWORT = "Ignorieren ist keine Toleranz";
// 
REDIRECT = "http://www.infokrieg.tv";
// URL bei richtiger Eingabe
//
UMBRUCH = 10;
//Anzahl der Zeichen bevor Zeilenumbruch
//
GKS = false;
// Groß- und Kleinschreibung beachten?
//
//
//
function getLock() {
    /////////////////////////////////////////
    // getLock() nutzt das Kennwort zur
    // Passwortabfrage und zum Aufbau der
    // kompletten Szene!
    ////////////////////////////////////
    //////
    CODIFY = KENNWORT.split(" ");
    //////////////////////////////
    ////// LOCK:String füllen
    var m = "";
    for (var i = 0; i<CODIFY.length; i++) {
        m += CODIFY[i];
    }
    if (GKS) {
        LOCK = m;
    } else {
        LOCK = m.toLowerCase();
    }
    //////////////////////// 
    ////// lineUP:Array 
    lineUp = [];
    var a = 0;
    var b = 0;
    var c = 1;
    for (var i = 0; i<CODIFY.length; i++) {
        for (var j = 0; j<CODIFY[i].length; j++) {
            lineUp[a] = b;
            a++;
            b++;
        }
        if (lineUp.length>UMBRUCH*c) {
            lineUp[a] = -2;
            c++;
        } else {
            lineUp[a] = -1;
        }
        a++;
    }
    ////////////////////
    ////// Attach letters
    var xx = 0;
    var yy = 0;
    var aa = 0;
    _root.createEmptyMovieClip("lock_mc", 7);
    for (var i = 0; i<lineUp.length; i++) {
        var j = lineUp[i];
        if (lineUp[i] == -1) {
            xx += 15;
        } else if (lineUp[i] == -2) {
            yy += 45;
            xx = 0;
            aa = 0;
        } else {
            _root.lock_mc.attachMovie("Letter Mc", "letter"+j+"_mc", i+30);
            var mc = _root.lock_mc["letter"+j+"_mc"];
            mc._x = (mc._width-4)*aa+xx;
            mc._y = yy;
            aa++;
        }
    }
    ///////////////
    // txt btn
    _root.lock_mc.createTextField("info_txt", 8, 0, -40, 210, 30);
    INFO = _root.lock_mc.info_txt;
    INFO.text = "Lösung hier eintragen:";
    HEAD = new TextFormat();
    HEAD.color = 0xFFFFFF;
    HEAD.font = "Tahoma";
    HEAD.size = 20;
    INFO.setTextFormat(HEAD);
    //
    lock_mc.attachMovie("Button Cancel", "cancel_mc", 90);
    var mc = _root.lock_mc.cancel_mc;
    var yy = lock_mc._height-mc._height+10;
    mc._y = yy;
    mc._x = lock_mc._width-mc._width-mc._width-10;
    //
    lock_mc.attachMovie("Button Approve", "enter_mc", 91);
    var mc = _root.lock_mc.enter_mc;
    mc._y = yy;
    mc._x = lock_mc._width-mc._width;
    //
    _root.lock_mc._x = (Stage.width-lock_mc._width)/2;
    _root.lock_mc._y = (Stage.height-lock_mc._height)/2;
}
//
function clearAll() {
    for (var i = 0; i<LOCK.length; i++) {
        _root.lock_mc["letter"+i+"_mc"].input_txt.text = "";
    }
    INFO.text = "Lösung hier eintragen:";
    INFO.setTextFormat(HEAD);
}
//
function getKey() {
    var m = "";
    for (var i = 0; i<LOCK.length; i++) {
        m += _root.lock_mc["letter"+i+"_mc"].input_txt.text;
    }
    if (GKS) {
        KEY = m;
    } else {
        KEY = m.toLowerCase();
    }
    ////////////////// WAS WENN RICHTIG?
    ///////////////////////////////////////
    if (LOCK == KEY) {
        INFO.text = "Richtig!";
        INFO.setTextFormat(HEAD);
        getURL(REDIRECT, "_blank");
    } else {
        INFO.text = "Leider falsch!";
        INFO.setTextFormat(HEAD);
    }
    ////////////////////////////////////////
    ///////////////////// WAS WENN FALSCH?
}
getLock();
_root.lock_mc.enter_mc.onRelease = getKey;
_root.lock_mc.cancel_mc.onRelease = clearAll; 


[mauri2006]

Coole Idee, aber ich fände es besser
wenn man nach eingabe eines Buchstaben
zum anderen Feld gehen kann bzw es
automatisch zum anderen Feld springt ^^

[Kandidat]

Das finde ich auch. Hat jemand eine Idee, wie man das realisieren kann?

Ich werde mich mal in der Actionscript-Hilfe umsehen. Ich denke es geht vielleicht mit einer Mischung aus Listener und Focus wenn es so etwas geben sollte.

Gruß Paul

[mildesign]

halte deine Textfelder in einem Array

Lausche auf onChange und spring dann bei deiner Textlänge von 1 über den Focusmanager zum nächsten Textfeld innerhalb deines Arrays

Edit dein Tabindex bei den Textfeldern scheint auch nicht ganz zu stimmen.

[Kandidat]

Hmm ich bin jetzt leider nicht mehr im Büro, komme erst morgen wieder dazu etwas zu verändern. Der Tabindex ist glaube ich deswegen fehlerhaft weil in dieser Zeile das letzte "i" ein "j" sein sollte.

_root.lock_mc.attachMovie("Letter Mc", "letter"+j+"_mc", i+30);

Dann stimmts glaube ich wieder.

Aber was meinst Du denn mit Textfelder im Array halten?

[mildesign]

öhm referenzen auf die MovieClips(welche die Textfelder beinhalten) in ein Array pushen

Pseudocode:

PHP-Code:

var allTextFields:Array = [];
var pointer:Number = 0;
for(....){

var temp:Movieclips = attachMovie(...)

allTextFields.push(temp);

}

function nextItem():void{

FocusManager.setFocus(allTextFields[pointer++]);

} 


[Barschel2004]

@kandidat....

verdammt coole seite, auf die dann verlinkt wird...