Brauche hilfe bei Kolisionsabfrage

[-Mani]

Hi Leute,
Ich hab ein Problem!!
Ich arbeite gerade an einem RPG-Stick-Game.
Fragt mich bitte nicht was das heißt , aber ich weiß jedenfalls,dass das ein Flash-Game ist bei dem man alles von oben sieht und rummrennen kann.
Nun habe ich meinen Strichmenchen (Die Hauptfigur,mit der man rummrennen kann) den skript:

function moveobject()
{
if(Key.isDown(Key.RIGHT)){
stick._x = stick._x + 2;
}
if(Key.isDown(Key.LEFT)){
stick._x = stick._x - 2;
}
if(Key.isDown(Key.UP)){
stick._y = stick._y - 2;
}
if(Key.isDown(Key.DOWN)){
stick._y = stick._y + 2;
}
}

setInterval(moveobject,50);

gegeben.
Ich habe auch schon einen Ausschnitt von einer Stadt von oben eingefügt.
Da ich aber nicht möchte,dass das Strichmenchen einfach über alles Laufen kann dachte ich ich muss dorthin, wo das Strichmänchen nicht hinlaufen darf ein Movieclip einfügen...
Leider weiß ich nicht was für ein skript dort hinmuss.
Ich ahne zwar, dass der skript so anfangen muss

if(_root.stick.hitTest(_root.Movieclip))
....

leider hab ich keine ahnung was dann kommen muss!!

Wichtig ist noch
der Skript muss in Actionscript 1 oder 2 geschrieben sein!!!

im Vorhinein schon Tausend Dank!!!!

[salazar]

hi und willkommen im flashforum,
je nachdem was du vor hast macht es mit hitTest keinen sinn!
schau dir doch mal die tutorials auf folgenden seiten näher an. das könnt was für dich sein:
http://www.tonypa.pri.ee/tbw/
http://oos.moxiecode.com/

anbei ein bsp. script wie man das mit hitTest lösen könnte.
du wirst allerdings schnell festellen das es recht ungenau ist und zudem noch weitere nachteile mit sich bringt.

PHP-Code:

//-------------------------------------

stop();

//-------------------------------------

var stickSpeed:Number = 1;

var hitTestObjHolder:Array = new Array(wall_left, wall_right, wall_top, wall_bottom, hit1, hit2, hit3, hit4, hit5, hit6, hit7);

//-------------------------------------

function moveObject(obj:MovieClip, xDir:Number, yDir:Number):Void {
    
    obj._x += xDir;
    obj._y += yDir;

    if(getHitTest(obj)) moveObject(obj, -xDir, -yDir);
    
}

//-------------------------------------

function getHitTest(obj:MovieClip):Boolean {

    for(var str:String in hitTestObjHolder) if(obj.hitTest(hitTestObjHolder[str])) return true;
    
    return false;

}

//-------------------------------------

function getKeys():Void {
    
    if (Key.isDown(Key.RIGHT)) moveObject(stick, stickSpeed, 0);
    if (Key.isDown(Key.LEFT))  moveObject(stick, -stickSpeed, 0);
    if (Key.isDown(Key.UP))    moveObject(stick, 0, -stickSpeed);
    if (Key.isDown(Key.DOWN))  moveObject(stick, 0, stickSpeed);
    
}

//-------------------------------------

setInterval(getKeys, 1);

//------------------------------------- 


ich hab dein script einfach erweitert und weil wir im achtionscript2 bereich sind etwas mehr as2 like umgetextet.
fla und swf hab ich dir einfach mal mit dazu gepackt

cheers, sal

[-Mani]

Hey DANKE!!!!!
Du bist echt ein Spetialist

[salazar]

kein prob.
ich hab das script aber nochmal etwas optimiert...
saugste also am besten nochmal neu die files

zudem funktioniert das so im moment nur mit quadratischen formen. das bringt halt der klassische hitTest so mit sich. man könnte das ganze noch etwas verbessern wenn man mit bitmapData objects arbeitet und dort den hitTest abfragt

cheers, sal

[-Mani]

hey danke noch mal für die schnelle Hilfe!!
Hätte ja nie gedacht das ich so schnell ne Antwort bekomm!!!

Also ciao!!

[salazar]

