inspectable und singleton?

[troner]

Guten Tag die Herren,

Ich habe ein Problem in zusammenhang mit dem singleton pattern und des inspectable tags!

konkretes bsp ist ein adventkalender an dem sich fenster anmelden sollen aber die designer am adventkalender und an den fenstern paramter einstellen können!

das problem ist aber das er die inspectable tags anscheinend nicht erkennt bzw. glaub ich das es an der compiler-reihenfolge liegt!

hier mal ein schnipsel zur verdeutlichung:

class xmas.Adventkalender {
    
    private static var _instance:Adventkalender = null;
    
    [Inspectable(name="Alle Fenster Zeigen", type="Boolean", defaultValue=true)]
    public static var showAll:Boolean;
    
    public function Adventkalender()
    {   }
    
    public static function getInstance():Adventkalender
    {
        if(Adventkalender._instance == null) {
            Adventkalender._instance = new Adventkalender();
        }
        
        return Adventkalender._instance;
    }
    
    public function getItem()
    {
        trace(showAll);
    }
} 

import xmas.*;
 
class xmas.Fenster extends MovieClip {
    
    private var a:Adventkalender;
    private var tagTxt:TextField;
    
    [Inspectable(name="Tag", type="Number")]
    public var tag:Number;
    
    public function Fenster()
    {
        //instance of adventkalender
        a = Adventkalender.getInstance();
        a.getItem();
        
        tagTxt = this.tagTxt;
        tagTxt.text = String(tag);
    }
    
} 

also wenn ich jetzt aus Fenster.as getItem von Adventkalender.as aufrufe traced der undefined??

das fla häng ich auch noch an!

vieleicht hat jemenad schon mal so ein problem gehabt oder weiß eine andere lösung will das nur nicht wieder mit global lösen!

g und danke mario

[michael]

wenn showAll static ist (sein muss?), kannst du zwangläufig auch
nicht direkt aus der instanz darauf zugreifen.

gehts denn so?

PHP-Code:

public function getItem()
{

      trace(Adventkalender.showAll);

} 


[michael]

sorry das war natürlich unsinn, du kannst ja von instanzen auf statische variablen zugreifen.
ich hatte das mit statischen methoden, die nicht auf instanzvariablen zugreifen können durcheinandergeworfen

[troner]

hallo

des gibts ja nicht wie kann ich das lösen wenn ich da inspectable parmater verwenden will!

so gehts natürlich tadelos:

//[Inspectable(name="Mode", type="Boolean", defaultValue=true)]
    public var showAll:Boolean;
    
    public function Adventkalender()
    {
        showAll = true;
    } 

bleibt wirklich nur _global?

g mario

[bokel]

Vielleicht kannst du einen setter/getter draus machen, der intern auf die statische Variable zugreift?

mfg. r

[troner]

danke bokel,

für deine antowort hab folgendes versucht aber jetzt steh ich völlig daneben!

im adventkalender.as

[Inspectable(defaultValue="true")]
    public function set mode(showAll:Boolean)
    {
        this.showAll = showAll;
    }
    
    public function get mode():Boolean
    {
        trace(showAll);
        return showAll;
    } 

und im Fenster.as

public function Fenster()
    {
        //instance of adventkalender
        a = Adventkalender.getInstance();
        trace(a.mode);
        
       } 

und da kommt jetzt auf einmal im trace 1.true, 2.undefined, 3. undefined???

das heißt allso das die flash ide die get und set ausführt und auch die var kennt aber Fenster.as nicht?!

bitte komm einfach nicht weiter oder soll ich das vergesen und anders drangehen aber wie?

g mario

[bokel]

Es ist doch showAll und nicht this.showAll im setter, oder?
mfg. r

[troner]

hallo

das mach ich immer damir ich die namen gleich habe macht aber nicht wirklich einen unterschied!

auch ohne this gehts nicht!

und ich hab keine ahnung warum das so sein soll!

