[Stuff] AS2 Flash-Tron 1658Byte

[michael]

ok, ist schon ein weilchen her, meine ersten as2 gehversuche quasi, der code kriegt also schonmal keinen schönheitspreis.


vieleicht hat ja trotzdem jemand spass dran.

wir brauchen eine Datei TronCycle.as

class TronCycle
{
    var map:Array;
    var base:MovieClip;
    var keys:Object;
    var speed:Number;
    var dir:Object;
    var pos:Object;
    var col:Number;
    var raster:Number;
    var gameItv:Number;
    var points:Number = 0;
    var n:Number = 1;
    var onDead:Function;
    public function TronCycle (base, map, raster, speed, color)
    {
        this.base = base;
        this.map = map;
        this.raster = raster;
        this.speed = speed;
        this.col = color;
    }
    public function startCycle (sx, sy, dx, dy, keys):Void
    {
        this.pos = {x:sx, y:sy};
        this.dir = {x:dx, y:dy};
        this.keys = keys;
        if (this.keys)
        {
            Key.addListener (this);
        }
        this.base.clear ();
        clearInterval (this.gameItv);
        this.base.lineStyle (1, col);
        this.base.moveTo (sx * this.raster, sy * this.raster);
        this.gameItv = setInterval (this, "mapPos", speed);
    }
    public function stopCycle ():Void
    {
        clearInterval (this.gameItv);
        Key.removeListener (this);
    }
    private function onKeyDown ():Void
    {
        if (Key.isDown (this.keys.right) && this.dir.x != -1)
        {
            this.dir.x = 1;
            this.dir.y = 0;
        }
        else if (Key.isDown (this.keys.left) && this.dir.x != 1)
        {
            this.dir.x = -1;
            this.dir.y = 0;
        }
        else if (Key.isDown (this.keys.up) && this.dir.y != 1)
        {
            this.dir.x = 0;
            this.dir.y = -1;
        }
        else if (Key.isDown (this.keys.down) && this.dir.y != -1)
        {
            this.dir.x = 0;
            this.dir.y = 1;
        }
    }
    private function mapPos ():Void
    {
        var x = this.pos.x += this.dir.x;
        var y = this.pos.y += this.dir.y;
        if (!this.keys)
        {
            this.autoDrive (x, y);
        }
        this.setLine (x, y);
    }
    private function autoDrive (x, y):Void
    {
        if (this.map[y + this.dir.y][x + this.dir.x] != 0)
        {
            if (this.dir.y == 0)
            {
                this.dir.x = 0;
                if (map[y + 1][x] != 0)
                {
                    this.dir.y = -1;
                }
                else if (this.map[y - 1][x] != 0)
                {
                    this.dir.y = 1;
                }
                else
                {
                    this.dir.y = (Math.round (Math.random ())) ? 1 : -1;
                }
            }
            else if (this.dir.x == 0)
            {
                this.dir.y = 0;
                if (this.map[y][x + 1] != 0)
                {
                    this.dir.x = -1;
                }
                else if (map[y][x - 1] != 0)
                {
                    this.dir.x = 1;
                }
                else
                {
                    this.dir.x = (Math.round (Math.random ())) ? 1 : -1;
                }
            }
        }
    }
    private function setLine (x, y)
    {
        if (this.map[y][x] == 0)
        {
            this.base.lineTo (x * this.raster, y * this.raster);
            this.points += 1;
            this.map[y][x] = 1;
        }
        else
        {
            this.onDead ();
            this.stopCycle ();
        }
    }
} 

und eine leere fla (420 x 350px dunkler hintergrund)

/***********************
*  Flashtron by michael kneib
*  listen(at)kneib.biz
*/
 
