komplexe dynamische filterfunction für arraycollection

[arnold85]

hallo experten,
ich habe eine ArrayCollection in der viele Einträge der Klasse Zeitstempel gespeichert sind. So ein Zeitstempel besteht aus einer Mitarbeiter_id, einer aufgaben_id, einer Startzeit und einer Endzeit. Jeder Mitarbeiter erstellt also jedesmal wenn er an einer bestimmten Aufgabe gearbeitet hat einen neuen Zeitstempel der festhält von wann bis wann er daran gearbeitet hat.

Diese ArrayCollection möchte ich nun auf verschiedene Arten auswerten und mit Charting-Komponenten darstellen.

Ein Beispiel:
Ein Kuchen-Chart soll darstellen wie lange insgesamt an dem gesamten Projekt gearbeitet wurde (also die Summe der Dauer aller Zeitstempel) und gleichzeitig welcher Mitarbeiter welchen Gesamtanteil daran hat (also die Summe der Dauer aller Zeitstempel die von den jeweiligen Mitarbeiter erstellt wurden)

Ich könnte derartige Abfragen natürlcih direkt auf meiner MySql Datenbank (von der die Daten stammen) machen und dann in Flex darstellen, allerdings würde ich mir diesen Traffic gerne sparen denn eigentlich sind ja alle Daten die ich benötige schon in der ZeitstempelArrayCollection beim Client vorhanden.
Leider kriege ich es nicht hin die filterFunction der ArrayCollection so dynamisch zum Einsatz zu bringen.
Problem verstanden?Kann und möchte mir jemand helfen?
Danke

[Omega Psi]

Was hast du denn schon?

[arnold85]

Also nach meinem letzten Eintrag haben ich mir noch folgendes "zusammengewurschtelt":

private function prepareDataForDisplayAllMitarbeiterCompleteWork(ac_data:ArrayCollection):ArrayCollection
			{
				var ac_tempAlleZeitstempel:ArrayCollection=new ArrayCollection();
				ac_tempAlleZeitstempel.addAll(ac_data);
				var ac_zeitstempelGeteiltNachMitarbeitern:ArrayCollection= new ArrayCollection();
				for each (var tempMitarbeiter:Mitarbeiter in ac_allMitarbeiter)
				{
					
					var filtered_array:Array = FilterByProperty(ac_tempAlleZeitstempel.source, tempMitarbeiter.idmitarbeiter);
					var ac_alleZeitstempelEinesMitarbeiters:ArrayCollection=new ArrayCollection(filtered_array);
					ac_zeitstempelGeteiltNachMitarbeitern.addItem(ac_alleZeitstempelEinesMitarbeiters);
				}
				return ac_zeitstempelGeteiltNachMitarbeitern;
			}
			protected function FilterByProperty(input_array:Array, extra_testing:Object):Array
			{
				function FilterFunction(element:Object, index:int, array:Array):Boolean
				{
					return element.mitarbeiter_idmitarbeiter == extra_testing; 
				}
				
				return input_array.filter(FilterFunction);
			}

funktioniert auch soweit, dass ich am Ende schon mal eine ArrayCollection habe welche wiederum für jeden Mitarbeiter eine weitere ArrayCollection enthält in der dann alle zeitstempel des jeweiligen mitarbeiter enthalten sind. Diese müsste ich dann alle nochmal durchlaufen und die dauer der jeweiligen zeitstempel zusammenrechnen.
Aber alles sehr umständlich und unschön finde ich.
Vielleicht geht es ja doch viel einfacher!?

[Omega Psi]

Ja, ich verstehe deinen Code nicht so ganz ... die Idee hinter meinem Code:

1. nur eine Collection, die gefiltert wird.
2. eine Filter-Funktion, die darauf angewandt wird.

package org.icodeapps.filters
{
  import mx.collections.ICollectionView;

  public class FilterStrategy
  {
    //-------------------------------------------------------------------------
    //
    //          Properties
    //
    //-------------------------------------------------------------------------

    //---------------------------------
    //          collection
    //---------------------------------

    private var _collection:ICollectionView;

    function set collection(value:ICollectionView):void
    {
      if (_collection)
      {
        _collection.filterFunction = null;
      }

      _collection = value;

      if (_collection)
      {
        updateFilterFunction();
        refreshCollection();
      }
    }

    //---------------------------------
    //          enableFiltering
    //---------------------------------

    private var _enableFiltering:Boolean;

    public function set enableFiltering(value:Boolean):void
    {
      _enableFiltering = value;
      if (_collection)
      {
        updateFilterFunction();
        refreshCollection();
      }
    }

    //---------------------------------
    //          filterForName
    //---------------------------------

    private var _filterForName:Boolean;

    public function set filterForName(value:Boolean):void
    {
      _filterForName = value;
      refreshCollection();
    }

    //---------------------------------
    //          name
    //---------------------------------

    private var _name:String;

    public function set name(value:String):void
    {
      _name = value;
      refreshCollection();
    }

    private function refreshCollection():void
    {
      if (!_collection) return;

      _collection.refresh();
    }

    //-------------------------------------------------------------------------
    //
    //          Methods
    //
    //-------------------------------------------------------------------------

    private function filter(item:Object):Boolean
    {
      if (!_enableFiltering) return true;

      if (!item) return false;

      if (_filterForName && item.property('name') && item['name'] != _name) return false;

      return true;
    }

    private function updateFilterFunction():void
    {
      _collection.filterFunction = _enableFiltering ? filter : null;
    }
  }
}

