MX: Brightness als Eigenschaft

[bokel]

In einem anderen Forum kam die Frage nach der
(normalerweise nicht existierenden) Eigenschaft
_brightness.

In der wunderbaren Welt von MX kann man diese
Eigenschaft leicht hinzufügen. Hier ist ein möglicher
Weg:

//im ersten Frame von _root
MovieClip.prototype.addProperty(
    "_brightness", 
    function () {
        var t = new Color(this).getTransform();
        return (t.ra + t.ga + t.ba) / 3;
    }, 
    function (b) {
        new Color(this).setTransform({ra:b, ga:b, ba:b});
    }
);
//
//
//test
createEmptyMovieClip("mc", 1);
with (mc) {
    beginFill(0xff0000);
    lineTo(100, 0);
    lineTo(100, 100);
    lineTo(0, 100);
    endFill();
}
//
mc.onEnterFrame = function() {
    this._brightness = random(100);
};
//ralf bokelberg 10/2002 helpQLODhelp.de 
 

mfg r.

[Hamster2k]

saub(a)er!

[michael]

prima, danke

endlich mal wieder movieclip.prototype in sinnvollem zusammenhang

damit wär ja myClip._color = ...
auch kein problem mehr.

gruss
michael

[Johannes P.]

Hoi,

schon ganz prima, nur müsste das Helligkeitsintervall nicht von -100% bis +100% reichen?

[Johannes P.]

Aber anstatt nur zu motzen, mach ich mich gleich mal nützlich:

MovieClip.prototype.addProperty("_color", function () {
    return new Color(this).getRGB().toString(16);
}, function (c) {
    new Color(this).setRGB(parseInt(c, 16));
});
// Aufruf
 
mc._color = "ff00ff";
currentColor = mc._color; 

damit wär ja myClip._color = ...
auch kein problem mehr.

[michael]

wie wärs damit? (-100% - 0 - 100%)

//im ersten Frame von _root
MovieClip.prototype.addProperty("_brightness", function ()
{
    var t = new Color(this).getTransform();
    return ((t.rb + t.gb + t.bb) / 3) / 2.56;
}, function (b)
{
    var p = 2.56 * b;
    new Color(this).setTransform({rb:p, gb:p, bb:p});
});
//
//
//test
mc1._brightness = 100;
mc2._brightness = 50;
mc3._brightness = -50;
trace(mc1._brightness);
trace(mc2._brightness);
trace(mc3._brightness); 

<edit>
natürlich könnte man auch ohne den umrechnungsfaktor mit werten von -255 bis 255 arbeiten, ich wollte aber das der user mit den gleichen werten wie im eigenschafteninspektor, auch das gleiche ergebnis bekommt. die ungenauigkeiten die sich daraus ergeben sind die gleichen die wir schon von alpha kennen:

mc._brightness = 70;
trace(mc._brightness);// 69.921875
mc._alpha = 70;
trace(mc._alpha);// 69.921875 
 

</edit>

gruss
michael

[michael]

@Johannes
da würde ich die gängige schreibweise mit 0x bevorzugen:

MovieClip.prototype.addProperty("_color", function ()
{
    return "0x" + new Color(this).getRGB().toString(16);
}, function (c)
{
    new Color(this).setRGB(c);
});
// Aufruf
mc1._color = 0xff00ff;
mc2._color = mc1._color;
trace(mc2._color); 

gruss
michael

[Gnut]

@gutknut: die zahl würde stimmen wenn du sie rundest.

MovieClip.prototype.addProperty("_brightness", function ()
{
        var t = new Color(this).getTransform();
        return Math.round((t.rb + t.gb + t.bb) / 3 * 100 / 0xff);
}, function (b)
{
        var p = 0xff * b / 100;
        new Color(this).setTransform({rb: p, gb: p, bb: p});
});
createEmptyMovieClip("mc1",1);
mc1._brightness = 60;
trace(mc1._brightness); 

[michael]

@ gnut
warum mit _brightness genauer sein als flash selbst mit _alpha?

das man es runden kann ist schon klar, trotzdem danke.

gruss
michael

[bloba]

nicht specht her schlecht
drei daumen hoch
gruss

[peterpawlow]

Habe im Archiv unten nocheinmal zitierten Beitrag gefunden.

Frage mich nun immer noch zwei Dinge:
-Wo soll dieses Script eimgefügt werden,
-und wie spreche ich damit
die Instanz eines Filmsymbols, nennen wir sie mal wieder
"myMovieclip" an?

Viele Grüße,
PP