function mapArray (yl, xl):Array
{
    var temp = [];
    for (var y = 0; y < yl; y++)
    {
        temp[y] = [];
        for (var x = 0; x < xl; x++)
        {
            temp[y][x] = 0;
        }
    }
    return temp;
}
function reset ():Void
{
    var map:Array = mapArray (75, 100);
    with (this.createEmptyMovieClip ("feld", 1))
    {
        _x = 10;
        _y = 25;
        lineStyle (2, 0xFFFFFF);
        moveTo (-raster, -raster);
        lineTo (-raster, map.length * 4);
        lineTo (map[0].length * raster, map.length * raster);
        lineTo (map[0].length * raster, -raster);
        lineTo (-raster, -raster);
    }
    status_txt.text = "";
    tron1.stopCycle ();
    tron3.stopCycle ();
    tron4.stopCycle ();
    tron5.stopCycle ();
    tron2.stopCycle ();
    tron1 = new TronCycle (feld.createEmptyMovieClip ("c1", 1), map, raster, 40, colors[0]);
    tron2 = new TronCycle (feld.createEmptyMovieClip ("c2", 2), map, raster, 42, colors[1]);
    tron3 = new TronCycle (feld.createEmptyMovieClip ("c3", 3), map, raster, 43, colors[2]);
    tron4 = new TronCycle (feld.createEmptyMovieClip ("c4", 4), map, raster, 44, colors[3]);
    tron5 = new TronCycle (feld.createEmptyMovieClip ("c5", 5), map, raster, 45, colors[4]);
    tron1.startCycle (20, 10, 0, 1);
    tron2.startCycle (40, 10, 0, 1);
    tron3.startCycle (60, 10, 0, 1);
    tron4.startCycle (50, 65, 0, -1, {up:38, down:40, left:37, right:39});
    tron5.startCycle (80, 10, 0, 1);
    tron4.onDead = function ()
    {
        status_txt.text = "Oops!\nPress \"R\" for Restart";
    };
}
var raster = 4;
var colors = [0xFFFF99, 0x9999FF, 0x99FF99, 0xFF0000, 0xFF9999];
var tf:TextFormat = new TextFormat ();
tf.align = "center";
tf.bold = true;
tf.color = 0xFFFFFF;
this.createTextField ("status_txt", 9, 150, 150, 120, 50);
this.status_txt.setNewTextFormat (tf);
this.status_txt.text = "Press \"R\" for Restart";
var obj:Object = new Object ();
obj.onKeyDown = function ()
{
    if (Key.isDown (82))
    {
        reset ();
    }
};
Key.addListener (obj); 

viel spass beim erweitern oder verbessern.
wenn ich sehe mit wie wenig code andere raycasting-engines schreiben, geht das hier bestimmt um einiges kürzer.

interessanterweise erzeugt die simple autoDrive-methode exact das fahrverhalten wie das java-tron auf meinem handy


have fun

gruß
michael

[Gnut]

gut gemacht
Ich hab's nicht getestet und weiss auch nicht was das ist

[jschum2s]

gefällt mir auch gut...danke.

noch ne bitte. Gibts da vielleicht was zu klicken? Habe Probleme beim code kopieren wenn er zu lang ist. ne kleine zip Datei wäre schick.

cheers,

Jens

[michael]

oh, ja klar

so siehts aus (in den flashfilm klicken um focus zu setzen)

zip im anhang.

gruß
michael

[bokel]

Das ist ja ein cooles Spiel. Ich kannte Tron ja schon als Film, aber das Spiel noch nicht.

mfg r.

[querkopf]

*seufz* die gute alte Zeit...
weiß noch wie ich das basic-tron früher endlos lang gezockt hab'.... immer mit Kumpels... bis zu 6 an einer tastatur (!)... das war richtig cool, das war ein wahres Multiplayerspiel

mir fehlt jetzt nur noch das "sie haben gewonnen" sobald man alle anderen ausgeschaltet hat...

[flory]

wenn man mehrmals "R" drückt sieht es sehr abgefahren aus

[querkopf]

ui cool... sobald man dann bereits in eine Richtung gedrückt hat kann man schöne Formen machen

[michael]

mist, lol

ok, bug notdürftig beseitigt und zip, script, beispiel aktualisiert

[querkopf]

jo, cool.

manchmal kommt es mir so vor, als ob die Kollision zu früh wär'.... also ein gutes Stück vor dem Gegner, der Wand, ... komisch.
Kann aber auch sein, daß ich einfach nur zuuuu langsam bin

[warrantmaster]

goil..

[nky]

wie fett !

ichs mal versucht in mx zu scripten....
hab dann aber aufgrund zeit nie weiter gemacht ....

find ich richtig cool

Gruss nky

[r0b]

Hm...

Ich glaube die vier Gegner cheaten... die lassen immer nur einen Pixel Abstand zur Wand. Ich krieg' das nie so hin.

Aber ein sehr nettes Game. Gut, Knut.

[bort]

Sehr sehr cool!!!

Jau, wir haben das früher auch immer zu sechst am C64 gedaddelt. Ein nettes Feature war damals, dass man durch die "Löcher" die andere durch crash in die Außenwand hinterlassen haben, "escapen" konnte - das gab dann extra Punkte. Genauso gab es Punkte, wenn man einen anderen Mitspieler auf dem Gewissen hatte

Ich hab das 2000 mal als Shockwave (also Director) nachgebaut. Link: http://www.crash.de/bort/shock/tron.html

Das mit dem "escapen" wär doch ein nettes add-on, oder gutknut?

8-Bit forever!

Gruß,
bort.

[madflanderz]

goil