asbroadcaster

[Skyla]

hi all

hier eine möglichkeit, das gleiche onEnterFrame-Event mehrmals zu nutzen.

hat 2 Vorteile:
-saves cpu
-der code kann besser strukturiert werden

ASBroadcaster.initialize(MovieClip);
mc = this.createEmptyMovieClip("EHSource", 4444);
 
 
MovieClip.addListener(mc1_mc)
MovieClip.addListener(mc2_mc)
mc1_mc.onMotor = function() {
    this._x += 2;
};
mc2_mc.onMotor = function() {
    this._x -= 2;
};
 
mc.onEnterFrame = function() {
    MovieClip.broadcastMessage("onMotor");
}; 

vielleicht ja noch nicht allen bekannt.

gruss skyla

[michael]

ja das ist sehr schön

viel interessanter finde ich, das man so auch Nicht-MovieClips mit einem onEnterFrame versehen kann:

ASBroadcaster.initialize(MovieClip);
this.createEmptyMovieClip("oEF", 10000);
this.oEF.onEnterFrame = function() {
    MovieClip.broadcastMessage("onEnterFrame");
};
//
//
myArray = ["a", "b", "c", "d", "e"];
myArray.onEnterFrame = function() {
    trace(this[random(this.length)]);
};
MovieClip.addListener(myArray); 

aber das ist wohl für die meisten OOPler nichts mehr neues.
zuerst in derartiger form von Robert Penner veröffentlicht, glaube ich.

gruss
michael

[Madokan]

michael zwar nichts neues aber ich bin sicher immer wieder gern gesehen.

Hinweis: Im Umgang mit dem ASBroadcaster solltet Ihr etwas vorsicht walten lassen. In einigen Flash Player Versionen (6,0,29,0 u. 6,0,40,0) gab es auf WinME u. Win98 Systemabstürze.

In wie weit der ASBroadcaster von macromedia beibehalten wird steht auch noch nicht fest. Lassen wir uns mal überraschen.

Liebe Grüsse
Matze K.

[michael]

ihhh Abstürze?
danke für den hinweis, war mir auch noch nicht bekannt.
naja, mit undokumentiertem sollte man immer vorsichtig sein


gruss
michael

[bokel]

Da die internen Listener auch alle mit ASBroadcaster arbeiten,
benutzt du ihn ja automatisch. Abstürze sind mir auch nicht
bekannt, hast du ein Beispiel dafür ?

Wenn man kein Vertrauen in den eingebauten
Broadcaster hat, kann man sich auch leicht einen
selber bauen.

mfg r.

[Madokan]

bokel: Vorsicht die internen Listener besitzen jedoch auch eine höhere Priorität, dies scheint auch Auswirkung auf die Ausführung (Stabilität) zu haben. Was mich nur stutzig macht ist die Tatsache, dass dieses Problem nicht auf allen Windows-Systemen durchweg zu finden ist. Bei WinNT oder WinXP hatte ich bisher noch nicht einen Abschuss.

Hab mal spassehalber den Code hier aus dem Thread genommen und unter dem Player 6,0,29,0 gab es auf WinME einen sauberen Crash - nix ging mehr.

Ich muss jedoch gestehen, dass auch mir das ganze doch noch ein Rätsel ist. Aber ich bleib dran!

Liebe Grüsse
Matze

[Skyla]

Danke für den Hinweis, Matze.

@Bokel: wie baust du einen eigenen broadcaster ?

[lp400]

Hi

Branden Hall hat schon einen EventBroardcaster gebaut. Funktioniert super:

_global.EventBroadcaster = new Object();
 
EventBroadcaster.initialize = function(obj){
    obj._listeners = new Array();
    obj.broadcastMessage = this._broadcastMessage;
    obj.addListener = this._addListener;
    obj.removeListener = this._removeListener;
}
 
EventBroadcaster._broardcastMessage = function(){
    var eventName = arguments.shift();
    var list = this._listeners;
    var max = list.length;
    for (var i=0; i<max; ++i){
        list[i][eventName].apply(list[i], arguments);
    }
}
 
EventBroadcaster._addListeners = function(){
    this.removeListener(obj);
    this_listeners.push(obj);
    return (true);
}
 
