[STUFF] ColorPicker F8

[[je]]

Hi, ich habe vor langem hier mal einen ColorPicker im Forum veröffentlicht. Der wurde auch froh weiter entwickelt. Bei einem Gespräch mit Janoscharlipp über das alte Gerät ist mir eine Idee mit Flash8 gekommen.

Ich denke es zeigt gut, wie man einmal BitmapData sinnvoll nicht nur für Spiele einsetzen kann.

Im Gegensatz zum alten ColorPicker wird keine Mathematik mehr benötigt. Das übernimmt jetzt alles Flash für uns.

Von daher viel übersichtlicher. Ich mag die Idee :o) Janoscharlipp nicht so.

import flash.display.BitmapData;
import flash.geom.*;
 
Stage.scaleMode = 'noScale';
 
//-- init color picker
var cp: Object = new Object;
 
//-- customize
cp.width = 320;
cp.height = 240;
 
//-- gradients
cp.colors = [ 0xff0000, 0xff00ff, 0x0000ff, 0x00ffff, 0x00ff00, 0xffff00,  0xff0000 ];
cp.alphas = new Array( cp.colors.length );
cp.ratios = new Array( cp.colors.length );
cp.matrix = { matrixType: 'box', x: 0, y: 0, w: cp.width, h: cp.height, r: Math.PI }; 
cp.matrix2 = {matrixType: 'box', x: 0, y: 0, w: cp.width, h: cp.height, r: 1.5 * Math.PI }; 
for ( var i: Number = 0; i < cp.colors.length; i++ )
{
    cp.alphas[ i ] = 100;
    cp.ratios[ i ] = ( 0xff / ( cp.colors.length - 1 ) ) * i;
}
    
//-- draw gradients
var buffer: MovieClip = this.createEmptyMovieClip( '__buffer', this.getNextHighestDepth() );
var gradient: MovieClip = buffer.createEmptyMovieClip( 'gradient', 1 );
var gray: MovieClip = buffer.createEmptyMovieClip( 'gray', 2 );
 
gradient.clear();
gray.clear();
 
gradient.beginGradientFill( 'linear', cp.colors, cp.alphas, cp.ratios, cp.matrix );
{
    gradient.lineTo( cp.width, 0 );
    gradient.lineTo( cp.width, cp.height );
    gradient.lineTo( 0, cp.height );
    gradient.lineTo( 0, 0 );
}
gradient.endFill(); 
 
gray.beginGradientFill( 'linear', [ 0, 0x808080, 0xffffff ], [ 100, 0, 100 ], [ 0, 0x80, 0xff ], cp.matrix2 );
{
    gray.lineTo( cp.width, 0 );
    gray.lineTo( cp.width, cp.height );
    gray.lineTo( 0, cp.height );
    gray.lineTo( 0, 0 );
}
gray.endFill(); 
 
//-- cache buffer
buffer.cacheAsBitmap = true;
 
//-- set up bitmap data
cp.bmp = new BitmapData( cp.width, cp.height, false, 0 );
cp.bmp.draw( buffer, new Matrix(), new ColorTransform() );
 
//-- EXAMPLE! --
buffer.onMouseDown = function( Void ): Void
{
    var color: Number;
    var mx: Number = this._xmouse;
    var my: Number = this._ymouse;
    
    if (mx >= 0 && mx <= cp.width &&
        my >= 0 && my <= cp.height )
    {
        var x: Number = mx | 0;
        var y: Number = my | 0;
        
        //-- read color from bitmapdata
        color = cp.bmp.getPixel( x, y );
        
        //-- output color
        var red: Number = (color & 0xff0000) >> 16;
        var green: Number = (color & 0xff00) >> 8;
        var blue: Number = color & 0xff;
        trace( '('+red+','+green+','+blue+')' );
    }
};
 
//-- if you want to have a bitmap instead a movieclip on stage
//buffer.removeMovieClip();
//this.attachBitmap( cp.bmp, 1, 'auto', true ); 
 

Sehr schöne Lösung!

[_level0]

sehr schön gemacht ja, darf ich fragen warum die wahl auf ein mit flash berechnetes gradient feld gefallen ist und nich auf "die üblichen" 256 color + dem was du schon hast(mit fadeslider) und so weiter in form eine grafik gefallen ist, befürchtest du farbuntreuheit dadurch?

[[je]]

Sicherlich ist die Farbe so nicht die schönste. Man hat auch Probleme (255,255,255) und (0,0,0) zu treffen. Aber ich wollte gerne etwas einfaches ohne 10 Slider haben.

Dafür finde ich das Ergebnis schon recht gut. Wie gesagt, man kann alles auch selbst errechnen, doch so übernimmt Flash die Rechnerei.

Was fehlt wäre noch ein Weg die Sättigung einzustellen. Helligkeit und Dunkelheit habe ich ja. So kommt man auf min. 3 Dimensionen. Es wäre sicher eine tolle Sache das ganze mal als Würfel zu basteln. Dafür habe ich aber heute zu wenig Zeit :)

(Anstatt mx | 0 könnte man auch Math.round( mx ) nehmen, wäre schonmal genauer)

[_level0]

Zitat von [je]

Sicherlich ist die Farbe so nicht die schönste. Man hat auch Probleme (255,255,255) und (0,0,0) zu treffen. Aber ich wollte gerne etwas einfaches ohne 10 Slider haben.

Dafür finde ich das Ergebnis schon recht gut. Wie gesagt, man kann alles auch selbst errechnen, doch so übernimmt Flash die Rechnerei.

Was fehlt wäre noch ein Weg die Sättigung einzustellen. Helligkeit und Dunkelheit habe ich ja. So kommt man auf min. 3 Dimensionen. Es wäre sicher eine tolle Sache das ganze mal als Würfel zu basteln. Dafür habe ich aber heute zu wenig Zeit

sollte auch keine kritik sein ich finde deinen colorpicker hervorragend, nur da ich unter 2004 selber schonmal einen gecodet hab wo ich damals praktich hintenrum grafiken hatte und nur sättigung und einzelne farbslider noch mit drin hatte und mir dann die farbwerte anhand der mausposition ausgerechenet habe,weiss ich was das für ne mistige rechnerei war, vor allem in so einem gradient feld welches du mit flash erzeugst, kompliment, daher nur die frage was dich dazu bewog und ob man die farbwerte dann nicht wirklich trifft durch veränderungen der grafiken beim kompriemieren mittels flash.

[[je]]

Farbwerte werden durch komprimierung nicht verfälscht. Über beginGradientFill wird diese ja jedes mal neu gezeichnet und wenn BitmapData auch nicht intern irgend etwas dreht müssten es echte Werte sein.

[_level0]

Zitat von [je]

Farbwerte werden durch komprimierung nicht verfälscht. Über beginGradientFill wird diese ja jedes mal neu gezeichnet und wenn BitmapData auch nicht intern irgend etwas dreht müssten es echte Werte sein.

löl

schon klar ich meinte ja beim einsatz von screenshots zum beispiel auf flash/ps oder ähnlicher software, die kann man dann ja auch umwandeln in mc´s und mittels der mausposition dann die position auf dem bild somit den px und daraus den farbwert erkennen, wie gesagt falls die farbwerte der grafiken nicht durch screenshot oder kompression verfäscht werden...

ein missverständniss, sorry