sudoku regeln

[Match_Boxer]

hi,

ich steh mal wieder aufm schlauch

ich muss eine sudoku variante machen die auch im prinzip dieselben regeln hat.
ist auch schon ziemlich fertig und funktioniert soweit. doch bei der abfrage ob die position gültig, also die selbe Zahl in der selben reihe, zeile oder 3x3Box bereits existiert! ich hab ein 2dimensionales fieldArray das die jeweiligen spielsteine (tiles) enthält.
hier frage ich die zeilen und die reihen ab, aber wie mach ich das am besten für die 3x3Boxen?

PHP-Code:

function isValidMove(row:int,col:int,nr:int)
        {
            MonsterDebugger.trace(this, fieldArray);

            if (nr == 0)
            {
                return true;
                trace("Joker is always valid");
            }
            //compare rows and colums
            for (var i:uint=0; i<fieldLength; i++)
            {

                if (fieldArray[row][i].number == nr)
                {
                    trace("nr exists in row");
                    takeLive();
                    return false;
                }

                if (fieldArray[i][col].number == nr)
                {
                    trace("nr exists in colum");
                    takeLive();
                    return false;
                }
            }

            return true;
        } 


EDIT: hab jetzt doch was gefunden, hab an sowas in der richtung auch schon gedacht.
in der Tile klasse beim platziern festlegen wie die startwerte der reihen und zeilen der jeweiligen box sind. und es funktioniert auch.aber geht das nicht einfacher?

PHP-Code:

// Work out what region this cell is in
        if(y < 3) // Region 1, 2 or 3
        {
                if(x < 3)
                {
                        this.Region = 1;
                        this.RegionRowStart = 0;
                        this.RegionColStart = 0;
                }
                else if(x >= 3 && x < 6)
                {
                        this.Region = 2;
                        this.RegionRowStart = 3;
                        this.RegionColStart = 0;
                }
                else if(x >= 6)
                {
                        this.Region = 3;
                        this.RegionRowStart = 6;
                        this.RegionColStart = 0;
                }
        }
        else if(y >= 3 && y < 6) // Region 4, 5 or 6
        {
                if(x < 3)
                {
                        this.Region = 4;
                        this.RegionRowStart = 0;
                        this.RegionColStart = 3;
                }
                else if(x >= 3 && x < 6)
                {
                        this.Region = 5;
                        this.RegionRowStart = 3;
                        this.RegionColStart = 3;
                }
                else if(x >= 6)
                {
                        this.Region = 6;
                        this.RegionRowStart = 6;
                        this.RegionColStart = 3;
                }
        }
        else if(y >= 6) // Region 7, 8 or 9
        {
                if(x < 3)
                {
                        this.Region = 7;
                        this.RegionRowStart = 0;
                        this.RegionColStart = 6;
                }
                else if(x >= 3 && x < 6)
                {
                        this.Region = 8;
                        this.RegionRowStart = 3;
                        this.RegionColStart = 6;
                }
                else if(x >= 6)
                {
                        this.Region = 9;
                        this.RegionRowStart = 6;
                        this.RegionColStart = 6;
                }
        } 


[thomas_E]

etwas kürzer

PHP-Code:

function isValidMove(row:int, col:int, nr:int)
{
    MonsterDebugger.trace(this, fieldArray);

    if (nr == 0)
    {
        trace("Joker is always valid");
        return true;
    }
    
    //offsets
    var _r:int = 3 * Math.floor(row / 3);
    var _c:int = 3 * Math.floor(col / 3);
    
    //compare rows and colums
    for (var i:uint=0; i<fieldLength; i++)
    {
        if (fieldArray[row][i].number == nr)
        {
            trace("nr exists in row");
            takeLive();
            return false;
        }

        if (fieldArray[i][col].number == nr)
        {
            trace("nr exists in colum");
            takeLive();
            return false;
        }
        
        if (fieldArray[int(i/3) + _r][i%3 + _c].number == nr)
        {
            trace("nr exists in field");
            takeLive();
            return false;
        }
    }

    return true;
} 


und zum Thema Region (aus deinem Code):

PHP-Code:

this.region = Math.floor(row / 3) * 3 + Math.floor(col / 3) + 1; 


[Match_Boxer]

perfekt danke!!! das mit den offsets meinte ich!

den 2ten code hab ich nur direkt von einer site rauskopiert zur varanschaulichung, hab da eben nix mit region

danke danke!!!