[AS2] attach/create Funktion mit Eintrag in Array

[regsnerven]

Hallo Leute,

ich habe mir gerade eine eigene Funktion für die Erstellung von MCs gebaut. Sie unterstützt "createEmptyMovieClip" und "attachMovieClip". Natürlich werdet ihr jetzt sagen: "Wieso brauch ich das? Dafür gibt es doch schon Funktionen." Ja, das ist richtig, aber ich brauchte etwas, das die MCs auch in einen Array einfügt, wenn ich das möchte, damit ich sie nachher ohne großen Aufwand wieder mit einer Schleife von der Bühne schmeißen kann.
Also hier der Code

Die Funktion an sich:

inhalt = new Array(); //Diese Variable dient dazu die MCs zu sammeln und muss vorhanden sein
 
MovieClip.prototype.newMC = function (methode: String, essential: Boolean, idName: String, neuerName: String, depth, initObject: Array){ 
    
    if (methode == "attach"){
        trace(methode);
        if (essential != true){
            inhalt.push(this.attachMovie(idName, neuerName, depth, initObject));
            result = inhalt[inhalt.length-1];
        }
        else{
            result = this.attachMovie(idName, neuerName, depth, initObject);
        }
        
        return result;
    }
    
    if (methode == "create"){
        trace(methode);
        depth2 = Number(neuerName);
        if (essential != true){
            inhalt.push(this.createEmptyMovieClip(idName, depth2));
            result = inhalt[inhalt.length-1];
        }
        else{
            result = this.createEmptyMovieClip(idName, depth2);
        }
        for (i in depth){
            result[i] = depth[i];
        }
        return result;
    
    }
} 

Ihr seht ja schon, dass sie eigentlich genau so funktioniert, wie die von Flash zu Verfügung gestellten Funktionen.
Der Unterschied liegt einfach daran, dass ihr MCs bestimmen könnt, die bei einem Durchlauf von "inhalt" von der Bühne entfernt sollen. Dazu setzt ihr einfach "essential" auf false. Sollte "essential" auf true gesetzt sein, so wird der MC, der erstellt oder attached wird, nicht in den Array "inhalt" eingefügt. Das heißt aber auch, dass ihr ihn ggf. manuell entfernen müsst oder einen weiteren Array einführt, in dem diese MCs gesammelt werden.
Zudem bietet diese Funktion die Möglichkeit neu erstellten MCs (createEmptyMovieClip) gleich Eigenschaften zuzuweisen, wenn ihr dies für nötig haltet. Hat auch nicht jeder


Der für einen NEU ERSTELLTEN Mc:

newMC("create", false, "neuer_mc", this.getNextHighestDepth(), { _x: 200, _y: 500}); 

Der für einen AUS DER BIBLIOTHEK geladenen Mc:

newMC("attach", false, "libary_link", "neuer_mc", this.getNextHighestDepth(), {_width: 100, _height: 100, _x: 50, _y: 50}); 

Für Verbesserungsvorschläge und Kritik (ob positiv oder negativ) bin ich immer offen.


Gr33tZ
Rn

[readme.txt]

Prinzipiell keine schlechte Idee ... aber wär nicht ne Klasse schöner?

[regsnerven]

Klasse xD mach mal :P

Ne, find ich gut mit der Klasse. Ich hab nur leider keine Ahnung, wie das bei AS mit den Klassen genau funzt.
Kannst da ja gerne ne Klasse draus machen

Ich frage mich nur, ob das für nur eine Funktion so viel Sinn macht. Also meiner Erfahrung nach sind Klassen eigentlich eher so Übersichtlichkeitsding, also man lagert darin alle Funktionen eines "Themas" aus und verliert so nicht die Übersicht in einem 10km-Code. Oder hab ich was übersehen? ^^

[RustyCake]

Bisschen verwirrend das "depth2"--> "NeuerName" ist

[regsnerven]

Ja, ging halt nicht anders. Wollte nicht, dass man dann leere Parameter übergeben muss.
Kann man ja noch ändern, also den Namen der Variable xD

[regsnerven]

Kleines Update, da so der Zugriff auf die MCs im Inhalt-Array besser gewährleistet wird.

