newsticker

[_kweso]

hier fuer mauri2006 und alle anderen mein newsticker-script:

Stage.scaleMode = "noScale";
Stage.align = "TL";
Stage.showMenu = false;
mcNTBG._width = Stage.width;
var stageListener:Object = new Object();
stageListener.onResize = function() {
    mcNTBG._width = Stage.width;
    txtScroll();
};
Stage.addListener(stageListener);
var scrolltext:String;
if(!st){
    scrolltext = "dummietext";
}else{
    scrolltext = st;
}
var aTextinst:Array = new Array();
var nXValue:Number = 0;
var nXValue2:Number = 0;
var nIID:Number;
var tfFormat:TextFormat = new TextFormat();
tfFormat.font = "verdana";
tfFormat.size = 26;
tfFormat.color = 0xffffff;
tfFormat.letterSpacing  = 1;
tfFormat.kerning = true;
function moveTxt():Void {
    for(values in aTextinst){
        aTextinst[values]._x -= 1;
        if(aTextinst[values]._x < -(aTextinst[values]._width)){
            aTextinst[values]._x = nXValue2;
        }
    }
}
function txtScroll() {
    clearInterval(nIID);
    nXValue = 0;
    nXValue2 = 0;
    aTextinst = [];
    for (item in this){
        if(this[item]._name.indexOf("tScroller") == 0){
            trace("name: "+this[item]._name);
            this[item].removeTextField();
        }
    }
    while (nXValue2 < Stage.width){
        var tScroll:TextField = this.createTextField("tScroller"+nXValue, this.getNextHighestDepth(), nXValue, -4, 10, 10)
        tScroll.setNewTextFormat(tfFormat);
        tScroll.text = scrolltext.toUpperCase()+" ** ";
        tScroll.autoSize = "left";
        nXValue += Math.ceil(tScroll._width);
        nXValue2 = nXValue - Math.ceil(tScroll._width);
        aTextinst.push(tScroll);
    }
    
    nIID = setInterval(this, "moveTxt", 30);
}
txtScroll(); 

mcNTBG ist einfach eine grafik, die man hinter den newsticker legt. koennt man sicher auch mit draw-fuctions machen. und "st", also der eigentliche text, wird per flashvars uebergeben...
viel spass

[mauri2006]

Danke für das Script
Ich fand den Newsticker klasse und da musste ich einfach
mal nachfragen. Kann man auch irgendwo die Geschwindigkeit verändern?

Edit//: Irgendwie kapier ich das nicht. Kannst du mal ein Beispiel anhängen?
Ich kapiere das nicht wie man da den Text zum vorschein bringt o.O

[DirtDevil]

ich habs ehrlich gesagt nicht probiert aber ich gehe schwer davon aus das

nIID = setInterval(this, "moveTxt", 30);

die geschwindigkeit beeinflusst.
kleine zahl = schnell
grosse zahl = langsam

[_kweso]

du musst wahrscheinlich nur die farbe des textes (tfFormat.color = 0xffffff oder deiner stage aendern. weiss auf weiss ist nicht so gut lesbar...
die geschwindigkeit kann man mit
aTextinst[values]._x -= 1;
bzw mit:
nIID = setInterval(this, "moveTxt", 30);
aendern
lg
kws

[mauri2006]

Wie kann man den Ticker auch Anti-Aliased machen? ^^