[stuff] asfunction (AS2) und TextEvent (AS3) im einsatz

[salazar]

hi,
weil das thema immer wieder angefragt wird hier eine kleine sammlung an beispielen wie man aus einem dynamisch befüllten textfeld eine function in seinem script aufrufen kann.

zum testen einfach eine neue fla (entsprechend AS2/AS3) erstellen und einen der folgenden bsp. codes einfügen.

bsp1 ( AS2: ruft die function "asfunctionListener" auf und übergibt den parameter "http://www.flashforum.de" ):

PHP-Code:

var deinText:String = 'Das ist ein Testlink: <a href="asfunction:asfunctionListener,http://www.flashforum.de\">"HIER KLICKEN"</a>';

var deinTextFeld:TextField = this.createTextField( "deinTextFeld", this.getNextHighestDepth(), 0, 0, 500, 200 );
    deinTextFeld.html = true;
    deinTextFeld.htmlText = deinText;
    
function asfunctionListener( link:String ):Void {
    
    trace( "asfunctionListener link:   " + link );
    
    //getURL( link, "_blank" );
    
} 


hierbei werden der funktionsname und der parameter durch ein "," getrennt: "asfunctionListener,http://www.flashforum.de"
auf diese weise kann nur EIN parameter übertragen werden. wie man trotzdem mehrere params übergeben kann, dazu später mehr.

bsp2 ( AS3: ruft die function "textEventListener" auf und übergibt den parameter "http://www.flashforum.de" ):

PHP-Code:

var deinText:String = 'Das ist ein Testlink: <a href="event:http://www.flashforum.de">"HIER KLICKEN"</a>';

var deinTextFeld:TextField = new TextField();
    deinTextFeld.width = 500;
    deinTextFeld.height = 200;
    deinTextFeld.htmlText = deinText;
    deinTextFeld.addEventListener( TextEvent.LINK, textEventListener );
    
addChild( deinTextFeld );

function textEventListener( e:TextEvent ):void {

    trace( "textEventListener link:   " + e.text );
    
    //navigateToURL( new URLRequest( e.text ), "_blank" );
    
} 


das bsp erklärt sich fast von selbst. wenn man einen parameter übregeben möchte gibt man einfach dem event einen string mit: "event:http://www.flashforum.de"

und hier noch zwei beispiele in denen 2 parameter übergeben werden.

bsp3 ( AS2: ruft die function "asfunctionListener" auf und übergibt die parameter "http://www.flashforum.de" und "_blank" ):

PHP-Code:

var deinText:String = 'Das ist ein Testlink: <a href="asfunction:asfunctionListener,http://www.flashforum.de,_blank\">"HIER KLICKEN"</a>';

var deinTextFeld:TextField = this.createTextField( "deinTextFeld", this.getNextHighestDepth(), 0, 0, 500, 200 );
    deinTextFeld.html = true;
    deinTextFeld.htmlText = deinText;
    
function asfunctionListener( parameter:String ):Void {

    var args:Array = parameter.split( "," );
    
    var link:String   = args[ 0 ];
    var target:String = args[ 1 ];
    
    trace( "asfunctionListener link:     " + link );
    trace( "asfunctionListener target:   " + target );
    
    //getURL( link, target );
    
} 


bsp4 ( AS3: ruft die function "textEventListener" auf und übergibt die parameter "http://www.flashforum.de" und "_blank" ):

PHP-Code:

var deinText:String = 'Das ist ein Testlink: <a href="event:http://www.flashforum.de,_blank">"HIER KLICKEN"</a>';

var deinTextFeld:TextField = new TextField();
    deinTextFeld.width = 500;
    deinTextFeld.height = 200;
    deinTextFeld.htmlText = deinText;
    deinTextFeld.addEventListener( TextEvent.LINK, textEventListener );
    
addChild( deinTextFeld );

function textEventListener( e:TextEvent ):void {

    var args:Array = e.text.split( "," );
    
    var link:String   = args[ 0 ];
    var target:String = args[ 1 ];
    
    trace( "textEventListener link:     " + link );
    trace( "textEventListener target:   " + target );

    //navigateToURL( new URLRequest( e.text ), "_blank" );
    
} 


viel spaß damit. ich hoffe das hilft dem ein oder anderen weiter.

cheers,
sal

[salazar]

der vollständigkeit halber...
ohne parameter:

bsp5 ( AS2: ruft die function "asfunctionListener" auf ):

PHP-Code:

var deinText:String = 'Das ist ein Testlink: <a href="asfunction:asfunctionListener\">"HIER KLICKEN"</a>';

var deinTextFeld:TextField = this.createTextField( "deinTextFeld", this.getNextHighestDepth(), 0, 0, 500, 200 );
    deinTextFeld.html = true;
    deinTextFeld.htmlText = deinText;
    
function asfunctionListener():Void {

    trace( "asfunctionListener" );
    
} 


bsp6 ( AS3: ruft die function "textEventListener" auf ):

PHP-Code:

var deinText:String = 'Das ist ein Testlink: <a href="event:">"HIER KLICKEN"</a>';

var deinTextFeld:TextField = new TextField();
    deinTextFeld.width = 500;
    deinTextFeld.height = 200;
    deinTextFeld.htmlText = deinText;
    deinTextFeld.addEventListener( TextEvent.LINK, textEventListener );
    
addChild( deinTextFeld );

function textEventListener( e:TextEvent ):void {

    trace( "textEventListener" );
    
} 


cheers,
sal

[salazar]

und hier noch 2 varianten für beliebig viele parameter..

bsp7 ( AS2: ruft die function "asfunctionListener" auf und übergibt X parameter ):

PHP-Code:

var deinText:String = 'Das ist ein Testlink: <a href="asfunction:asfunctionListener,http://www.flashforum.de,_blank,param3,param4,paramX\">"HIER KLICKEN"</a>';

var deinTextFeld:TextField = this.createTextField( "deinTextFeld", this.getNextHighestDepth(), 0, 0, 500, 200 );
    deinTextFeld.html = true;
    deinTextFeld.htmlText = deinText;
    
function asfunctionListener( parameter:String ):Void {

    var args:Array = parameter.split( "," );

    for ( var string:String in args ) {
        
        trace( "asfunctionListener paramt" + string + ": " + args[ string ] );
        
    }

} 


bsp8 ( AS3: ruft die function "textEventListener" auf und übergibt X parameter):

PHP-Code:

var deinText:String = 'Das ist ein Testlink: <a href="event:http://www.flashforum.de,_blank,param3,param4,paramX">"HIER KLICKEN"</a>';

var deinTextFeld:TextField = new TextField();
    deinTextFeld.width = 500;
    deinTextFeld.height = 200;
    deinTextFeld.htmlText = deinText;
    deinTextFeld.addEventListener( TextEvent.LINK, textEventListener );
    
addChild( deinTextFeld );

function textEventListener( e:TextEvent ):void {

    var args:Array = e.text.split( "," );

    for ( var string:String in args ) {
        
        trace( "asfunctionListener paramt" + string + ": " + args[ string ] );
        
    }
    
} 


cheers,
sal

[zerlettino]

funktioniert lustigerweise auch mit statischen Textfeldern- zumindest mit AS3 / CS4