g mario

[bokel]

Ich dachte showAll ist static, oder ?
mfg.r

[bokel]

Ich frage mich allerdings, was passiert, wenn mehrere Fenster in die selbe globale oder static Variable schreiben. Dann gewinnt jeweils der letzte. Ist es das, was du willst?

mfg. r

[troner]

aso ja war static da hab ich aber nur alle möglichen varianten versucht!

was ich eigentlich wollte ist das alle fenster vom adventkalender paramter abrufen können - die designer einstellen können!

das problem ist ja das er immer undefined ausgibt sobald ich die variable mit inspectable anlege sobald ich sie normal anlege also im constructor oder so - dann kann das fenster sie ja auch lesen??!

g mario

[troner]

ich weiß jetzt warum er die variable nicht lesen kann - falls das problem wieder mal wer haben sollte!

wenn man die komponenten mit der klasse per bibliothek verbindet (was ja sinn und zweck ist) gehts nicht weil die ide zum instanziern eine andere routine benutzt! also ist der singleton definitiv nichts für komponenten!

aber die frage wie man verschiedene komponenten sauber miteinander kommunizieren lässt und variablen teilt bleibt! das einzige was mir da eingefallen ist:

//adventkalender.as
/**
 * @author mue
 */
 
class xmas.Adventkalender {
 
    [Inspectable(name="Alle zeigen", type="Boolean", defaultValue=true)]
    public var showAll:Boolean;
    
    private var windowArr:Array;
    
    public function Adventkalender()
    {   
        //das stoert mich einfach so extrem!! zum kotzen!
        _global.adventkalender = this;
        windowArr = new Array();
    }
    
    public function addWindow(win:MovieClip)
    {
        for(var i:String in windowArr) {
            if(windowArr[i] == win) return;
            else windowArr.push(win);
        }
    }
 
}
 
//fenster.as
/**
 * @author mue
 */
 
import xmas.*;
 
class xmas.Fenster extends MovieClip {
    
    private var a:Adventkalender;
    private var tagTxt:TextField;
    
    [Inspectable(name="Tag", type="Number", defaultValue=1)]
    public var tag:Number;
    
    public function Fenster()
    {      
        _global.adventkalender.addWindow(this);
    }
    
    private function init()
    {
        tagTxt = this.tagTxt;
        tagTxt.text = String(tag);
    }
    
} 

aber schön ist das nicht!

g mario

[michael]

ich würds vermutlich wie bei den radioButtons machen.

mit übergeordneter class xmas.FensterGroup

[Janoscharlipp]

So geht es bei mir, aber das ist wohl nicht was du willst, oder?

PHP-Code:

/**
 * @author mue
 */
class xmas.Adventkalender {
    
    private static var _instance:Adventkalender = null;
    
    private static var _showAll : Boolean;
    
    [Inspectable(name="Alle Fenster Zeigen", type="Boolean", defaultValue=true)]
    public function set showAll(newValue:Boolean) : Void
    {
        _showAll = newValue;
    }
    
    public function get showAll() : Boolean
    {
        return _showAll;
    }
    
    public static function getShowAll(Void) : Boolean
    {
        return _showAll;
    }
    
    public function Adventkalender() {
        trace("Adventkalender#Adventkalender - showAll: " + showAll);
    }
    
    public static function getInstance():Adventkalender
    {
        if(Adventkalender._instance == null) {
            Adventkalender._instance = new Adventkalender();
        }
        
        return Adventkalender._instance;
    }
    
    public function getItem()
    {
        trace(showAll);
    }
} 


[troner]

@Janoscharlipp du bist der held - das ist genau das was ich gesucht habe!°!

hab mir aber eingebildet das ich das selbe auch versucht habe!

vielen dank!!!

PS: für was wär das gewesen?

public static function getShowAll(Void) : Boolean 
    { 
        return _showAll; 
    } 

g mario