EventBroadcaster._removeListeners = function(){
    var list = this._listeners;
    var i = list.length;
    while (i--){
        if (list[i] == obj){
            list.splice(i, 1);
            return (true);
        }
    }
    return (false);
} 

Gruß, Herbert

[Skyla]

Hi Herbert, vielen Dank.
Bei mir klappts weniger gut;
zB auf diesen Test:

Mouth = new Object();
Ear = new Object();
EventBroadcaster.initialize(Mouth);
Ear.onSpeak = function() {
    trace("I hear you");
};
Mouth._addListeners(Ear);
Mouth._broadcastMessage("onSpeak"); 

gruss stephan

[lp400]

@Skyla

Oh mann, da habe ich ja ne Menge Tippfehler eingebaut.
Sorry

Hier ist noch einmal Dein Beispiel, das jetzt funktioniert:

_global.EventBroadcaster = new Object();
 
EventBroadcaster.initialize = function(obj) {
    obj._listeners = new Array();
    obj.broadcastMessage = this._broadcastMessage;
    obj.addListener = this._addListener;
    obj.removeListener = this._removeListener;
}
 
EventBroadcaster._broadcastMessage = function() {
    var eventName = arguments.shift();
    var list = this._listeners;
    var max = list.length;
    for (var i = 0; i<max; ++i) {
        list[i][eventName].apply(list[i], arguments);
    }
};
EventBroadcaster._addListener = function(obj) {
    this.removeListener(obj);
    this._listeners.push(obj);
    return (true);
}
 
EventBroadcaster._removeListener = function(obj) {
    var list = this._listeners;
    var i = list.length;
    while (i--) {
        if (list[i] == obj) {
            list.splice(i, 1);
            return (true);
        }
    }
    return (false);
}
 
Mouth = new Object();
Ear = new Object();
EventBroadcaster.initialize(Mouth);
Ear.onSpeak = function() {
    trace("I hear you");
};
Mouth.addListener(Ear);
Mouth.broadcastMessage("onSpeak"); 

Zur Sicherheit lege ich noch die FLA bei.

Gruß, Herbert

[Skyla]

@IP400: jetzt ist fein. Dank Dir bestens; kann ich gut gebrauchen.

Gruss Skyla

[theWEBster]

schöne sache!!!
werd ich mir gleich mal zu gemüte ziehen

[TOAOTC]

... sagt doch eigentlich schon alles, oder?

_global.EventBroadcaster = function(obj) {
    this._listeners = new Array();
}
 
EventBroadcaster.prototype._broadcastMessage = function() {
    var eventName = arguments.shift();
    for (i in this._listeners) {
        this._listeners[i][eventName].apply(this._listeners[i], arguments);
    }
};
EventBroadcaster.prototype._addListener = function(obj) {
    this._removeListener(obj);
    this._listeners.push(obj);
    return (true);
}
 
EventBroadcaster.prototype._removeListener = function(obj) {
    for (i in this._listeners) {
        if (this._listeners[i] == obj) {
            this._listeners.splice(i, 1);
            return (true);
        }
    }
    return (false);
}
 
Mouth = new EventBroadcaster();
Ear = new Object();
Ear.onSpeak = function() {
    trace("I hear you");
};
Mouth._addListener(Ear);
Mouth._broadcastMessage("onSpeak"); 

Kann mir jemand sagen, ob dieses Script genauso gut/besser/schlechter arbeitet und wo die Vorteile/Nachteile liegen?

*nachwissendürst* TOAOTC

[rOb]

zu skylas beispiel

wieso saves cpu?

mc1_mc.onEnterFrame = mc1_mc.onMotor;
mc1_mc.onMotor = function() {
        this._x += 2;
};
 
mc2_mc.onEnterFrame = mc2_mc.onMotor;
mc2_mc.onMotor = function() {
        this._x -= 2;
}; 

die strukturellen vorteile sind klar, auch das somit objekte ohne zeitleiste einen enterframe bekommen können, aber wieso soll das in dem beispiel cpu sparen? ich sehs nicht.....

thx rob

[Janoscharlipp]

vielleicht meinte er Speicher?
aber ob da jetzt ne funktion mehr oder weniger drinn steht?
tut sie das überhaupt?