hey ho,
ich hatte bock drauf das mit einem bitmapData hitTest auszuprobieren. das ganze läuft ganz gut. das ergebnis will ich dir nicht vorenthalten.
es gibt gleich mehrere vorteile dabei!
zum einen ist man nicht mehr drauf angewiesen nur quadratische fomen zu benutzen und zum anderen ist das ganze etwas genauer geworden...

PHP-Code:

//-------------------------------------

stop();

//-------------------------------------

import flash.display.BitmapData;
import flash.geom.Point;

//-------------------------------------

var stageHolder:MovieClip;
var moveSpeed:Number;
var hitTestObjHolder:Array;
var hitTestObjLinkIDs:Array;
var character:MovieClip;
var characterBMP:BitmapData;
var characterPoint:Point;

//-------------------------------------

function initApp():Void {
    
    stageHolder = this.createEmptyMovieClip("stageHolder", this.getNextHighestDepth());//erzeugt den movieclip in den alle anderen movieclpis abgelegt werden
    moveSpeed = 1;//die geschwindigkeit vom character. vorsicht. je hoeher die zahl, umso ungenauer ist die kollisionsabfrage!
    hitTestObjHolder = new Array();//generiert ein array in dem die bitmapData objecte abgelegt werden
    hitTestObjLinkIDs = new Array("enviPNG", "envi_objsPNG");//hier werden die bilder (verlinkungsname in der bib) eingetragen die hindernisse sein sollen

    buildPlayer("charPNG");//erzeugt den player movieclip. hier die verlinkung aus der bib mit uebergeben. pos vom player wird festgelegt
    buildHitObjs();//erzeugt die hinderniss objekte
    
    setInterval(getKeys, 1);//die tastenagfrage. 1 ist der speed. je hoeher die zahl umso langsamer ist die bewegung

}

//-------------------------------------

function buildPlayer(img:String):Void {

    characterPoint = new Point();
    characterBMP = BitmapData.loadBitmap(img);

    character = stageHolder.createEmptyMovieClip("character", stageHolder.getNextHighestDepth());
    character.attachBitmap(characterBMP, character.getNextHighestDepth());
    character._x = Stage.width / 2;
    character._y = Stage.height / 2;
    
}

//-------------------------------------

function buildHitObjs():Void {

    var bmp:BitmapData;

    for (var str:String in hitTestObjLinkIDs) {
        
        bmp = BitmapData.loadBitmap(hitTestObjLinkIDs[str]);
    
        hitTestObjHolder.push(bmp);
    
        stageHolder.attachBitmap(bmp, stageHolder.getNextHighestDepth());
        
    }

}

//-------------------------------------

function moveObject(obj:MovieClip, xDir:Number, yDir:Number):Void {
    
    obj._x += xDir;
    obj._y += yDir;

    if (getHitTest(obj)) moveObject(obj, -xDir, -yDir);
    
}

//-------------------------------------

function getHitTest(obj:MovieClip):Boolean {

    var hitObj:BitmapData;

    characterPoint.x = character._x;
    characterPoint.y = character._y;
    
    for (var str:String in hitTestObjHolder) {
        
        hitObj = BitmapData(hitTestObjHolder[str]);

        if (hitObj.hitTest(new Point(hitObj.rectangle.x, hitObj.rectangle.y), 255, characterBMP, characterPoint)) return true;
        
    }
    
    return false;

}

//-------------------------------------

function getKeys():Void {
    
    if (Key.isDown(Key.RIGHT)) moveObject(character, moveSpeed, 0);
    if (Key.isDown(Key.LEFT))  moveObject(character, -moveSpeed, 0);
    if (Key.isDown(Key.UP))    moveObject(character, 0, -moveSpeed);
    if (Key.isDown(Key.DOWN))  moveObject(character, 0, moveSpeed);
    
}

//-------------------------------------

initApp();

//------------------------------------- 


ich hab das ganze script noch ein bissal aufgebohrt. es koennen mehrere bilder hinzugefügt werden die als hinderniss fungieren sollen... die entsprechenden codezeilen sind kommentiert.

die fla ist leider zu groß zum uppen.
einfach den code in eine leere fla einfügen und dort in der bib ein png24 für den player und 2 png24s für die hindernisse einfügen...