Du kannst einfach die Filter-Funktion und die Klasse nach deinen Belieben anpassen. Meine Vorschäge:

1. Für jede Collection einen andere Strategie.
2. filter sollte einen kokreten Datentypen bekommen, um den Code zu vereinfachen.
3. Man kann auch mehrere Subroutinen implementieren und die dann über die Setter in ein Array stecken/entfernen, das dann in der Filterfunktion durchlaufen wird, um das Objekt entsprechend den gesetzten Filtern zu validieren.

[arnold85]

das gefällt mir sehr gut. Damit werde ich es mal versuchen udn mich dann zurück melden.
Tausend Dank und ich bin mal wieder beeindruckt mit welcher Einsatzfreude du dich an die Probleme anderer machst und da du wirklich "Clean Code" hast, dient dein Code auch schon gut als Tutorial.

schönen abend noch

[LordCorax]

Moin moin,

die Variante ist auch nicht schlecht. Ich hab mich allerdings für eine andere entschieden. Hierzu hab ich mir eine BasicVO-Klasse geschrieben, die von den anderen ValueObject-Klassen geerbt wird.

So sieht die Basic-Klasse aus:

PHP-Code:

package vo 
{
    import mx.utils.ObjectUtil;

    public class BasicVO 
    {
        private var properties:Array = new Array();
        
        public function BasicVO() 
        {
            properties = listProperties(this);
        }
        private function listProperties(item:Object):Array 
        {
            var obj:Object = ObjectUtil.getClassInfo(item);
            var arr:Array = obj.properties as Array;
            return arr;
        }
        public function search(item:String):Boolean
        {
            var isObject:Boolean = false;
            var searchString:String = new String();
            for (var i:int = 0; i < properties.length; i++) 
            {
                searchString = this[properties[i]];
                if (searchString != null) 
                {
                    if (searchString.toLowerCase().search(item.toLowerCase()) != -1) 
                    {
                        isObject = true;
                    }
                }
            }
            return isObject;
        }
    }

} 


Und so eine erbende Klasse:

PHP-Code:

package vo 
{
    [Bindable]
    public class PersonalVO extends BasicVO 
    {
        public var vorname:String;
        public var nachname:String;
        public var titel:String;
        public var alter:int;
        public var geschlecht:String;
        
        public function PersonalVO(vorname:String, nachname:String, alter:int, titel:String, geschlecht:String) 
        {
            super(); //Super-Statement nicht vergessen;
            this.vorname = vorname;
            this.nachname = nachname;
            this.alter = alter;
            this.geschlecht = geschlecht;
            this.titel = titel;
        }
    }

} 


Jetzt kann man bspw. eine ArrayCollection in der Flex-Anwendung mit PersonalVO's füllen und diese mit einer Suchfunktion über mehrere Properties hinweg filtern. Siehe Beispiel:

PHP-Code:

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" creationComplete="onInit();">
    
    <mx:Script>
        <![CDATA[
        import mx.collections.ArrayCollection;
        import vo.PersonalVO;
        [Bindable]
        private var personalCollection:ArrayCollection = new ArrayCollection();
        private function onInit():void
        {
            personalCollection.addItem(new PersonalVO("Peter", "Griffin", 35, "", "Männlich"));
            personalCollection.addItem(new PersonalVO("Glenn", "Quagmire", 33, "", "Männlich"));
            personalCollection.addItem(new PersonalVO("Joseph", "Swanson", 35, "", "Männlich"));            
        }
        public function filterPerson():void
        {
            personalCollection.filterFunction = searchVO;
            personalCollection.refresh();
        }
        private function searchVO(vo:PersonalVO):Boolean
        {
            var pvo:PersonalVO = vo;
            return pvo.search(suchFeld.text);
        }
        ]]>
    </mx:Script>
    <mx:DataGrid id="personalGrid" dataProvider="{personalCollection}">
        <mx:columns>
            <mx:DataGridColumn dataField="vorname" headerText="Vorname:"/>
            <mx:DataGridColumn dataField="nachname" headerText="Nachname:"/>
        </mx:columns>
    </mx:DataGrid>
    <mx:TextInput id="suchFeld" width="100" change="filterPerson();"/>
</mx:Application>

VG

LordCorax

[Omega Psi]

Sehe ich das richtig und du schaust nur, ob ein VO eine Eigenschaft hat? Das schränkt die Usecases ja schon etwas ein.

[LordCorax]

Ja, das tue ich. An sich genügt mir die Variante auch vollkommen. Aber du hast recht, deine ist natürlich allumfassender.

[Omega Psi]

Das war auch nicht böse gemeint, nur eine Feststellung

[LordCorax]

Hehe, ich dachte schon ich bekäme hier gleich einen vor den Bug geschossen wegen meines Ansatzes.

[Omega Psi]

Nene, alles gut. Wenn es für dich funktioniert, ist das gut. Allgemein gültige Lösungen sind schwer zum implementieren. Thanx for the beitrag