Inertia Movements

[figure8]

hi,
ich weiß nicht, ob´s sowas schon hier gibt, aber jedenfalls hab ich zwei snippets für "je weiter du mit der maus nach links gehst, desto schneller bewegt sich der clip darunter nach rechts" gebastelt - kennt man aus vielen thumbnail-galerien oder navigationen. da dazu ein bißchen text (auf englisch) gehört, poste ich einfach mal den direkten link und nur das script:

Two Inertia Movements | Beautify Code Blog


Endlos:

var xCenter:int = thumbMask.width/2;
var acc:Number;
 
clipContainer.addEventListener(MouseEvent.ROLL_OVER, onClipRoll);
clipContainer.addEventListener(MouseEvent.ROLL_OUT, onClipRoll);
 
function onClipRoll(event:MouseEvent):void {
    if(event.type == MouseEvent.ROLL_OVER) clipContainer.addEventListener(Event.ENTER_FRAME, moveContainer);
    else clipContainer.removeEventListener(Event.ENTER_FRAME, moveContainer);
}
 
function moveContainer(event:Event):void {
    acc = thumbMask.mouseX < xCenter ? xCenter-thumbMask.mouseX : -(thumbMask.mouseX-xCenter);
    clipContainer.x += acc * 0.05;
} 

begrenzt und langsamer werden:

var leftLimit:int = 0;
var rightLimit:int = -245;
 
var thumbWidth:Number = thumbMask.width;
 
var xRef:Number;
var xConv:Number;
 
clipContainer.addEventListener(MouseEvent.ROLL_OVER, onClipRoll);
clipContainer.addEventListener(MouseEvent.ROLL_OUT, onClipRoll);
 
function onClipRoll(event:MouseEvent):void {
    if(event.type == MouseEvent.ROLL_OVER) clipContainer.addEventListener(Event.ENTER_FRAME, moveContainerBySlow);
    else clipContainer.removeEventListener(Event.ENTER_FRAME, moveContainerBySlow);
}
 
function moveContainerBySlow(evt:Event):void {
    xRef = -thumbMask.mouseX + thumbWidth / 2;
    xConv = (xRef - clipContainer.x) * 0.01;
   
    clipContainer.x += xConv;
 
    // cliplimits
    if (clipContainer.x>= leftLimit) clipContainer.x = leftLimit;
    if (clipContainer.x <= rightLimit) clipContainer.x = rightLimit;
} 

oder hier im forum: navigation

[mildesign]

Schönes snippet. Hab es noch nicht getestet aber ich würde noch

PHP-Code:

if(event.type == "rollOver") 


durch

PHP-Code:

if(event.type == MouseEvent.ROLL_OVER) 


ersetzen.
Das ist irgendwie konsequenter als einmal mit Konstante und dann wieder mit Strings zu arbeiten ;o)

[figure8]

oh, jau - stimmt. wird geändert, danke

[figure8]

so, falls es wen interessiert: es ist eine kleine demo vom script online (link siehe oben).