Methode innerhalb der Klasse aufrufen?!

[Master Wu]

Ich bastel gerade an ner Portfolio-Navigation.
Ich hab also eine Klasse gebaut, die eine Arbeit zeigen soll.
In der Klasse baue ich einen Button (mcBar),
der onRelease die Funktion aufrufen soll, die dann das Bild groß darstellt.

Jetzt habe ich ein Problem, die Methode aufzurufen, weil ich ja in diesem Button drin bin, dachte schon an this._parent.createBla(), aber hat auch nicht geklappt.

Jemand ne Idee?

// PortBar Klasse -----------------------------------------------
PortBar = function (xml, id) {
    this.xml = xml;
    this.id = id;
    
    //------------------------
    this.createBar = function () {
        _root.mcPort.createEmptyMovieClip ("mcBar"+id, 10+id);
        this.mc = _root.mcPort["mcBar"+id];
        this.mc.createEmptyMovieClip("mcGfx", 2);
        mcGfx = this.mc.mcGfx;
        // ThumbBar
        mcGfx.drawRect (0, -13, 220, 13, 0x000000); //schwarz, oben
        
        mcGfx.onRelease = function() {
                       // hier ist das Problem!
            this.createContent(); //??
        }
        //
    }
 
    // Methode
    this.createContent = function () {
        // hier passiert dann was
    }
 
 
}
Port.prototype = new MovieClip ();
 
// action:
    for (i=0; _root.pfCount>i; i++) {
        xa = xmlCont.childNodes[0].childNodes[i].attributes;
        _root["myPort"+i] = new PortBar(xa, i);
        _root["myPort"+i].createBar();
    } 

[atothek]

scope und delegation heißen die zauberwörter

class Delegate {
    
    public static function create( obj, func ) : Function {
        var args : Array = arguments.splice(2);
        return function(){
            if( func instanceof Function )
                return func.apply( obj, arguments.concat( args ) );
            else 
                return obj[ func ].apply( obj, arguments.concat( args ) );
        };
    }
} 

anwednen tuste das ganze wie folgt

mcGfx.onRelease = Delegate.create( this, createContent ); // jeder weitere parameter wird an die methode mit übergeben 
 

ohne eine Delegate klasse verläßt nix mehr mein haus. Events werden einfach auf den klassen scope umgebogen und fertisch

mfg
alex

[Master Wu]

Danke schonmal,
leider versteh ich nur Bahnhof

Zum laufen hab ichs leider auch nicht gebracht und tu mich schwer mit der Fehlersuche, wenn ich nicht wirklich kapiere,
was da in Delegate.create überhaupt passiert

Bin schon in der ersten Zele verwirrt, was macht die?

var args : Array = arguments.splice(2);

was ist arguments?
wo kommt das überhaupt her?
sorry, bin nicht so der Pro

[atothek]

arguments sind alle FunctionArguments also alle parameter einer function.
zB.

function test( arg1, arg2 ) {

}

arguments wäre also eine array bestehend aus Array( arg1, arg2 ).

Die delegate.create methode erstellt eine function die zurück gegeben wird
anstelle eine eigene function zu definieren. der erste parameter ist das object welches die aufzurufende methode handhabt in diesem fall also this (Delegate.create( this, myCallback ); ) der 2 parameter ist die callbackmethode in diesem fall wäre es createContent.

Was ich auch verafft habe ist das du ja AS1 klassen machst in einer komischen schreibweiße . anstatt das delegate zu nuzten versuch folgendes

var scope = this;
mcGfx.onRelease = function() {
                        // hier ist das Problem!
                        scope .createContent(); //??
                } 

das sollte nun aber klappen.

mfg
alex

[Master Wu]

Zitat von atothek

das du ja AS1 klassen machst in einer komischen schreibweiße

hmmja, ich wurschtel so rum

Die scope-Sache funktioniert ... mann, da hätt ich aber auch mal selber drauf kommen können ...

Vielen Dank!

Die andere Sache muss ich mir nochmal gaanz genau anschauen, damit ich das raff

[pokepika]

benutz die Flash-eigene Delegate Klasse dafür.

schreib oben vor deine klassendefinition:

import mx.utils.Delegate 

und ändere den aufruf in:

mcGfx.onRelease = Delegate.create( this, createContent ); 

[atothek]

@pokepika warum???

mfg
alex

[pokepika]

weil man dann nicht erst noch ne eigene Klasse schreiben muss..

Warum das Rad neu erfinden? (oder wie war das ^^)

[atothek]

tja da sage ich nicht neu erfinden aber rund machen
versuch mal parameter mit der mx Delegate klasse mit zu übergeben

import mx.utils.Delegate;
 
bla = {};
bla.onTest = function( arg1 ) {
    trace( "onTest: " + arg1 );
}
 
mc.onPress = Delegate.create( bla, bla.onTest, "testParam" ); 

das geht in die hose und ist eigentlich nen notwendiges feature

mfg
alex

[nky]