cheers, sal

[-Mani]

BoAAA hey!!
Du hast es voll drauf!!!
danke ey!!!

Hast du das ganze swf nur für mich gemacht??????

voll nett!

sers

[salazar]

moin,
direkt für dich hab ichs nicht geschraubt
du hast mich aber auf die idee gebracht mal wieder in diese richtung zu experimentieren.

ich hab das ganze grad auch noch was weitergesponnen und auch hier möchte ich dir/euch das ergebnis nicht vorenthalten!

swf und fla gibts weiter unten mit dazu...

man kann jetzt beliebig viele gegner platzieren!
die gegner verhalten sich in diesme bsp. alleridings noch ziemlich primitv:

PHP-Code:

buildEnemy("enemPNG", 150, 50, 0); 


-parameter 1 = der verknüpnfungsname in der bib
-parameter 2 = x
-parameter 3 = y
-parameter 4 = rotation

der folgende as code ist nur an ganz wenigen stellen kommentiert.
in der function "initApp" ist alles genau beschrieben wie man weitere gegner hinzufügt, bzw. wie gegner, spieler und envi aussehen usw.
hier der code part 1:

PHP-Code:

//-------------------------------------

stop();

//-------------------------------------

import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.geom.Matrix;

//-------------------------------------

var stageHolder:MovieClip;
var moveSpeed:Number;
var hitTestEnviHolder:Array;
var hitTestEnemyHolder:Array;
var hitTestObjLinkIDs:Array;
var character:MovieClip;
var characterSpeed:Number;
var characterOBJ:Object;
var enemy:MovieClip;
var enemySpeed:Number;
var enemyInterval:Number;

//-------------------------------------

function initApp():Void {

    stageHolder = this.createEmptyMovieClip("stageHolder", this.getNextHighestDepth());//erzeugt den movieclip in den alle anderen movieclpis abgelegt werden
    moveSpeed = 1;//die geschwindigkeit vom character. vorsicht. je hoeher die zahl, umso ungenauer ist die kollisionsabfrage!
    hitTestEnviHolder = new Array();//generiert ein array in dem die envi bitmapData objecte abgelegt werden
    hitTestEnemyHolder = new Array();//generiert ein array in dem die enemy bitmapData objecte abgelegt werden
    hitTestObjLinkIDs = new Array("enviPNG", "envi_objsPNG");//hier werden die bilder (verlinkungsname in der bib) eingetragen die hindernisse sein sollen
    characterSpeed = 1;//der speed mit dem sich der character bewegt. je kleiner die zahl umso schneller. keine komma zahlen
    enemySpeed = 7;//der speed mit dem sich die gegner bewegen. je kleiner die zahl umso schneller. keine komma zahlen
    
    //beachten. player sowie gegner duerfen initial nicht so platziert werden, dass sie einen hitTest ausloesen. das gilt für objecte und das envi
    buildEnemy("enemPNG", 150, 50, 0);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 800, 10, 45);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 500, 520, 90);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 750, 500, 180);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 300, 500, 133);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 200, 660, 270);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 350, 660, 233);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 250, 280, 191);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildPlayer("charPNG");//erzeugt den player movieclip. hier die verlinkung aus der bib mit uebergeben. pos vom player wird festgelegt
    
    buildHitObjs();//erzeugt die hinderniss objekte
    controlEnemys();//bewegt die gegner
    
    setInterval(controlCharacter, characterSpeed);//die tastenagfrage. 1 ist der speed fuer den player. je hoeher die zahl umso langsamer ist die bewegung
    
    mc_fps.swapDepths(10000);//setzt die fps anzeige über alle anderen display elemnte

}

//-------------------------------------

function buildEnemy(img:String, xPos:Number, yPos:Number, rot:Number):Void {
    
    var obj:Object;
    
    var enemyBMP:BitmapData = BitmapData.loadBitmap(img);

    enemy = stageHolder.createEmptyMovieClip("enemy", stageHolder.getNextHighestDepth());
    enemy.attachBitmap(enemyBMP, enemy.getNextHighestDepth());
    enemy._x = xPos;
    enemy._y = yPos;

    obj = new Object();
    obj.mc = enemy;
    obj.bmp = enemyBMP;
    obj.bmpSource = BitmapData.loadBitmap(img);
    obj.x = enemy._x;
    obj.y = enemy._y;
    obj.xDir = null;
    obj.yDir = null;
    obj.objPos = new Object();
    obj.hitChar = false;

    hitTestEnemyHolder.push(obj);
    
    drawBitmap(obj, rot);
    
}

