Parameter an Komponente übergeben

[phase]

hi, ich habe ein komponente die ein paar button und label enthält.
ich möchte jetzt für ein label den text mitgeben.

component:

[...]
private var destination:String;
			
			private function init():void 
			{
				destination = new String;
			}
			
			public function get dest():String
			{
				return this.destLabel.text;
			}
			
			public function set dest(str:String):void
			{
				this.destination=str;
			}
[...]

und so wird die dann eingebunden:

<controls:Fileupload id="TopNews" left="0" y="350" width="500" height="120" dest="hello"/>

dest soll dabei der text des labels destLabel werden.
Fehler werden nicht angezeigt aber wenn ich das ganze kompiliere, wird nur eine weisse seite angezeigt. wenn cih in dem setter 'this.destination=str;' aus kommentiere, wird alles angezeigt aber der parameter natürlich nciht übergeben.

kann mir bitte jemand verraten was ich falsch mache?

gruß,
phase

[phase]

ok, ich habs jetzt doch hinbekommen.

[Bindable]
private var _destination:String = "Default";
			
public function get dest():String {
	return _destination;
}
			
public function set dest(value:String):void {
	destination = value;
}

[Omega Psi]

Als gut gemeinter Nachtrag - und ich hatte die Beispiele nun schon getippt

Die sparsame Version. Ähnlich deiner nur mit wirtschaftlicherem DataBinding.

<?xml version="1.0" encoding="utf-8"?>
<mx:HBox xmlns:mx="http://www.adobe.com/2006/mxml">
	<mx:Script>
		<![CDATA[
			private var _title:String;

			[Bindable("titleChanged")]
			public function get title():String
			{
				return _title;
			}

			public function set title(value:String):void
			{
				if (_title == value) return;
				_title = value;
				dispatchEvent(new Event("titleChanged"));
			}
		]]>
	</mx:Script>
	<mx:Label text="{title}" />
</mx:HBox>

Bei UIComponents sollte man aber besser über die Template Methoden arbeiten:

<?xml version="1.0" encoding="utf-8"?>
<mx:HBox xmlns:mx="http://www.adobe.com/2006/mxml">
	<mx:Script>
		<![CDATA[
			private var _title:String;
			private var _titleChanged:Boolean = false;

			[Bindable("titleChanged")]
			public function get title():String
			{
				return _title;
			}

			public function set title(value:String):void
			{
				if (_title == value) return;
				_title = value;
				_titleChanged = true;
				invalidateProperties();
				dispatchEvent(new Event("titleChanged"));
			}

			override protected function commitProperties():void
			{
				super.commitProperties();
				if (_titleChanged)
				{
					_titleChanged = false;
					titleLabel.text = _title
				}
			}
		]]>
	</mx:Script>
	<mx:Label id="titleLabel" />
</mx:HBox>

Bei diesem Beispiel mag das überzogen wirken - ist es auch, aber bei komplexeren Komponenten kriegt man sonst mit der verzögerten Erzeugung der Komponente Probleme.

[hazy fantazy]

Binding ist dein Freund. Deklariere einfach eine oeffnetliche Variable fuer die Eigenschaft die du deiner Komponente zuweisen willst und bind dann intern an diese Eigebschaft.

<?xml version="1.0" encoding="utf-8"?>
<mx:HBox xmlns:mx="http://www.adobe.com/2006/mxml">
        <mx:String id="title"/>
	<mx:Label text="{title}" />
</mx:HBox>

Schöne Grüße
hazy

[Omega Psi]

Aber bei vielen Objekten mit vielen Properties würde ich diese straight forward Strategie nicht fahren.

[phase]

Zitat von Omega Psi

Als gut gemeinter Nachtrag - und ich hatte die Beispiele nun schon getippt
...
Die sparsame Version. Ähnlich deiner nur mit wirtschaftlicherem DataBinding.
Bei diesem Beispiel mag das überzogen wirken - ist es auch, aber bei komplexeren Komponenten kriegt man sonst mit der verzögerten Erzeugung der Komponente Probleme.

hi Omega Psi, hab nach meinem psoting dann doch noch mal gesucht und bin dann tatsächlich selbst drauf gekommen ;-)

deine variante scheint mir irgendwie komplizierter aber wahrscheinlich sieht man den vorteil erst bei komplexeren dingen, diesmal reicht mir meine variante. ich hab den vorteil von [Bindable("titleChanged")]
auch noch nicht feststellen können und was meinst du mit wirtschaftlicher?

gruß,
phase

[Omega Psi]

Mit wirtschaftlicher meine ich folgendes.

Verwendest du

[Bindable]
public var name:String; 

generiert dir das Flex Framework ähnlichen Code, nur wird ein PropertyChangeEvent dispatched. Da der PropertyChangeEvent nur den Typen PropertyChangeEvent.PROPERTY_CHANGE kennt, springen alle EventListener an, die durch den generierten Stubcode erzeugt wurden. Das bedeutet es werden potenziell ungleich mehr EventListener ausgeführt je mehr Properties gebunden werden, als mit einer differenzierten [Bindable("type")] Deklaration.

[phase]

ok, verstehe aber sollte man dann nciht immer diese form benutzen?

[Omega Psi]

Meine Form? Ja, schaden tut es nicht.

[hazy fantazy]

Klar schadet das und zwar der Lesbarkeit. Premature optimizing nennen wir das. Optimieren sollte man nur, wenn es auch wirklich nötig ist.