jo die parameterbeschränkung suckt ziemlich bei delegate..deshalb benuz ich mittlerweile eigentlich immer diese klasse
http://www.person13.com/articles/proxy/Proxy.htm
da ist das mit dem parameter übergeben kein problem - und durch die gleiche syntax ist die verwendung auch ziemlich einfach finde ich

Gruss nky

[atothek]

hey marcel alter haudegen

jau im allgemenen ist der name besser Proxy drückt das ja auch besser aus als
Delegate. da ja eine Stellvetretermethode erzeugt wird

mfg
alex

[pokepika]

@atothek: ah, jo stimmt.
hab jetzt ne erweiterung geschrieben, die das Problem behebt

Proxy Klasse? guck ich mir mal an

[antiplex]

@atothek: feines ding dein delegate. versuch da grad durchzusteigen, vielleicht
kannst/magst du mir ein wenig helfen?

ich hab mir auch das (besser kommentierte) proxy-beispiel angeschaut und mir
is schon einigermassen klar was das ganze überhaupt macht und soll. ich würd
nur gern verstehen was genau in deinem code passiert.

dazu nehm ich ihn mal ein wenig auseinander:
... sorry wegen der scrollerei *schäm*

class Delegate {
        
        public static function create( obj, func ) : Function {     // <-- obj & func typisieren? naja, is kosmetik, durch die namen ja klar.
                var args : Array = arguments.splice(2);             // <-- warum splice? das fügt doch eigentlich elemente ein und braucht mehr args, oder? meinst du vielleicht slice?
                return function(){                                  // <-- ok, das is ein netter hack, dachte man muss erst die funktion anlegen, ihr was zuweisen und dann zurückgeben, aber wenn as das auch rückwärts kann... why not.
                        if( func instanceof Function )              // <-- ??? schaust du nach ob das ne funktion im lokalen scope ist?
                        return func.apply( obj, arguments.concat( args ) );   // <-- arguments sollte eigentlich leer sein bis hierhin, oder? dann werden einfach nur die params angehängt?
                        else
                        return obj[ func ].apply( obj, arguments.concat( args ) );   // <-- ??? wenn nicht lokal dann auf das zielobjekt angewandt?was wenn obj keine passende func hat? warum wird obj wieder übergeben? ist das dann logisch ein 'this'???
                };
        }
} 

danke fürs erklären...

[Janoscharlipp]

ich versuche das mal...

class Delegate {
        
        public static function create( obj, func ) : Function {     // die Typen sind nicht bekannt, obj kann irgendeine Instanz sein, func ist entweder eine Funktion, oder ein String (Unterscheidung später mit typeof)
                var args : Array = arguments.splice(2);             // die ersten 2 Parameter sind obj und func, es geht aber nur um die (wenn es welche gibt) anderen
                return function(){                                  // das ist kein Hack, der Trick ist nur, dass die lokalen Variablen obj und func in dieser Funktion später verfügbar sind! (heißt glaube ich "closure")
                        if( func instanceof Function )              // func entweder eine Funktion oder ein Methodenname
                        return func.apply( obj, arguments.concat( args ) );   // arguments sind die Argumente, die beim eigentlichen Aufruf übergeben werden, args sind die Argumente die beim Delegate-Erstellen nach func und obj übergeben wurden
                        else
                        return obj[ func ].apply( obj, arguments.concat( args ) );   // die Funktion wird immer auf obj angewendet (s. Hilfe zu apply) diesmal allerdings wenn func ein String war
                };
        }
} 

Hoffe ich konnte zur Klärung beitragen...

[antiplex]

ok, danke für den versuch, aber ich glaube wir reden aneinander vorbei oder ich
bin zu doof...

in meiner ersten comment zeile meinte ich, dass es doch eigentlich obj:Object
und func:Function ist. dass nicht feststeht ist, was für ein objekt ist klar.

zweite commentzeile: mit myarray1:Array = myarray2.spline(2, 0 , "hinzu1", "hinzu2");
dachte ich füge ich zu myarray2 an stelle 2 die werte "hinzu1" und "hinzu2" zu
ohne welche darin enthaltenen zu löschen (durch die '0'). anschliessend wird das
gesamte ergebnis einfach an myarray1 übergeben.

dritte zeile: ok, hack war im sinne der bücherserie '... hacks' gemeint. das proxy
beispiel machts andersrum, was mir auf den ersten blick einleuchtender erschien.

vierte zeile: was meinst du mit funktion/methodenname? dasselbe? oder meinst
du mit methoden functions von objekten und mit funktion functions auf
framecode-ebene? hmmm... vielleicht liegt hier mein denkfehler, ich geh mal
davon aus dass man an create für func eigentlich immer nur strings übergibt
die dann halt auf die tatsächlichen functions mappen...

fünfte zeile: das war mir soweit klar, allerdings wurde die funktion doch erst
erzeugt/zusammengebaut und daher ist der arguments array doch noch leer,
oder? naja, dann werden die übergebenen parameter reingehängt... klar.

letzte commentzeile: die hilfe hab ich gelesen =) anwendung auf objekt is klar,
rest siehe vierte zeile... den unterschied blick ich nicht...

sorry... da wills mal wieder einer genau wissen...