EventProxy.as -- Argumente übergeben?

[dante]

hallo,

habe heute versucht mit der EventProxy Klasse was anzustelle, soweit klappt das auch ganz gut nur ich bekomme es nicht hin argumente an die funktion zu übergeben:

EventProxy.as

/*
EventProxy class
Allows:
-scope of events to be changed
-events calls to be proxied to arbitrary functions
*/
 
class com.macromedia.mesh.events.EventProxy
{
 private var receiverObj:Object;
 private var funcName:String;
 
 /*
 Constructor:
 -receiverObj : the receiverObj in which the event will be called
 -the function name to be called in response to the event
 */
 function EventProxy(receiverObj:Object, funcName:String)
 {
  this.receiverObj = receiverObj;
  this.funcName = funcName;
 }
 
 //this is called before the event is broadcast by the components
 private function handleEvent(eventObj:Object):Void
 {
  //if not function name has been defined
  if(funcName == undefined)
  {
   //pass the call to the event name method
   receiverObj[eventObj.type](eventObj);
  }
  else
  {
   //pass the call to the specified method name
   receiverObj[funcName](eventObj);
  }
 }
} 

ich benutz sie so auf nem button:

private function erstelleMenuNeuesDokument() {
    trace("erstelleMenuNeuesDokument() aufgerufen")
 
    var tiefe = 0
    
    var but:Button = neuesdok.createClassObject(Button, "neu", tiefe++);
    but.label = "Erstelle Map";
    but.addEventListener("click", new EventProxy(this,"erstelleNeueMap"));
    }
 
private function erstelleNeueMap(gridBreite:Number,gridHoehe:Number,tileGroesse:Number) {
    trace("erstelleNeueMap( "+gridBreite+", "+gridHoehe+", "+tileGroesse+" ) aufgerufen")
} 

und möchte drei Parameter an die Funktion übergeben. Habs schon versucht nen String zusammenzubauen (wird ja als String übergeben) und abenteuerliche Konstruktionen mit [] bzw {} probiert. Funktioniert alles irgendwie nicht.

Könnt ihr mir bitte auf die Sprünge helfen woran es harkt oder gibts da sogar ne bessere Lösung dafür?

EventProxy habe ich noch nicht verwendet, aber schau Dir doch mal die Delegate-Klasse von Andre Michelle an. Die liegt im event-Verzeichnis der Game Package (http://www.gamepackage.org/ ). Ich habe die Klasse für mein letztes Projekt benutzt und bin ganz glücklich damit.
z.B. mc.onRollOver = Delegate.createArgs ( this, rollOver, arg1, arg2, arg3 );

[atothek]

ansich muß die proxy methode erstmal public sein da der zugriff von außerhalb der klasse kommt, aber das ist nich das problem wie skinny schon andeutet werden bei der EventProxy klasse keine optionalen arguments unterstützt. was in deinem fall mehr sinn machen würde wäre folgende klasse

class Delegate {
    
    private function Delegate(){};
 
    public static function create(pObj, pFunc) : Function {
        var args : Array = arguments.splice(2);
        return function(){
            if(pFunc instanceof Function)
                return pFunc.apply(pObj, arguments.concat(args));
            else 
                return pObj[pFunc].apply(pObj, arguments.concat(args));
        };
    }
} 

die unterstützt arguments verwendung wie folgt

but.addEventListener("click", Delegate.create(this,"erstelleNeueMap", 20, 20, 5 ));

mfg alex

[cancerinform]

Hier ist ein Beispiel fuer die Proxy class.

http://flashscript.biz/MX2004/OOP_tu...0Proxy%20class