loadVars

[monroe]

Mahlzeit

Ich habe mal eine Frage bezüglich loadVars.

Wie geht ihr denn mit der Kommunikation zwischen PHP und FLASH um.
Habt ihr eine zentrale Funktion oder Klasse die dies managed, oder definiert ihr an 50 verschiedenen Orten dann 50 verschiedene loadVars.

Ich hab mir eine zentrale Funktion geschrieben, die das Daten-Management übernimmt. Ich bin jedoch nicht zufrieden, da diese Funktion sehr unflexibel ist.

Wie geht ihr damit um?

Ich bedanke mich mal

gruss

[hgseib]

"..Ich bin jedoch nicht zufrieden, da diese Funktion sehr unflexibel ist .. Wie geht ihr damit um?.."
genauso: wir sind damit unzufrieden ;-)

zeig vielleicht einmal deine lösung und sage uns, was genau dir daran nicht passt. da kann man drüber reden.

[Janoscharlipp]

Bei uns läuft sowas immer über eine zentrale Klasse, ich würde ganz im Gegenteil behaupten, das das sehr flexibel ist.
Womit hast du denn Probleme?

[monroe]

Servus

Zitat von Janoscharlipp

Bei uns läuft sowas immer über eine zentrale Klasse, ich würde ganz im Gegenteil behaupten, das das sehr flexibel ist.
Womit hast du denn Probleme?

Ja deine Lösung sicher, meine nicht


Also meine Lösung sieht folgendermaßen aus.

Ich habe eine Funktion unter _root definiert, die einen Parameter übergebene bekommt.
Innerhalb der Funktion wird dann ein loadVars Objekt erzeugt und die Daten aus der PHP Datei gelesen.

Bin ich jetzt in einem MC zum Beispiel _root.xxx.meinMC rufe ich die _root.funktion auf.
Am liebsten wäre mir, wenn die _root.funktion den Inhalt aus der PHP Datei einfach zurück gibt und ich im MC: _root.xxx.meinMC dann meinString = _root.funktion schreiben kann.
Ich bekomme jedoch immer einen Leerstring zurück. Ich vermute weil die Daten noch nicht verfügbar sind wenn die Funktion die Daten zurück gibt.

Ich habe dies dann gelöst, dass meine _root.funktion eine funktion (zum Beispiel: _root.xxx.meinMC.schreibeDatenAusPhpInTextdatei() ) aufruft wenn die Daten geladen sind. Dann funktioniert es.

Und das ist schon meine Frage, wie kann dies umgehen das ich nicht irgendwelche Funktionen aufrufen muss die Daten an gewünschtem Ort und Stelle verfügbar zu machen.

Wenn es zu verwirrend ist erkläre ich es gerne noch mal

Vielen dank

Gruss

[hgseib]

du hasst dir bereits selbst die antwort gegeben:
"..Ich vermute weil die Daten noch nicht verfügbar sind wenn die Funktion die Daten zurück gibt.."
das ist korrekt!

AS wartet nicht, bis die daten geladen sind, sondern der aktuelle script wird zu ende geführt.
der vorgang etwas vom server nach zu laden geschieht asynchron. die daten kommen irgendwann viel später - oder auch garnicht.
sonst bräuchte man ja auch keine empfangs-funktionen wie onLoad durch .send, .load bzw .sendAndLoad ausgelösst.

[monroe]

danke für die Antwort

Aber wie bewerkstellige ich dass dann?
In meiner _root.funktion befindet sich eine Routine die prüft ob die Daten erfolgreich und ganz geladen wurden.
Sollte ich die Daten extern zwischenspeichern? Dann müsste ich ja aber in einem onEnterFrame fragen wann diese Variable "gefüllt" wäre.

Mir ist nicht klar wie ich auf diesen Ladevorgang (onLoad) in der Funktion, an einer anderen Stelle warte.

Gruss

[Janoscharlipp]

Du wartest garnicht, sondern du übergibst deiner _root-Funktion eine Callback-Funktion, die dann die Daten verarbeitet.

Allerdings würde ich für sowas als allererstes mal ne Klasse anlegen, die sich um die Ladevorgänge kümmert, einfach so ne Funktion in _root ... das ist nicht wirklich sauber.
Die Klasse kannst du dann auch immer wieder verwenden, durch die Callbacks ist sie allgemein einsetzbar.

[hgseib]

"..Dann müsste ich ja aber in einem onEnterFrame fragen wann diese Variable "gefüllt" wäre.."
ja, nur eleganter: das onLoad-event teilt dir genau das mit.

meine besten 'erklärversuchsergebnisse' hatte ich damit (sinngemäss):
du arbeitest nur in frame1.

function xxxx.onLoad(ok)
{ if (ok) gotoAndPlay(2);
}

sobald der programmablauf in frame 2 angekommen ist kannst du die geladenen daten benützen.
das mit den frames dient nur zur erklärung. das geht auch, wenn du nach if-ok eine funktion aufrufst.

jedenfalls, die ursprünglich auslösende funktion ist abgelaufen, tot, passe, im datenhimmel, wo auch immer aber auf garkeinen fall mehr auf empfang!

[monroe]

ich dank euch, ich werd dies mal mit einer Klasse verusuchen und euch spätestens dann wieder nerven

