Lade Animation

[Lukas78]

Ich weiß sowas gibt es bestimmt schon zu hauf, wollte es selber ausprobieren, und euch teilhaben lassen.

Klassische LadeAnimationsKlasse, die, wie ich finde, relativ einfach und schnell angepasst werden kann.

PHP-Code:

package
{
    import flash.display.MovieClip;
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.events.Event;

    public class LoadingCircle extends MovieClip
    {
        public static const CIRCLE        :uint = 0;
        public static const RECTANGLE    :uint = 1;
        
        private var _main    :Sprite    = new Sprite(); 
        private var _step    :Number;
        private var _slow    :Boolean;
        private var _delay    :uint;
        private var _curDel    :uint    = 0;
        
        public function LoadingCircle( type:uint = CIRCLE, color:uint = 0x333333, count:uint = 8, radius:uint = 12, size:uint = 4, aspectRatio:Number = 5, slow:Boolean = false, delay:uint = 2)
        {
            _slow    = slow;
            _delay    = delay;
            _step     = 360 / count;
            for(var i:uint = 0; i < count; i++ )
            {
                var sub:Shape = new Shape();
                sub.graphics.beginFill( color, i/count);
                switch(type)
                {
                    case RECTANGLE:
                        sub.graphics.drawRect( -size/2, -( radius + size * aspectRatio), size, size * aspectRatio);
                        break;
                    case CIRCLE:
                        sub.graphics.drawCircle( 0, -radius, size);        
                        break;
                }
                sub.graphics.endFill();
                sub.rotation = i * _step;
                _main.addChild( sub);
            }
            this.addEventListener(Event.ENTER_FRAME, rotateCircle);
            this.addChild( _main);
        }
        
        private function rotateCircle( e:Event):void
        {
            if(_slow)
            {
                _curDel++;    
                if( ! ( _curDel < _delay) )
                {
                    _main.rotation += _step;
                    _curDel = 0;
                }
            }
            else
            {
                _main.rotation += _step;
            }
        }
    }
} 


Ist beschämender weise unkommentiert, aber das meiste sollte denke ich klar sein.

Hätte zufällig jemand eine Idee, wie man innerhalb dieser Struktur einzelne Ringelemente realisieren könnte?

[bobo_k1]

nicht schlecht -