//-------------------------------------

function posEnemy():Object {

    var dirsArrAll:Array = new Array(-1, 0, 1);
    var dirsArrSmall:Array = new Array(-1, 1);

    var objPos:Object = new Object();
        objPos.xDir = moveSpeed * dirsArrAll[random(dirsArrAll.length)];
        objPos.xDir == 0 ? objPos.yDir = moveSpeed * dirsArrSmall[random(dirsArrSmall.length)] : objPos.yDir = moveSpeed * dirsArrAll[random(dirsArrAll.length)];
        
    return objPos;

}

//-------------------------------------

function controlEnemys():Void {

    var enemyObj:Object;

    enemyInterval = setInterval(function():Void {
    
        for (var str:String in hitTestEnemyHolder) {

            enemyObj = hitTestEnemyHolder[str];

            enemyObj.objPos.xDir == null ? enemyObj.objPos = posEnemy() : enemyObj.objPos = enemyObj.objPos;
            
            enemyObj.xDir = enemyObj.objPos.xDir;
            enemyObj.yDir = enemyObj.objPos.yDir;

            moveEnemy(enemyObj, enemyObj.xDir, enemyObj.yDir)
            
            if (getHitTest(hitTestEnviHolder, enemyObj) || getHitTest(hitTestEnemyHolder, enemyObj)) {

                moveEnemy(enemyObj, -enemyObj.xDir, -enemyObj.yDir);
                
                enemyObj.objPos = posEnemy();
                
            }

        }
    
    }, enemySpeed);

}

//------------------------------------- 


[salazar]

code part 2:

PHP-Code:

//-------------------------------------

function moveEnemy(enemyObj:Object, xDir:Number, yDir:Number):Void {
    
    enemyObj.x += xDir;
    enemyObj.y += yDir;
                                                   
    enemyObj.mc._x = enemyObj.x;
    enemyObj.mc._y = enemyObj.y;

}

//-------------------------------------

function buildPlayer(img:String):Void {
    
    var characterBMP:BitmapData = BitmapData.loadBitmap(img);

    character = stageHolder.createEmptyMovieClip("character", stageHolder.getNextHighestDepth());
    character.attachBitmap(characterBMP, character.getNextHighestDepth());
    character._x = Stage.width / 2;
    character._y = Stage.height / 2;

    characterOBJ = new Object();
    characterOBJ.mc = character;
    characterOBJ.bmp = characterBMP;
    characterOBJ.bmpSource = BitmapData.loadBitmap(img);
    characterOBJ.x = character._x;
    characterOBJ.y = character._y;
    characterOBJ.xDir = 0;
    characterOBJ.yDir = 0;

}

//-------------------------------------

function buildHitObjs():Void {
    
    var obj:Object;

    for (var str:String in hitTestObjLinkIDs) {
        
        obj = new Object();
        
        obj.bmp = BitmapData.loadBitmap(hitTestObjLinkIDs[str]);
        obj.x = 0;
        obj.y = 0;
    
        hitTestEnviHolder.push(obj);
    
        stageHolder.attachBitmap(obj.bmp, stageHolder.getNextHighestDepth());
        
    }

}

//-------------------------------------

function drawBitmap(obj:Object, rot:Number):Void {

    var objWidthHalf:Number = obj.bmpSource.width / 2;
    var objHeightHalf:Number = obj.bmpSource.height / 2;
    
    var degrees:Number = rot;
    
    var angle = Math.PI * 2 * (degrees / 360);
    
    var rotationMatrix:Matrix = new Matrix();
        rotationMatrix.translate(-objWidthHalf, -objHeightHalf);
        rotationMatrix.rotate(angle);
        rotationMatrix.translate(objWidthHalf, objHeightHalf);
        
    rubberBitmap(obj);

    obj.bmp.draw(obj.bmpSource, rotationMatrix, null, null, null, true);

}

//-------------------------------------

