iphone - Schriften/Textfield = Performance Killer?

[_geo_]

Hab auf meinem iPhone 2G arge Probleme Schriften in Textfeldern flüssig darstellen zu können: z.B. reicht schon ein einziges Textfeld aus um die Framerate von 31 fps auf 6-8 sinken zu lassen. Vorausgesetzt das Textfeld ist dynamisch und bekommt jeden Frame einen neuen Text zugewiesen.

Verwende ein iPhone 2G 3.1.3 (7E18), Jail Break, Modell: MA712LL

Wer selbst mal ausprobieren möchte, hier der code den ich verwendet habe:

var format:TextFormat = new TextFormat();  
format.font = "_sans";  
format.size = 16;
format.color = 0x0; 
format.align = "center";
 
_tf = new TextField();  
_tf.defaultTextFormat = format;  
_tf.text = "Some Text";
_tf.width = 300;
_tf.height = 30;
_tf.selectable = false;
_tf.mouseEnabled = false;
addChild(_tf);
 
// im EnterFrame dann
 
private function onUpdate(e:Event):void 
{
    e.stopPropagation();
    
    _tf.text = "Time: " + getTimer();
} 

Ich versteh nicht was dabei so arg viel Performance kostet, dass die fps einbrechen. Immerhin verwende ich nicht einmal ebmedded fonts ?!? Kann es sein, dass es am JailBreak liegt?

Bin für jeden Hinweis dankbar

[_geo_]

Hab nun als Workaround eine Klasse erstellt die mir eine Zahl aus einem Textfeld generiert in dem es die Ziffern "0-9", "-" und "." als BitmapData speichert und in eine "große" Bitmap schreibt.

Lösung ist das immer noch keine, allerdings hab ich nun 16 - 20 fps statt 6-8.

Für die dies interessiert:

package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.text.TextField;
    
    /**
     * ...
     * @author geo
     */
    public class NumberAsTexture extends Sprite 
    {
        private var _tmpMatrix:Matrix;
        private var _numOfChars:uint;
        private var _numberAsBitmapData:BitmapData;
        private var _numberAsBitmap:Bitmap;
        private var _number:Number;
        private var _numAsString:String;
        private var _charLookup:Array;
        private var _digitBitmaps:Vector.<BitmapData>;
        
        public function NumberAsTexture(num:Number, tf:TextField, numOfChars:uint = 8) 
        {
            super();
            
            // prepare tf
            tf.width = 4;
            tf.height = 4;
            tf.autoSize = "left";
            
            // update sprite
            x = tf.x;
            y = tf.y;
            mouseEnabled = tf.mouseEnabled;
            
            // number of digits defines the size of the generated bitmap
            _numOfChars = numOfChars;
            
            // preapre matrix
            _tmpMatrix = new Matrix();
            
            // possible chars
            _charLookup = ['0', '1', '2', '3', '4', '5', '6', '7', '8', '9', '10', '.', '-'];
            
            // prepare bitmaps
            _digitBitmaps = new Vector.<BitmapData>();
            _digitBitmaps.length = _charLookup.length;
            _digitBitmaps.fixed = true;
            
            // create bitmaps
            for (var i:uint = 0; i < _charLookup.length; ++i)
            {
                tf.text = "";
                tf.width = 4;
                tf.height = 4;
                tf.text = _charLookup[i];
                
                _digitBitmaps[i] = new BitmapData(tf.textWidth, tf.textHeight, true, 0x00ffffff);
                _tmpMatrix.identity();
                _tmpMatrix.tx = -2;
                _digitBitmaps[i].draw(tf, _tmpMatrix);
            }
            
            // create final output bitmap
            _numberAsBitmapData = new BitmapData( _digitBitmaps[0].width * _numOfChars + 2,
                                             _digitBitmaps[0].height, true, 0x00ffffff);
            _numberAsBitmap = new Bitmap(_numberAsBitmapData);
            
            addChild(_numberAsBitmap);
            
            number = num;
        }
        
        public function get number():Number { return _number; }
        
        public function set number(value:Number):void 
        {
            if (_number == value)
                return;
 
            _number = value;
            _numAsString = String(value);
            _tmpMatrix.identity();
            _tmpMatrix.tx = 2;
            _numberAsBitmapData.fillRect(_numberAsBitmapData.rect, 0x00ffffff);
            
            var l:uint = _numAsString.length;
            var char:BitmapData;
            for (var i:uint; i < l; ++i)
            {
                char = _digitBitmaps[ _charLookup.indexOf(_numAsString.charAt(i)) ];
                
                _numberAsBitmapData.draw( char, _tmpMatrix );
                _tmpMatrix.translate(char.width, 0);
            }
        }
        
    }
 
} 

Benutzt wirds so:

var texField:TextField = new TextField();
 
var tfAsTexture:NumberAsTexture = new NumberAsTexture(54231, texField);
addChild(tfAsTexture);
 
// udpate der zahl
tfAsTexture.number = 123.4; 

Lösung ist das aber immer noch keine *grml*. Ist das iPhone (2G) echt so lahm?

Wenn ich alles in Texturschnipsel zerlegen muss, dann kann ich auch gleich Objective-C und OpenGL nutzen, denn dafür brauch ich keine Flash LLVM *frust*.

[medianetic]

Ohne den Code zu überprüfen. Auf einem alten 2G wirst Du im Moment kaum eine sinnvolle App mit dem iPhone Packager machen können.

Ich habe ein 3GS und da sind simpelste Animationen schon verhältnissmäßig 'ruckelig'.

Das ist wohl alles eher noch in 'work in progress'. Wenn man nicht zu Objective-C und Co. direkt greifen möchte, muss man sich da im Moment noch sehr einschränken.

PS: Ich hoffe Adobe teilt uns bald mit, wann bzw. ob ein neues Update geplant ist.

[medianetic]

Native Apps laufen auf einem 3G allerdings auch nicht mehr flüssig.

[_geo_]

Hi, danke für die Bestätigung meiner Vermutung

Da mein Geldbörsel zurzeit keine 400€ für ein neues iPhone bereitstellen kann/möchte, werd ich wohl erst mal meine iPhone-Versuche einstellen.

Auch bin ich skeptisch ob es überhaupt jemals eine Packager Version geben wird die auch auf solch alten Geräten läuft. Ich denke Adobe schraubt zurzeit eher an ihrem Air für Android SDK und der Runtime dafür.

Na ja vllt wirds ja mal was mit Flash auf dem iPhone. Im Moment macht es wohl keinen Sinn darauf zu setzen wenn man sowieso nur die neueste Generation an Geräten damit ansprechen kann.

lg

edit: Jetzt erst gesehen in deiner Signatur: "Gesendet von meinem Windows-PC. " - sehr geil