MovieClip.prototype.newMC = function (methode: String, essential: Boolean, idName: String, neuerName: String, depth, initObject: Array){
    
    if (methode == "attach"){
        if (essential != true){
            inhalt[neuerName] = this.attachMovie(idName, neuerName, depth, initObject);
            result = inhalt[neuerName];
        }
        else{
            essential_array[neuerName] = this.attachMovie(idName, neuerName, depth, initObject);
            result = essential_array[neuerName];
        }
        return result;
    }
    
    if (methode == "create"){
        depth2 = Number(neuerName);
        if (essential != true){
            inhalt[idName]  = this.createEmptyMovieClip(idName, depth2);
            result = inhalt[idName];
        }
        else{
            essential_array[idName] = this.createEmptyMovieClip(idName, depth2);
            result = essential_array[idName];
        }
        
        for (i in depth){
            result[i] = depth[i];
        }
        return result;
    
    }
} 

[McMannus]

Die Klasse könnte zum Beispiel so aussehen. parentMC ist der MovieClip, in den der neu erstellte MovieClip attached oder created wird...

class MovieClipContainer {
    private var inhalt:Array;
 
    function MovieClipContainer() {
        inhalt = new Array();
    }
    
    public function attachMC(essential:Boolean, parentMC:MovieClip, idName:String, newName:String, depth:Number, initObject:Object):MovieClip {
        var mc:MovieClip;
        if (essential != true) {
            mc = inhalt[newName] = parentMC.attachMovie(idName, newName, depth, initObject);
        } else {
            mc = parentMC.attachMovie(idName, newName, depth, initObject);
        }
        return mc;
    }
    
    public function createMC(essential:Boolean, parentMC:MovieClip, newName:String, depth:Number):MovieClip {
        var mc:MovieClip;
        if (essential != true) {
            mc = inhalt[newName] = parentMC.createEmptyMovieClip(newName, depth);
        } else {
            mc = parentMC.createEmptyMovieClip(newName,depth);
        }
        return mc;
    }
    
    //Löscht alle MovieClips, die sich im Array befinden
    public function flush():Void {
        for (var i:String in inhalt) {
            removeMovieClip(inhalt[i]);
        }
    }
    
    //Traced die Namen aller MovieClips, die sich im Array befinden
    public function traceList():Void {
        for (var i:String in inhalt) {
            trace(i+": "+inhalt[i]);
        }
    }
} 

[regsnerven]

Ja, dnan habe ich aber wieder 2 Funktionen. Ist nicht unbedingt schlimm, aber nervig ^^

Außerdem habe ich bei deiner Ausführung keine Möglichkeit dem neu ERSTELLTEN MC Eigenschaften zu zu weisen, was bei deiner Ausführung allerdings nen bisschen leichter zu ergänzen wäre - also Umfunktionierung von Variablen.

Gr33tZ
Rn

[McMannus]

Du hast bei meiner Version genauso die Möglichkeit, den erstellten oder attachten MovieClips Eigenschaften zuzuweisen bzw. zu ändern, da du ja als Rückgabe in beiden Fällen eine Referenz auf den MovieClip erhältst, d.h. du kannst den Funktionsaufruf mit einer Variable vom Typ MovieClip gleichsetzen und an dieser Variable(=Referenz) Eigenschaften ändern.

[regsnerven]

Nein, das meine ich nicht. Schau dir meinen CREATE-Code noch einmal an.
Ich weise schon beim Funktionsaufruf die Eigenschaften zu.
Das habe ich gemeint.

[McMannus]

#
if (methode == "create"){
#
depth2 = Number(neuerName);
#
if (essential != true){
#
inhalt[idName] = this.createEmptyMovieClip(idName, depth2);
#
result = inhalt[idName];
#
}
#
else{
#
essential_array[idName] = this.createEmptyMovieClip(idName, depth2);
#
result = essential_array[idName];
#
}
#

#
for (i in depth){
#
result[i] = depth[i];
#
}
#
return result;
#

#
}

Erzähl mir mal, wo du in der Funktion dem Movieclip Eigenschaften zuweist?

[regsnerven]

for (i in depth){
 
result[i] = depth[i];
 
} 

Genau an dieser Stelle Ist ein bisschen verwirrend, weil die Variable "depth" heißt, aber naja.
Deswegen habe ich ja auch die Tiefe, die bei dem "create"-Fall in "neuerName" steht, ganz am Anfang in "depth2" geschrieben.

Gr33tZ
Rn

[McMannus]

Okay, ein wenig verwirrend, aber genau das kannst du doch in die Klasse miteinbauen.

class MovieClipContainer {
    private var inhalt:Array;
 
    function MovieClipContainer() {
        inhalt = new Array();
    }
    