[QUOTE]Geschrieben von bokel
[B]In einem anderen Forum kam die Frage nach der
(normalerweise nicht existierenden) Eigenschaft
_brightness.

In der wunderbaren Welt von MX kann man diese
Eigenschaft leicht hinzufügen. Hier ist ein möglicher
Weg:

//im ersten Frame von _root
MovieClip.prototype.addProperty(
    "_brightness", 
    function () {
        var t = new Color(this).getTransform();
        return (t.ra + t.ga + t.ba) / 3;
    }, 
    function (b) {
        new Color(this).setTransform({ra:b, ga:b, ba:b});
    }
);
//
//
//test
createEmptyMovieClip("mc", 1);
with (mc) {
    beginFill(0xff0000);
    lineTo(100, 0);
    lineTo(100, 100);
    lineTo(0, 100);
    endFill();
}
//
mc.onEnterFrame = function() {
    this._brightness = random(100);
};
//ralf bokelberg 10/2002 helpQLODhelp.de 
 

[bokel]

Hallo Peter,

den ersten Teil bis zum Kommentar "// test" fügst du in deinem ersten Frame auf der Hauptzeitleiste ein. Danach kannst du die Eigenschaft _brightness überall benutzen. Deinen MovieClip kannst du dann z.B. folgendermassen steuern:

myMovieclip._brightness = 50; 

mfg r.

[Janoscharlipp]

super, dass kann man auf jeden Fall mal gebrauchen!

[peterpawlow]

Hi Bokel,


