[Flash CS3] DataGrid + CellRenderer (AS3)

[silentx]

Ich habe einen CellRenderer gemacht welchen ich verwende um Bilder
in einem Grid darzustellen. Wenn ich allerdings folgendes mache

grdMessages.getColumnAt(1).cellRenderer = wImageRenderer;
grdMessages.getColumnAt(2).cellRenderer = wImageRenderer;

wird das Bild immer von der Spalte 2 angezeigt, er geht auch immer
x mal durch den renderer weiss jemand wo das Problem liegen könnte?

[silentx]

Das Problem habe ich nun analysiert, im wImageCellRenderer gehe
ich immer alle Spalten durch.
Dadurch stellt sich mir die Frage, wie kann ich im Renderer abfragen kann
in welcher Spalte ich mich befinde? Habe irgendwie nichts gefunden oder
weiss jemand wo ich noch suchen könnte?

[silentx]

Problemlösung:
Für den Inhalt zu ändern sollte nicht 'set data(...)' sonder
'set listData(...)' verwendet werden.

Die Klasse sieht jetzt so aus:

package w.wComponents.cellRenderer
{      
    import fl.controls.listClasses.CellRenderer;
    import fl.controls.listClasses.ListData;
    import w.wComponents.wImage;
    import w.wMain.wGlobal;
 
    public class wImageRenderer extends CellRenderer
    {
        public const NAME:String        = "wImageRenderer";
        public const VERSION:String      = "0.9.1";
        public const ERSTELLDATUM:String = "21.05.2009";
        public const AENDERDATUM:String  = "23.09.2009";
        
        // Definition
        private var _obj:Object;
        private var _img:wImage;
        private var _imgWidth:Number;
        private var _imgHeight:Number;
        private var _listdata2:ListData;
        
        //{ Ebene 0 - Konstruktor
        //} ---------------------------------------------------------------------------------------------------
        private function X0____________________EBENE_0():void { };
        
        public function wImageRenderer():void
        {
            // Konstruktor von der Oberklasse ausführen
            super();
            
            // Label
            _imgHeight = 0;
            _imgWidth = 0;
            _img = new wImage();
            this.addChild(_img);                
        }
        
        //{ Ebene 1 - API
        //} ---------------------------------------------------------------------------------------------------
        private function X1____________________EBENE_1():void { };  
        
        override public function get data():Object
        {
            return _obj;
        }
        
        public override function get listData():ListData
        {
            return _listdata2;
        }
        
        override public function set data(value:Object):void
        {
            _obj = value;
            var obj:Object;
        }
        
        public override function set listData(ld:ListData):void
        {
            label = "";
            if (typeof(_obj[ld.column]) == "object")
            {
                var obj:Object = _obj[ld.column];
                if (obj.img != undefined && obj.width != undefined && obj.height != undefined)
                {
                    _img.source = obj.img;
                    _imgWidth = obj.width;
                    _imgHeight = obj.height;
                    _img.setSize(obj.width, obj.height);
                    _img.setXY(2, 2);
                }            
            }         
            _listdata2 = ld;
        }
        
        
        override public function setSize(width:Number, height:Number):void
        {
            super.setSize(width, height);
            if (_img != null && _imgWidth == 0 && _imgHeight == 0)
            {
                _img.setSize(width, height);
            }
        }
        
        //{ Ebene 2 
        //} ---------------------------------------------------------------------------------------------------
        private function X2____________________EBENE_2():void { };  
        
        //{ Ebene 3 
        //} ---------------------------------------------------------------------------------------------------
        private function X3____________________EBENE_3():void { };
        
    }
 
} 

Diese Klasse kann nicht 1:1 herauskopiert werden, da es noch
individuelle Elemente von meinem FrameWork verwendet werden.
Bei Fragen einfach schreiben...