[STUFF] Blitzlicht (FlashLight) Klasse

[public]

hallo leute....
vielleicht kanns jemand gebrauchen, ik hab grad ma auf die schnelle ne Blitzlicht klasse geschrieben....

die klasse:

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;
import flash.filters.ColorMatrixFilter;
class FlashLight {
    public var onRun:Function;
    public var onFinish:Function;
    public var isRun:Boolean;
    function FlashLight () {
    }
    private function setBrightness (target:Object, brightness:Number):Void {
        var matrix:Array = [1, 0, 0, 0, brightness, 0, 1, 0, 0, brightness, 0, 0, 1, 0, brightness, 0, 0, 0, 1, 0];
        var colorMatrix:ColorMatrixFilter = new ColorMatrixFilter (matrix);
        target.filters = [colorMatrix];
    }
    private function deleteFilter (target:Object):Void {
        target.filters = [];
    }
    public function run (target:Object, time:Number, power:Number, useSeconds:Boolean, callBack:Function):Void {
        this.onRun ();
        this.isRun = true;
        var time2:Number = time * 6;
        var ref:FlashLight = this;
        var to:Object = {};
        var tween:Tween = new Tween (to, "_brightness", Strong.easeOut, 0, power, time, useSeconds);
        tween.onMotionChanged = function () {
            ref.setBrightness (target, to._brightness);
        };
        tween.onMotionFinished = function () {
            var tween2:Tween = new Tween (to, "_brightness", Strong.easeOut, power, 0, time2, useSeconds);
            tween2.onMotionChanged = function () {
                ref.setBrightness (target, to._brightness);
            };
            tween2.onMotionFinished = function () {
                callBack ();
                ref.onFinish ();
                ref.isRun = false;
                ref.deleteFilter (target);
            };
        };
    }
} 


bsp:

PHP-Code:

var fl:FlashLight = new FlashLight ();
onMouseDown = function () {
    // run(target:Object, time:Number, power:Number, useSeconds:Boolean)
    fl.run (test_mc, .2, 220, true);
};
fl.onRun = function () {
    trace ("Animation laüft");
};
fl.onFinish = function () {
    trace ("Animation beendet");
}; 


[~pyropete~]

Kannst Du noch nen Link zum Angucken basteln?

--pp

[bloba]

nettes teil

ich wüsst zwaer nicht wozu man das brauchen könnte aber isn netter effekt

[public]

hiern bsp...

[public]

so hier noch ne version ohne die filter klassen also funktioniert auch mit flash 7

klasse:

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;
class de.FlashLight {
    public var onRun:Function;
    public var onFinish:Function;
    public var isRun:Boolean;
    private var c:Color;
    private var to:Object;
    function FlashLight () {
    }
    private function setBrightness (target:Object, brightness:Number):Void {
        this.c = new Color (target);
        this.to = {ra:100, rb:brightness, ga:100, gb:brightness, ba:100, bb:brightness, aa:100, ab:brightness};
        this.c.setTransform (to);
    }

    public function run (target:Object, time:Number, power:Number, useSeconds:Boolean, callBack:Function):Void {
        this.onRun ();
        this.isRun = true;
        var time2:Number = time * 6;
        var ref:FlashLight = this;
        var to:Object = {};
        var tween:Tween = new Tween (to, "_brightness", Strong.easeOut, 0, power, time, useSeconds);
        tween.onMotionChanged = function () {
            ref.setBrightness (target, to._brightness);
        };
        tween.onMotionFinished = function () {
            var tween2:Tween = new Tween (to, "_brightness", Strong.easeOut, power, 0, time2, useSeconds);
            tween2.onMotionChanged = function () {
                ref.setBrightness (target, to._brightness);
            };
            tween2.onMotionFinished = function () {
                callBack ();
                ref.onFinish ();
                ref.isRun = false;
                delete ref.to;
            };
        };
    }
} 


bsp:

PHP-Code:

import de.FlashLight;
var fl:FlashLight = new FlashLight ();
onMouseDown = function () {
    fl.run(test_mc,.1,220,true);
}; 


[hgseib]

oder so

_mc.onRelease = function()
{ var _color = new Color(this);
  var p = 100+150, _speed = 5;
  this.onEnterFrame = function()
  { _color.setTransform({rb:p, gb:p, bb:p});
    if ((p -= _speed)<0) delete this.onEnterFrame;
}; };

[public]

*g* oder so gehts natürlich ooch...