Ein einfaches Ballerspiel (MX Code)

[bokel]

Das Grundgerüst für ein einfaches Ballerspiel ist relativ
schnell gemacht. (Vor allem weil ich kein OOP benutzt
habe )

Was mich hier besonders interessiert hat, war die
Unterbringung der Schuesse und Feinde in eigenen MCs.
Dadurch wird die Buchhaltung stark vereinfacht, weil man
einfach mit for in Loops durch die Feinde oder Schuesse
laufen kann.

createEmptyMovieClip("schuesse", 1);
createEmptyMovieClip("feinde", 2);
 
function Schuss(x, y, RichtungWinkel, Speed){
    //Hier benutze ich bewusst nicht .depth,
    //weil depth nicht in der "for in"-Schleife" über 
    //schuesse auftauchen soll
    var d = ++schuesse_depth;
    var mc = schuesse.createEmptyMovieClip("s" + d, d);
    //startposition festlegen
    mc._x = x;
    mc._y = y;
    //winkel in x und y anteil zerlegen
    var alpha = RichtungWinkel * Math.PI / 180;
    mc.xSpeed = Math.cos(alpha) * Speed;
    mc.ySpeed = Math.sin(alpha) * Speed;
    //frameloop eines schusses
    mc.onEnterFrame = function(){
        //animation des schusses
        this._x += this.xSpeed;
        this._y += this.ySpeed;
        //kill me, wenn wir aus dem bild fliegen
        if(this._x < 0 || this._x > 550) this.removeMovieClip();
        if(this._y < 0 || this._y > 400) this.removeMovieClip();
        //kollision mit einem feindl. raumschiff ? 
        for(var i in feinde){
            if(this.hitTest(feinde[i])){
                feinde[i].removeMovieClip();
                this.removeMovieClip();
                break;
            }
        }
    }
    //schuss zeichnen
    mc.lineStyle(2, 0xff0000);
    mc.lineTo(5,0);
    mc._rotation = RichtungWinkel;
}
 
function Feind(){
    //Hier benutze ich bewusst nicht .depth,
    //weil depth nicht in der "for in"-Schleife" über 
    //feinde auftauchen soll
    var d = ++feinde_depth; 
    //
    var mc = feinde.createEmptyMovieClip("f" + d, d);
    mc._x = random(550);
    mc._y = random(400);
    mc.xSpeed = Math.random() * 5 - 2;
    mc.ySpeed = Math.random() * 5 - 2;
    mc.zSpeed = Math.random() * 3 - 1;
    //
    //frameloop eines feindes
    mc.onEnterFrame = function(){
        //animation der position
        this._x += this.xSpeed;
        this._y += this.ySpeed;
        //animation von groesse und alpha um tiefe zu simulieren
        this._alpha = this._xscale = this._yscale += this.zSpeed;      
        //an den rändern kommen wir zurueck
        if(this._x < 0 || this._x > 550) this.xSpeed = -this.xSpeed;
        if(this._y < 0 || this._y > 400) this.ySpeed = -this.ySpeed;
        if(this._xscale < 50 || this._xscale > 150) this.zSpeed = -this.zSpeed;
    }
    //feind zeichnen
    mc.lineStyle(0, 0x00ff00);
    mc.beginFill(0x003333);
    mc.moveTo(-20,-20);
    mc.lineTo(20,-20);
    mc.lineTo(20,20);
    mc.lineTo(-20,20);
    mc.endFill();
}
 
onMouseUp = function(){
    Schuss(550/2, 400, Math.atan2(_ymouse-400, _xmouse-550/2) * 180 / Math.PI, 3);  
}
 
for(i=0; i<10; i++) Feind(); 

Mit Copy & Paste sollte das funktionieren

mfg r.

[michael]

funktioniert super.

missile command wär damit schnell gebaut

gruss
michael

[nky]

nice !!!

Gruss nky

[sebastian]

subba! mx rulez das ist das tolle. früher musste man noch eine halbe seite anleitung beilegen, welche mcs zu erstellen sind, welcher welche aktion bekommen muss und heutzutage brauchtm man nur einen code

lg,
sebastian

[Madokan]

Yup mx macht schon spass nicht Daumen!

mfg
Matze K.

[Gnut]

fleissige arbeit bokel!

oder wollen wir ihn mr. bokel nennen?

[the-ox]

wie wärs mit mr bokelman

ps:
schickes teil

[bloba]

wow der fällt mir echt nix mehr ein....

[dassoud]

klasse!

..und keine 80 zeilen...

dassoud