function rubberBitmap(obj:Object):Void {

    obj.bmp.fillRect(new Rectangle(0, 0, obj.bmpSource.width, obj.bmpSource.height), 0x00000000);
    
}

//-------------------------------------
    
function moveObject(obj:Object, xDir:Number, yDir:Number):Void {
    
    obj.x += xDir;
    obj.y += yDir;
    
    obj.mc._x = obj.x;
    obj.mc._y = obj.y;
    
    obj.xDir = xDir;
    obj.yDir = yDir;

    if (getHitTest(hitTestEnviHolder, obj)) moveObject(obj, -xDir, -yDir);
    
}

//-------------------------------------

function getHitTest(arr:Array, obj:Object):Boolean {

    var hitObj:Object;

    var poi:Point = new Point(obj.x, obj.y);

    for (var str:String in arr) {
        
        hitObj = Object(arr[str]);
        
        if (hitObj != obj) {

            if (hitObj.bmp.hitTest(new Point(hitObj.x, hitObj.y), 255, obj.bmp, poi)) return true;
        
        }
        
    }
    
    return false;

}

//-------------------------------------

function controlCharacter():Void {

    if (Key.isDown(Key.RIGHT)) moveObject(characterOBJ, moveSpeed, 0);
    if (Key.isDown(Key.LEFT))  moveObject(characterOBJ, -moveSpeed, 0);
    if (Key.isDown(Key.UP))    moveObject(characterOBJ, 0, -moveSpeed);
    if (Key.isDown(Key.DOWN))  moveObject(characterOBJ, 0, moveSpeed);

    characterOBJ.mc._alpha = 100;
    
    if (getHitTest(hitTestEnemyHolder, characterOBJ)) characterOBJ.mc._alpha = 25;
    
}

//-------------------------------------

initApp();

//------------------------------------- 


swf und fa gibts auch mit dazu.

viel spaß damit

cheers, sal

[salazar]

ich hab den thread mal verschoben
das ganze passt viel mehr zum thema spiele

cheers, sal

[salazar]

nochmal optimiert und von altem balast befreit...

PHP-Code:

//-------------------------------------

stop();

//-------------------------------------

import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.geom.Matrix;

//-------------------------------------

var stageHolder:MovieClip;
var moveSteps:Number;
var hitTestEnviHolder:Array;
var hitTestEnemyHolder:Array;
var hitTestObjLinkIDs:Array;
var characterOBJ:Object;
var characterSpeed:Number;
var enemySpeed:Number;
var enemyInterval:Number;
var dirsArrAll:Array;
var dirsArrSmall:Array;

//-------------------------------------

function initApp():Void {

    stageHolder = this.createEmptyMovieClip("stageHolder", this.getNextHighestDepth());//erzeugt den movieclip in den alle anderen movieclpis abgelegt werden
    moveSteps = 1;//der weg der pro zeiteinheit in pix zurückgelegt wird. vorsicht. je hoeher die zahl, umso ungenauer ist die kollisionsabfrage!
    hitTestEnviHolder = new Array();//generiert ein array in dem die envi bitmapData objecte abgelegt werden
    hitTestEnemyHolder = new Array();//generiert ein array in dem die enemy bitmapData objecte abgelegt werden
    hitTestObjLinkIDs = new Array("enviPNG", "envi_objsPNG");//hier werden die bilder (verlinkungsname in der bib) eingetragen die hindernisse sein sollen
    characterSpeed = 1;//der speed mit dem sich der character bewegt. je kleiner die zahl umso schneller. keine komma zahlen
    enemySpeed = 7;//der speed mit dem sich die gegner bewegen. je kleiner die zahl umso schneller. keine komma zahlen
    dirsArrAll = new Array(-1, 0, 1);//die richtungen in die sich die gegner bewegen koennen. 3 richtungen. links, stillstand, rechts
    dirsArrSmall = new Array(-1, 1);//die richtungen in die sich die gegner bewegen koennen. 3 richtungen. links, rechts
    
    //beachten. player sowie gegner duerfen initial nicht so platziert werden, dass sie einen hitTest ausloesen. das gilt für objecte und das envi
    buildEnemy("enemPNG", 150, 50, 0);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 800, 10, 45);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 500, 520, 90);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 750, 500, 180);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 300, 500, 133);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 200, 660, 270);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 350, 660, 233);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildEnemy("enemPNG", 250, 280, 191);//erzeugt gegner. hier die verlinkung aus der bib mit uebergeben. pos vom enemy wird festgelegt
    buildPlayer("charPNG", Stage.width / 2, Stage.height / 2, 0);//erzeugt den player movieclip. hier die verlinkung aus der bib mit uebergeben. pos vom player wird festgelegt
    
    buildEnviHitObjs();//erzeugt die hinderniss objekte
    controlEnemys();//bewegt die gegner
    
    setInterval(controlCharacter, characterSpeed);//die tastenagfrage. 1 ist der speed fuer den player. je hoeher die zahl umso langsamer ist die bewegung
    
    mc_fps.swapDepths(10000);//setzt die fps anzeige über alle anderen display elemnte

}

