[F5/MX proto] - pause/resume mit childs

[Niels]

Hallo @ All

Ist ne ganze Weile her das ich was zu sagen hatte, von daher an viele von "damals": Hoffe es geht auch allen gut

Ich hab ehrlich gesagt keine Ahnung ob es nicht in den letzten Monaten mal so ähnlich schonmal da war, dazu war ich einfach zuwenig hier. Aber suchen und finden hat mich zumindest nicht auf die Spur gebracht ... oder ich war zu dumm die richtigen Begriffe einzutippen *g*

Ich hab das hier für ein CD-Rom Projekt gebraucht bei dem ich massiv viele verschachtelte Clips hatte die "minianimationen" enthielten. Das ganze Projekt sollte pausierbar sein. Ist für die Usability ja auch sehr praktisch. Das hier ist dann bei rausgekommen.

Naja, mich würde wir immer interessieren ob es eine andere Möglichkeit gibt das ganze eleganter zu realisieren und würde es damit hiermit zum Abschuss freigeben. Einziger Punkt von mir wäre: Man könnte pause() und resume() noch in eine funktion packen die nach dem status geht. Hab ich bis jetzt einfach noch nicht gemacht weils so schön fehlerlos lief ... und naja ...deadlines. Ihr wisst ja

Viel Spass und Grüße aus Freiburg

hth
Niels

[BESCHREIBUNG]
Eigentlich sehr easy: Clip samt Childs mit Clip.pause(); anhalten und mit Clip.resume(); wieder anfahren. Das sollte eigentlich reichen. Hoffe ich hehe.

[ANMERKUNG]
Es sollte eigentlich sowohl unter F5 als auch unter MX gehen. Da ich aus Zeitgründen noch nicht so wirklich tief in die "neuen MX Strukturen" geschaut habe will ichs aber nicht versprechen. Würde mich freuen einer von auch Xlern guggt mal drüber.

So. Ende des Romans.

MovieClip.prototype._isPlaying = true;
MovieClip.prototype._isPaused = false;
 
//überschreiben der play methode
MovieClip.prototype.play2 = MovieClip.prototype.play;
MovieClip.prototype.play = function(){
    if(!this._isPaused) this.play2();
    this._isPlaying = true;
}
 
//überschreiben der stop methode
MovieClip.prototype.stop2 = MovieClip.prototype.stop;
MovieClip.prototype.stop = function(){
    this.stop2();
    this._isPlaying = false;
}
 
//überschreiben der gotoAndPlay methode
MovieClip.prototype.gotoAndPlay2 = MovieClip.prototype.gotoAndPlay;
MovieClip.prototype.gotoAndPlay = function(frame){
    if(!this._isPaused) this.gotoAndPlay2(frame);
    else this.gotoAndStop2(frame);
    this._isPlaying = true;
}
 
//überschreiben der gotoAndStop methode
MovieClip.prototype.gotoAndStop2 = MovieClip.prototype.gotoAndStop;
MovieClip.prototype.gotoAndStop = function(frame){
    this.gotoAndStop2(frame);
    this._isPlaying = false;
}
 
//neue MC methoden: pause und resume
MovieClip.prototype.pause = function(){
    this._isPaused = true;
    this.stop2();
    for(child in this) {
        if(typeof(this[child]) == "movieclip") {
            if(this[child] != this) this[child].pause();
            //debugg bzw. info output. Falls gewüscht auskommentieren
            //else trace(this[child]);
        }
    }
}
MovieClip.prototype.resume = function(){
    if(this._isPaused){
        this._isPaused = false;
        if(this._isPlaying) this.play2();
        for(child in this) {
            if(typeof(this[child]) == "movieclip") {
                if(this[child] != this) this[child].resume();
            }
        }
    }
} 

[beachmeat]

Nope noch nich gesehen, und mit Sicherheit eine gute Sache, besonders wenn der Kunde erst zum Ende des Projektes eine Pause-funktion wünscht

Eingesackt

[Madokan]

Niels welcome back.

Liebe Grüsse
Matze K.