danke

Gruss

[monroe]

hallo jungs

ich hab meine erste klasse in flash geschrieben, bitte nicht hauen!!!
sind arge Konzeptionsfehler vorhanden?

*angst hat*

ich hab eine PHP Datei:
php.php

PHP-Code:

$sRet = "flashforum";
echo "&phpinfo=".urlencode(utf8_encode($sRet)); 


einen movieclip in der ich meine klasse aufrufe:

import CphpDb;
 
var oDb:CphpDb = new CphpDb();
 
textfeld.text = oDb.ausgabe; 

und meine klasse!

/**************************************************************************************************************
**************************************************************************************************************/
class CphpDb
//*************************************************************************************************************
{
    private var lvData:LoadVars;
    private var sData:String;
    
    function CphpDb()
    {
        //erzeugt ein neues LoadVar Objekt
        lvData = new LoadVars();
        sData = "err";
    } //end Konstruktor
    
    private function onLoadData():Number
    {
        var nRet:Number = 0;
        lvData.onLoad = function(sucess)
        {
            if (sucess)
            { 
                sData = this.phpinfo;
                nRet = 1;
            }
            else
            {
                nRet = 0;
            } //end if
        } //end onLoad
        return nRet;
    } //end onLoadData
    
    private function sendData():Number
    {
        var nRet:Number = 0;
        lvData.sendAndLoad('php.php', lvData);
        if (onLoadData() == 1)
        {
            nRet = 1;
        }
        return nRet;
    } //end sendData
    
    public function get ausgabe():String
    {
        if (sendData() == 1)
        {
            return sData;
        }
    } //end get sData
} //end class 
 

ausgegeben wird ein undefined!



danke für euer bemühen

gruss

[Janoscharlipp]

Jepp, da sind Konzeptionsfehler drinn

Also, es ist ja klar, dass das Laden von Daten in Flash immer asynchron abläuft, d.h. du startest eine Anfrage, kannst aber nicht im gleichen Atemzug die Daten verwenden, sondern musst entweder regelmäßig prüfen, ob die Daten da sind, oder über ein Callback verständigt werden.

Wenn man jetzt das hier ansieht:

import CphpDb;
      
var oDb:CphpDb = new CphpDb();
 
textfeld.text = oDb.ausgabe; 

Dann fehlt da schonmal das Asynchrone, egal was deine Klasse tut, so kann es nicht gehen, da oDb.ausgabe noch nicht definiert sein kann.

Am besten du baust mal in deinen Code ganz viele traces ein, und gibst an, was grad passiert, und dann noch die Zeit (einfach getTimer()) dazu aus, dann siehst du, wie dein aktueller Code durchlaufen wird.

[monroe]

servus Janoscharlipp und CO

ich war leider eine Weile verhindert und konnte nicht weiter machen. Aber ich habe troztdem eine Frage. Wie kann ich denn die onLoad Funktion public machen, so dass ich abfragen kann wann die Daten fertig geladen wurden.

zum Beispiel:
wenn objekt.status = ok ist dann
objekt.ausgabe der dateien

ich verzweifel:

class CphpDb
{
    private var lvData:LoadVars;
    private var sData:String;
    private var bStatus:Boolean;
    
    function CphpDb()
    {
        lvData = new LoadVars();
        sData = "err";
    }
    
    private function getDataFromPhp()
    {
        lvData.sendAndLoad('php.php', lvData, 'POST');
        lvData.onLoad = function (sucess)
        {
            if (sucess)
            {
                sData = this.phpinfo;
                bStatus = true;
            }
        } //end onLoad    
    }
    
    public function get stat()
    {
        getDataFromPhp();
        if (bStatus == true)
        {
            return true;
        }
    }
    
    public function ausgabe():String
    {
        return sData;
    }
        
    
} 

aufruf:

import CphpDb;
var oDb:CphpDb = new CphpDb();
if (oDb.stat)
{
    a.text = oDb.ausgabe();
} 

danke für die hilfe

gruss

[shorty]

Mit Events vieleicht?

Biliges beispiel:

PHP-Code:

<?php
    echo "&word=hello world!&";
?>

PHP-Code:

import mx.utils.Delegate
import mx.events.EventDispatcher

class CphpDb
{
    
    var source : LoadVars
    var data : String
    
    private var dispatchEvent : Function
    public var addEventListener : Function
    public var removeEventListener : Function
    
    function CphpDb ()
    {
        EventDispatcher.initialize( this )
    }
    
    public function load ( url : String )
    {
        source = new LoadVars ()
        source.onLoad = Delegate.create ( this, onDataComplete )
        source.sendAndLoad ( url, source, 'POST' )        
    }
    
    private function onDataComplete ( success : Boolean )
    {
        if ( success )
        {
            data = source.word
            dispatchEvent ( {type:'onDataComplete', target:this} );
        }
    }
    
} 


PHP-Code:

var test : CphpDb = new CphpDb ()
function output ( e : Object )
{
    trace (e.target.data)
}
test.addEventListener ( 'onDataComplete', output )
test.load ( 'http://localhost/say.php' ) 


Anbei noch ein link zum Eventdispatcher: http://www.asnative.de/artikel/eventdispatcher.html