//-------------------------------------

function buildEnemy(img:String, xPos:Number, yPos:Number, rot:Number):Void {
    
    var enemyBMP:BitmapData = BitmapData.loadBitmap(img);
    
    var enemyOBJ:Object;

    enemyOBJ = new Object();
    enemyOBJ.mc = stageHolder.createEmptyMovieClip("character", stageHolder.getNextHighestDepth());
    enemyOBJ.mc.attachBitmap(enemyBMP, character.getNextHighestDepth());
    enemyOBJ.mc._x = xPos;
    enemyOBJ.mc._y = yPos;
    enemyOBJ.bmp = enemyBMP;
    enemyOBJ.bmpSource = BitmapData.loadBitmap(img);
    enemyOBJ.x = xPos;
    enemyOBJ.y = yPos;
    
    enemyOBJ.objPos = new Object();
    enemyOBJ.objPos.xDir = null;
    enemyOBJ.objPos.yDir = null;
    enemyOBJ.hitChar = false;

    drawBitmap(enemyOBJ, rot);
    
    hitTestEnemyHolder.push(enemyOBJ);

}

//-------------------------------------

function posEnemy():Object {

    var objPos:Object = new Object();
        objPos.xDir = moveSteps * dirsArrAll[random(dirsArrAll.length)];
        objPos.xDir == 0 ? objPos.yDir = moveSteps * dirsArrSmall[random(dirsArrSmall.length)] : objPos.yDir = moveSteps * dirsArrAll[random(dirsArrAll.length)];
        
    return objPos;

}

//-------------------------------------

function controlEnemys():Void {

    var enemyObj:Object;

    enemyInterval = setInterval(function():Void {
    
        for (var str:String in hitTestEnemyHolder) {

            enemyObj = hitTestEnemyHolder[str];

            enemyObj.objPos.xDir == null ? enemyObj.objPos = posEnemy() : enemyObj.objPos = enemyObj.objPos;

            moveEnemy(enemyObj, enemyObj.objPos.xDir, enemyObj.objPos.yDir)

            if (getHitTest(hitTestEnviHolder, enemyObj) || getHitTest(hitTestEnemyHolder, enemyObj)) {

                moveEnemy(enemyObj, -enemyObj.objPos.xDir, -enemyObj.objPos.yDir);
                
                enemyObj.objPos = posEnemy();
                
            }

        }
    
    }, enemySpeed);

}

//-------------------------------------

function moveEnemy(enemyOBJ:Object, xDir:Number, yDir:Number):Void {
    
    enemyOBJ.mc._x = enemyOBJ.x += xDir;
    enemyOBJ.mc._y = enemyOBJ.y += yDir;

}

//-------------------------------------

function buildPlayer(img:String, xPos:Number, yPos:Number, rot:Number):Void {

    var characterBMP:BitmapData = BitmapData.loadBitmap(img);

    characterOBJ = new Object();
    characterOBJ.mc = stageHolder.createEmptyMovieClip("character", stageHolder.getNextHighestDepth());
    characterOBJ.mc.attachBitmap(characterBMP, character.getNextHighestDepth());
    characterOBJ.mc._x = xPos;
    characterOBJ.mc._y = yPos;
    characterOBJ.bmp = characterBMP;
    characterOBJ.bmpSource = BitmapData.loadBitmap(img);
    characterOBJ.x = xPos;
    characterOBJ.y = yPos;

    drawBitmap(characterOBJ, rot);
    
}