habs probiert und probiert, aber es funktioniert nicht. :-(

Hab mal die scripte beigepackt, vieleicht findet ja
jemand dass Problem.
.fla-Datei ist leider auch kompremiert 30mb groß (cd-rom-test),
ließ sich nicht ranhängen.
wenns wen interessiert, mail ich die auch gerne!

Geht um ein Filmsymbol "myMovie", das sich abhängig von Variablen-
Abfragen in der Farbigkeit und in der BRIGHTNESS ändern soll.
Farbigkeit funktioniert problemlos über Farbobjekt "myColor".
Erster Teil Script von Frame 3 + Frame 4 betrifft Sounsteuerung,
ist warscheinlich nicht so interessant.
Im zweiten Teil von Script von Frame 3 + Frame 4 geht es dann u.A.
um die Brightness.


also:


Script Haupleiste Frame 1:
---------------------------------




//Wenn Farbvariable "richtigen" Wert, soll in Hauptleiste, Frame 3/4 Prozedur
//zur farbveränderung ausgefürt werden.

farbwertvariable = 7.1;

//Prozedur in Hauptleiste, Frame 3/4 soll Farbobjekt entsprechend diesem //Variablenwert ausführen.

farbwert = {bb: '100'};



dynamik = 1;

stimmung = 1;


//dieses Script führt die Eigenschaft Brightness ein, die es sonst in Flash-MX
//nicht gibt.


MovieClip.prototype.addProperty(
"_brightness",
function () {
var t = new Color(this).getTransform();
return (t.ra + t.ga + t.ba) / 3;
},
function (b) {
new Color(this).setTransform({ra:b, ga:b, ba:b});
}
);


//Soundobjekt
mus11 = new Sound();
// Verknüpfe das Sound-Objekt s über den Bezeichner mit dem Symbol in der Bibliothek

mus11.attachSound("mus11");

mus12 = new Sound();
mus12.attachSound("mus12");
mus21 = new Sound();
mus21.attachSound("mus21");
mus22 = new Sound();
mus22.attachSound("mus22");

// Create a color object called myColor for the target myMovie

myColor = new Color(myMovie);

// Create a color transform object called myColorTransfrom using
// the generic Object object

myColorTransform = new Object();

// Set the values for myColorTransform
//myColorTransform2 = new Object();

gotoAndPlay(2);





Script Haupleiste Frame 2:
---------------------------------




//läßt erste Musik starten, von Anfang an, kein loop.

mus11.start(0, 0);


//Verändert dass farbobjekt "mycolor" entsprechend "farbwert"

myColor.setTransform(_root.farbwert);
play;




Script Haupleiste Frame 3:
---------------------------------




//mus11
//wenn die Musik zuende, spiele je nach dem eine neue.
//setzte die variable "farbwertvariable" [erstes frame ebenne "script"]
//auf einen neuen Wert.
mus11.onSoundComplete = function() {
mus11.stop();
if (_root.dynamik<4) {
mus12.start();
_root.farbwertvariable=1.1;
}
if (_root.dynamik>4) {
mus22.start();
_root.farbwertvariable=1.2;
}
};
//mus12
//wenn die Musik zuende, spiele je nach dem eine neue.
//setzte die variable "farbwertvariable" [erstes frame ebene "script"]
//auf einen neuen Wert.
mus12.onSoundComplete = function() {
mus12.stop();
if (_root.dynamik<4) {
mus11.start();
_root.farbwertvariable=1.3;
}
if (_root.dynamik>4) {
mus21.start();
_root.farbwertvariable=1.4;
}
};
//mus21
//wenn die Musik zuende, spiele je nach dem eine neue.
//setzte die variable "farbwertvariable" [erstes frame ebenne "script"]
//auf einen neuen Wert.
mus21.onSoundComplete = function() {
mus21.stop();
if (_root.dynamik<4) {
mus11.start();
_root.farbwertvariable=2.1;
}
if (_root.dynamik>4) {
mus22.start();
_root.farbwertvariable=2.2;
}
};
//mus22
//wenn die Musik zuende, spiele je nach dem eine neue.
//setzte die variable "farbwertvariable" [erstes frame ebenne "script"]
//auf einen neuen Wert.
mus22.onSoundComplete = function() {
mus22.stop();
if (_root.dynamik<4) {
mus11.start();
_root.farbwertvariable=2.3;
}
if (_root.dynamik>4) {
mus21.start();
_root.farbwertvariable=2.4;
}
};

//wenn "farbvariable" genau diesen wert hat, dann setze die Variable "farbwert"
//auf diesen wert
//verändere das farbobjekt "myColor" entsprechend "MyColorTransform".
//Der Wert von "myColorTransform" folgt aus der Variable "farbwert"
//[siehe frame 1 Ebenne Script].
//Diese Prozedur taucht im folgenden für 8 verschiedenne "farbwert"-Werte
//8 mal auf.

if (_root.farbwertvariable == 1.1) {
//if (_root.farbwert != {bb: '20'}) {
_root.farbwert = {bb: '20'};
myMovie._brightness = 30;
myColor.setTransform(_root.farbwert);
//}
}

if (_root.farbwertvariable == 1.2) {
// if (_root.farbwert != {bb: '80'}) {
_root.farbwert = {bb: '80'};
myMovie._brightness = 100;
myColor.setTransform(_root.farbwert);

//}


}
if (_root.farbwertvariable == 1.3) {
// if (_root.farbwert != {rb: '40', gb: '40}) {
_root.farbwert = {rb: '40', gb: '40'};
myMovie._brightness = 50;

myColor.setTransform(_root.farbwert);
// }


}
if (_root.farbwertvariable == 1.4) {
// if (_root.farbwert != {rb: '20', gb: '20'}) {
_root.farbwert = {rb:'20', gb:'20'};
myMovie._brightness = 130;
myColor.setTransform(_root.farbwert);
// }
}
if (_root.farbwertvariable == 2.1) {
// if (_root.farbwert != {rb: '60', gb: '30'}) {
_root.farbwert = {rb: '60', gb: '30'};
myMovie._brightness = 80;
myColor.setTransform(_root.farbwert);
// }
}
if (_root.farbwertvariable == 2.2) {
// if (_root.farbwert != {rb: '30', gb: '20'}) {
_root.farbwert = {rb:'30', gb:'20'};
myMovie._brightness = 00;
myColor.setTransform(_root.farbwert);
// }
}
if (_root.farbwertvariable == 2.3) {
// if (_root.farbwert != {rb: '50', bb: '50'}) {
_root.farbwert = {rb: '50', bb: '50'};
myMovie._brightness = 15;
myColor.setTransform(_root.farbwert);
// }
}
if (_root.farbwertvariable == 2.4) {
// if (_root.farbwert != {rb: '40', bb: '40'}) {
_root.farbwert = {rb:'40', bb:'40'};
myMovie._brightness = 20;
myColor.setTransform(_root.farbwert);
// }
}
//nun soll zu frame 4 gespielt werden, damit
//auch langsame farbübergänge machbar sind. (Vor-Rücksprung)
play;




Script Haupleiste Frame 4:
---------------------------------



wie Frame 3, nur letzte drei Zeilen anders:

//nun soll zu frame 3 gespielt werden, damit
//auch langsame farbübergänge machbar sind. (Vor-Rücksprung)
gotoAndPlay(3);




Viele Grüße,
ein leicht entnervter
sich redlich bemüht habender

Peter Pawlow

[bokel]

Hallo Peter,

eigentlich sollte es klappen.
Veröffentlichst du als MX ?
Und erstellst du deinen Projektor auch mit MX ?

mfg r.