    public function attachMC(essential:Boolean, parentMC:MovieClip, idName:String, newName:String, depth:Number, initObject:Object):MovieClip {
        var mc:MovieClip;
        if (essential != true) {
            mc = inhalt[newName] = parentMC.attachMovie(idName, newName, depth, initObject);
        } else {
            mc = parentMC.attachMovie(idName, newName, depth, initObject);
        }
        return mc;
    }
    
    public function createMC(essential:Boolean, parentMC:MovieClip, newName:String, depth:Number, initObject:Object):MovieClip {
        var mc:MovieClip;
        if (essential != true) {
            mc = inhalt[newName] = parentMC.createEmptyMovieClip(newName, depth);
        } else {
            mc = parentMC.createEmptyMovieClip(newName,depth);
        }
        for (var i:String in initObject) {
            mc[i] = initObject[i];
        }
        return mc;
    }
    
    //Löscht alle MovieClips, die sich im Array befinden
    public function flush():Void {
        for (var i:String in inhalt) {
            removeMovieClip(inhalt[i]);
        }
    }
    
    //Traced die Namen aller MovieClips, die sich im Array befinden
    public function traceList():Void {
        for (var i:String in inhalt) {
            trace(i+": "+inhalt[i]);
        }
    }
} 

[regsnerven]

Ja, ich weiß. Ich sagte ja nur, dass du sie vergessen hattest.
Klasse Klasse, muss ich ja schon sagen ^^

Vllt. bau ich die sogar in mein aktuelles Projekt mit ein.
Allerdings müsste ich dann mein Skript wieder komplett umschreiben, weil ich ja mit meiner Funktion newMC "attachMovie" und "createEmptyMovieClip" in einer Funktion vereine.

Egal. ^^

Ich hab noch 2 neue Funktionen für die Klasse..muss nur mal gerade die Zeilenangaben löschen....

Array.prototype.in_array = function(searchFor) {
   // andr3a [ 25 / 03 / 2004 ]
   // check if a value is inside an array
   for( var a = 0; a < this.length; a++ ) {
      if( this[a] == searchFor ) {
         return true;
      }
      else if( this[a] instanceof Array ) {
         return this[a].in_array(searchFor);
      }
   }
   return false;
}
 
//Prototypes nicht als Eigenschaften der Arrays anzeigen
ASSetPropFlags(Array.prototype,['in_array'],1,1);
 
class MovieClipContainer {
    private var inhalt:Array;
    
    function MovieClipContainer() {
      inhalt = new Array();
    }
    
    
    public function attachMC(essential:Boolean, parentMC:MovieClip, idName:String, newName:String, depth:Number, initObject:Object):MovieClip {
        var mc:MovieClip;
        
        if (essential != true) {        
            mc = inhalt[newName] = parentMC.attachMovie(idName, newName, depth, initObject);
        } else {
        mc = parentMC.attachMovie(idName, newName, depth, initObject);
        }
        return mc;  
    }
    
    
    public function createMC(essential:Boolean, parentMC:MovieClip, newName:String, depth:Number, initObject:Object):MovieClip {
    var mc:MovieClip;
        
        if (essential != true) {
            mc = inhalt[newName] = parentMC.createEmptyMovieClip(newName, depth);
        } else {
            mc = parentMC.createEmptyMovieClip(newName,depth);
        }
        
        for (var i:String in initObject) {
            mc[i] = initObject[i];
        }
        return mc;    
    }
    
    
    
    //Löscht alle MovieClips, die sich im Array befinden
    public function flush():Void {  
        for (var i:String in inhalt) {  
            removeMovieClip(inhalt[i]);
        }   
    }
    
    //Löscht bestimmte MovieClips und dessen "Eintrag" aus dem Array
    public function removeMCs(mc_names:Array){
        for (var mc:String in mc_names){
            removeMovieClip(inhalt[mc_names[mc]]);
            delete inhalt[mc_names[mc]];
        }
    }
    
    //Löscht alle MovieClips und dessen "Einträge" außer den angegebenen aus dem Array
    public function keepMCs(mc_names:Array){
        for (var mc:String in inhalt){
            if(!mc_names.in_array(mc)){
                removeMovieClip(inhalt[mc]);
                delete inhalt[mc];
            }
        }
    }
    
    
    //Traced die Namen aller MovieClips, die sich im Array befinden
    public function traceList():Void {
        for (var i:String in inhalt) {
            trace(i+": "+inhalt[i]);
        }   
    }
} 

Ich weiß nicht, ob der Prototype mit in die Klasse soll oder wo sonst hin ^^ Arbeite nicht so oft-gar nicht mit Klassen.


Gr33tZ
Rn