//-------------------------------------

function buildEnviHitObjs():Void {
    
    var obj:Object;

    for (var str:String in hitTestObjLinkIDs) {
        
        obj = new Object();
        
        obj.bmp = BitmapData.loadBitmap(hitTestObjLinkIDs[str]);
        obj.x = 0;
        obj.y = 0;
    
        hitTestEnviHolder.push(obj);
    
        stageHolder.attachBitmap(obj.bmp, stageHolder.getNextHighestDepth());
        
    }

}

//-------------------------------------

function drawBitmap(obj:Object, rot:Number):Void {

    var objWidthHalf:Number = obj.bmpSource.width / 2;
    var objHeightHalf:Number = obj.bmpSource.height / 2;

    var angle:Number = Math.PI * 2 * (rot / 360);
    
    var rotationMatrix:Matrix = new Matrix();
        rotationMatrix.translate(-objWidthHalf, -objHeightHalf);
        rotationMatrix.rotate(angle);
        rotationMatrix.translate(objWidthHalf, objHeightHalf);
        
    rubberBitmap(obj);

    obj.bmp.draw(obj.bmpSource, rotationMatrix, null, null, null, true);

}

//-------------------------------------

function rubberBitmap(obj:Object):Void {

    obj.bmp.fillRect(new Rectangle(0, 0, obj.bmpSource.width, obj.bmpSource.height), 0x00000000);
    
}

//-------------------------------------
    
function moveCharacter(obj:Object, xDir:Number, yDir:Number):Void {
    
    obj.mc._x = obj.x += xDir;
    obj.mc._y = obj.y += yDir;
    
    obj.xDir = xDir;
    obj.yDir = yDir;

    if (getHitTest(hitTestEnviHolder, obj)) moveCharacter(obj, -xDir, -yDir);
    
}

//-------------------------------------

function getHitTest(arr:Array, obj:Object):Boolean {

    var hitObj:Object;

    var objPoi:Point = new Point(obj.x, obj.y);

    for (var str:String in arr) {
        
        hitObj = Object(arr[str]);

        if (hitObj != obj && hitObj.bmp.hitTest(new Point(hitObj.x, hitObj.y), 255, obj.bmp, objPoi)) return true;
        
    }
    
    return false;

}

//-------------------------------------

function controlCharacter():Void {
    
    //get keys
    if (Key.isDown(Key.RIGHT)) moveCharacter(characterOBJ, moveSteps, 0);
    if (Key.isDown(Key.LEFT))  moveCharacter(characterOBJ, -moveSteps, 0);
    if (Key.isDown(Key.UP))    moveCharacter(characterOBJ, 0, -moveSteps);
    if (Key.isDown(Key.DOWN))  moveCharacter(characterOBJ, 0, moveSteps);
    
    //set hit
    characterOBJ.mc._alpha = 100;
    
    if (getHitTest(hitTestEnemyHolder, characterOBJ)) characterOBJ.mc._alpha = 25;
    
}

//-------------------------------------

initApp();

//------------------------------------- 


einfach den alten code in der letzten fla mit diesem hier ersetzen und fertig.

cheers, sal

[Rocco]

cooles ding hast du da zusammengeschraubt. :-)
sehr effizient und funktioniert perfekt.
Ich brauch zwar momentan soetwas nicht, aber wenn ich an meiner homepage weiterbastle und ein paar andere bewegliche chars dabeihaben will, werd ich mich davon inspirieren lassen.

[Circushund]

jup, nach dem ersten Anschauen/Ausprobieren find ich's auch nicht schlecht.

[salazar]

ja denn hau ich nochmal 'ne neue version raus
hatte da die tage noch was weiter drann geschraubt. ist jetzt immer noch nicht opti, aber es gibt ein paar neue features.

-schiessen. mit strg.
-envi eraser. geh durch wände und veränder die landschaft. mit der entf taste wärend man sich bewegt zu gebrauchen.

ein bsp. ist weiter unten mit dabei.

cheers, sal

[cidic]

wow wie genial ist das denn?
lustig, dass man jetzt auch aus der welt entfliehen und alles "aufräumen" kann