Problem mit DataBinding

[kev52]

Hallo,

ich habe ein recht nerviges Problem beim Thema DataBinding:

Folgende Umgebung:

Einem DataGrid wird via DataBinding eine ArrayCollection (members) zugeordnet. Wenn ich ein Objekt im DataGrid markiere, so wird dieses Objekt (member) via Binding einem Formular zugeordnet.

protected function onGridClick(event:ListEvent):void
{
	currentMember = new Member();
	currentMember = myMembers.getItemAt(event.rowIndex) as Member;
}

Hier ist im MXML das Binding:

<components:MemberFormView id="form_memberData" member="{this.currentMember}" />

Wenn sich nun in der Komponente MemberFormView etwas ändert, so wird diese Änderung automatisch auch im DataGrid vorgenommen. Die Problematik dahinter ist mir auch bewusst, denn am Ende referenzieren die Elemente ja alle im Speicher auf das Objekt in der ArrayCollection. Wie kann ich aber eine Kopie von diesem Objekt erstellen, ohne dass es nur eine Referenz auf das Original ist sondern unabhängig?

[Omega Psi]

Das ist kein DataBinding Problem. Implementiere eine clone Methode und arbeite mit dem Klon wenn nötig.

[kev52]

Genau das meine ich ja, wie bekomme ich es hin, dass auch im speicher eine neue Kopie/Clone des Objektes erstellt wird.

Ah danke der Suche bin ich nun schlauer thx für den Ansatz ;o)

[Omega Psi]

Und ich schrieb: implementiere eine Methode clone

package fs.example.utils
{
 
    public interface ICloneable
    {
 
        function clone():Object;
    }
} 

package fs.example
{
 
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import fs.example.utils.ICloneable;
 
    public class MyType extends EventDispatcher implements ICloneable
    {
 
        private var _name:String;
 
        [Bindable("nameChanged")]
        public function get name():String
        {
            return this._name;
        }
 
        public function set name(value:String):void
        {
            if (this._name == value) return;
            this._name = value;
            this.dispatchEvent(new Event("nameChanged"));
        }
 
        public function MyType()
        {
            super();
        }
 
        public function clone():Object
        {   var newClone:MyType = new MyType();
            newClone.name = _name
            return newClone;
        }
    }
} 

Alernativ könntest du auch IFactory implementieren.

[kev52]

jop so hab ich es jetzt auch gemacht und es funktioniert bestens! Vielen Dank noch mal!