Flashforum - Die Community zu Adobe Flash, Flex AIR. Web Design und Inspiration.

Max91 · 12-04-2011, 09:23

Hallo ich wollte fragen wie man am besten eine IF-Anweisung schreibt, um zu überprüfen ob der Name in der Tabelle vorhanden ist, bevor es über ein popup in eine Liste eingetragen(editiert) wird.

hier mein bisheriger Versuch

Code:

<mx:Script>
		<![CDATA[
			import com.crossmedia_solutions.mamBackendConfig.vo.ConversionTypesTypeVO;
			import com.crossmedia_solutions.mamBackendConfig.vo.ConversionTypesVO;
			import com.crossmedia_solutions.mamBackendConfig.vo.FileConversionSettingsVO;
			import com.crossmedia_solutions.mamBackendConfig.vo.MAMBackendConfigVO;
			import com.crossmedia_solutions.mamBackendConfig.vo.SetupDefinitionVO;
			import com.crossmedia_solutions.mamBackendConfig.vo.SetupVO;
			import com.crossmedia_solutions.mamBackendConfig.vo.TypeVO;
			
			import mx.controls.Alert;
			import mx.managers.PopUpManager;
			
			import views.ConversionTypesView;
			
			[Bindable]public var setupVO:SetupVO;
			[Bindable]public var conversiontypestypeVO:ConversionTypesTypeVO;
			
			private function close():void {
				PopUpManager.removePopUp(this);
			}
			
			
			
			protected function edit_clickHandler(event:MouseEvent):void
			{
			
					if(setupVO.nameValue != conversiontypestypeVO.value){
						Alert.show("Der Name ist nicht vorhanden.");
						return;
				}
					
				setupVO.nameValue = nameCol.text;
				setupVO.availableVO.value = (avaibleCol.selected)?"true":null;
				setupVO.descriptionVO.value = descriptionCol.text;
				setupVO.templateVO.value = templateCol.text;
				setupVO.typeVO.value = typeCol.text;
				setupVO.setupDefinitionVO.locationFilesystemVO.value = (location_filesystemCol.selected)?"true":null;
				setupVO.setupDefinitionVO.mimetypeFallbackVO.value = (mimetype_fallbackCol.selected)?"true":null;
				setupVO.setupDefinitionVO.databinaryMimetypeVO.value = databinary_mimetypeCol.text;
				setupVO.setupDefinitionVO.fileExtensionVO.value = file_extensionnCol.text;
				setupVO.setupDefinitionVO.databinaryCachecontrolVO.value = databinary_cachcontrolCol.text;
				
				close();
				
			}
			
		]]>
	</mx:Script>

Falls jemand das gesamte Projekt braucht um mehr Überblick zu haben hier:

kostenlos Dateien hochladen bei File Upload X

Danke im Vorraus

Gruß

Max

**Omega Psi** · 12-04-2011, 10:03

Das kann man über eine Filterfunktion regeln. Ich hab mal einen Test dafür geschrieben um zu zeigen, wie das so funcktioniert

ActionScript:

package
{
    import flexunit.framework.Assert;
    import flexunit.framework.TestCase;
 
    import mx.collections.ArrayCollection;
    import mx.collections.ICollectionView;
 
    public class ListCollectionViewFilterTest extends TestCase
    {
        public function ListCollectionViewFilterTest()
        {
        }
 
        [Test]
        public function testFilterFunction():void
        {
            const source:Array = [
                {name:"Fred"},
                {name:"Barney"},
                null,
                {noName:""}
            ];
 
            const collectionView:ICollectionView = new ArrayCollection(source);
            const propertyName:String = "name";
            const name:String = "Fred";
            const simpleNameFilter:Function = function(o:Object):Boolean
            {
                return o && o.hasOwnProperty(propertyName) && o[propertyName] == name;
            };
 
            // No filter was applied yet, the length shouldn't have changed.
            Assert.assertTrue(collectionView.length === 4);
 
            // Applying the filter function.
            collectionView.filterFunction = simpleNameFilter;
 
            // Since we haven't refreshed the collection, the length shouldn't have changed.
            Assert.assertTrue(collectionView.length === 4);
 
            // Refresh the collection, in order to find specific items
            collectionView.refresh();
 
            // As expected, the length has changed, after the filter function was applied refreshing the collection.
            Assert.assertTrue(collectionView.length === 1);
 
            // Remove the filter function, but don't expect the length to be changed
            collectionView.filterFunction = null;
 
            // As expected, the state of the collection view hasn't changed.
            Assert.assertTrue(collectionView.length === 1);
 
            // Refresh the collection view, in order to go back to the original state
            collectionView.refresh();
 
            // All items are found
            Assert.assertTrue(collectionView.length === 4);
        }
 
    }
}

Max91 · 12-04-2011, 10:32

Ich glaube man kann das auch mit einer for schleife machen, sodas es im datagrid durchläuft und prüft ob der Name vorhanden ist.Nur weiß ich nicht genau wie man die for Schleife dafür schreibt, kann auch sein das ich falsch liege.

**Omega Psi** · 12-04-2011, 10:44

Ja, das geht auch:

Code:

private function listHasItemWithPropertyOfValue(list:IList, propertyName:String, value:String):Boolean
{
	var o:Object;
	for (var i:int; i < list.length; i++)
	{
		o = list.getItemAt(i);
		if (o && o.hasOwnProperty(propertyName) && o[propertyName] == value)
		{
			return true;
		}
	}
	return false;
}

Das ganze geht natürlich auch flexibler oder noch hartgecodeter.

Max91 · 13-04-2011, 07:48

mit flexibler meinst du wohl die Filterfuktion oder gibt es noch eine flexiblere methode?

Max91 · 13-04-2011, 10:50

Ich habs jetzt so gemacht aber er bleibt immer auf false. Er findet irgentwie den Wert nicht obwohl der eigentlich vorhanden ist. Worin könnte der Fehler
liegen?

Code:

			protected function edit_clickHandler(event:MouseEvent):void
			{
				var found:Boolean  = false;
				for (var i:int = 0; i < conversion_typesList2.length; i++) 
				{
					if(setupVO.nameValue == conversiontypestypeVO.value){
						found= true;
						break;

					}
				}
				if(found == false){
					Alert.show("Der Name ist nicht vorhanden.");
				}
				if(found == true){
					
					setupVO.nameValue = nameCol.text;
					setupVO.availableVO.value = (avaibleCol.selected)?"true":null;
					setupVO.descriptionVO.value = descriptionCol.text;
					setupVO.templateVO.value = templateCol.text;
					setupVO.typeVO.value = typeCol.text;
					setupVO.setupDefinitionVO.locationFilesystemVO.value = (location_filesystemCol.selected)?"true":null;
					setupVO.setupDefinitionVO.mimetypeFallbackVO.value = (mimetype_fallbackCol.selected)?"true":null;
					setupVO.setupDefinitionVO.databinaryMimetypeVO.value = databinary_mimetypeCol.text;
					setupVO.setupDefinitionVO.fileExtensionVO.value = file_extensionnCol.text;
					setupVO.setupDefinitionVO.databinaryCachecontrolVO.value = databinary_cachcontrolCol.text;
					
					close();
				}
			}

**Omega Psi** · 13-04-2011, 11:53

Ich verstehe nicht so ganz, worauf das alles hinausläuft, versuche aber mal, da etwas List ins Dunkel zu bringen:

Code:

			protected function edit_clickHandler(event:MouseEvent):void
			{
				var found:Boolean  = false;
				const length:uint = conversion_typesList2.length;
				for (var i:int = 0; i < length; i++) 
				{
					var type:ConversionTypesTypeVO = conversion_typesList2.getItemAt(i);

					if(setupVO.nameValue == type.value){
						setupVO.nameValue = nameCol.text;
						setupVO.availableVO.value = (avaibleCol.selected)?"true":null;
						setupVO.descriptionVO.value = descriptionCol.text;
						setupVO.templateVO.value = templateCol.text;
						setupVO.typeVO.value = typeCol.text;
						setupVO.setupDefinitionVO.locationFilesystemVO.value = (location_filesystemCol.selected)?"true":null;
						setupVO.setupDefinitionVO.mimetypeFallbackVO.value = (mimetype_fallbackCol.selected)?"true":null;
						setupVO.setupDefinitionVO.databinaryMimetypeVO.value = databinary_mimetypeCol.text;
						setupVO.setupDefinitionVO.fileExtensionVO.value = file_extensionnCol.text;
						setupVO.setupDefinitionVO.databinaryCachecontrolVO.value = databinary_cachcontrolCol.text;
					
						close();
						break;
					}
				}
			}

Du hast nicht über die Liste iteriert. Ob das nun sein soll oder muss, weiss ich nicht.

PS: die VO Suffice kannst/solltest du bei den Properties weglassen.

Max91 · 13-04-2011, 12:19

der meldet mir dann folgende Fehlermeldung:

Zitat:

Beschreibung Pfad Ressource Position Typ
1118: Implizite Umwandlung von einem Wert mit statischem Typ Object in einen möglicherweise nicht verwandten Typ com.crossmedia_solutions.mamBackendConfig.vo:Conve rsionTypesTypeVO. /Projekt/src/Popups ConversionSetupsPopup.mxml Zeile 34 Flex-Problem

**Omega Psi** · 13-04-2011, 12:20

Ich rate auch, was in der Liste drin ist. Du musst meine Idee schon mit deinem Code abgleichen.

Max91 · 14-04-2011, 07:57

hab das jetzt so gelöst und funktioniert einwandfrei danke für deine Hilfe

Code:

		import mx.collections.ArrayCollection;
			import mx.controls.Alert;
			import mx.managers.PopUpManager;
			
			import views.ConversionTypesView;
			
			[Bindable]public var setupVO:SetupVO;
			[Bindable]public var conversion_typesList2:Array= new Array();
			
			private function close():void {
				PopUpManager.removePopUp(this);
			}
			
			protected function save_clickHandler(event:MouseEvent):void
			{
				var found:Boolean  = false;
 				for (var i:int = 0; i < conversion_typesList2.length; i++) 
				{
					if(nameCol.text == ConversionTypesTypeVO(conversion_typesList2[i]).value){
						found= true;
						break;

					}
				}
				if(found == true){
					setupVO.nameValue = nameCol.text;
					setupVO.availableVO.value = (avaibleCol.selected)?"true":null;
					setupVO.descriptionVO.value = descriptionCol.text;
					setupVO.templateVO.value = templateCol.text;
					setupVO.typeVO.value = typeCol.text;
					setupVO.setupDefinitionVO.locationFilesystemVO.value = (location_filesystemCol.selected)?"true":null;
					setupVO.setupDefinitionVO.mimetypeFallbackVO.value = (mimetype_fallbackCol.selected)?"true":null;
					setupVO.setupDefinitionVO.databinaryMimetypeVO.value = databinary_mimetypeCol.text;
					setupVO.setupDefinitionVO.fileExtensionVO.value = file_extensionnCol.text;
					setupVO.setupDefinitionVO.databinaryCachecontrolVO.value = databinary_cachcontrolCol.text;
					
					close();
				} else {
					Alert.show("Der Name ist nicht vorhanden.");
				}
			}
			
		]]>
	</mx:Script>
	<mx:Form width="100%" height="100%">
		<mx:FormHeading width="329" label="conversion_setups" textAlign="center"/>
		<mx:FormItem id="name_form"  width="100%" label="name:">
			<mx:TextInput id="nameCol"  text="{setupVO.nameValue}"/>

12-04-2011, 10:44	#4 (permalink)
Omega Psi Perverted Hermit Registriert seit: Mar 2004 Ort: Delmenhorst Beiträge: 12.147	Ja, das geht auch: Code: private function listHasItemWithPropertyOfValue(list:IList, propertyName:String, value:String):Boolean { var o:Object; for (var i:int; i < list.length; i++) { o = list.getItemAt(i); if (o && o.hasOwnProperty(propertyName) && o[propertyName] == value) { return true; } } return false; } Das ganze geht natürlich auch flexibler oder noch hartgecodeter. __________________ http://icodeapps.net \| Meet me at the Flex user group Hamburg talking about CoffeeScript

13-04-2011, 12:20	#9 (permalink)
Omega Psi Perverted Hermit Registriert seit: Mar 2004 Ort: Delmenhorst Beiträge: 12.147	Ich rate auch, was in der Liste drin ist. Du musst meine Idee schon mit deinem Code abgleichen. __________________ http://icodeapps.net \| Meet me at the Flex user group Hamburg talking about CoffeeScript

Themen-Optionen
Druckbare Version zeigen Jemanden per E-Mail auf dieses Thema hinweisen
Ansicht
Linear-Darstellung Zur Hybrid-Darstellung wechseln Zur Baum-Darstellung wechseln

Ähnliche Themen
Thema	Autor	Forum	Antworten	Letzter Beitrag
komplexerer MP3Player - (Wiedergabe-)liste (datagrid) , preloader	headgrowe	ActionScript 2	6	15-04-2009 13:41
Datagrid, via as2 die Liste an die richtige Stelle scrollen!	easyJoe	Komponenten und SmartClips	2	11-03-2009 00:14
Inhalte von einem Datagrid in ein zweites Datagrid übergeben...?!	dahoody	Flash MX 2004	0	16-02-2005 14:19
cpu vergleich...	mort3n	Am Rande	38	15-03-2004 20:16
if-Anweisung in on(release)-Anweisung	mcpilz	ActionScript 1	3	24-09-2003 19:39

12-04-2011, 10:32	#3 (permalink)
Max91 Neuer User Registriert seit: Mar 2011 Beiträge: 7	Ich glaube man kann das auch mit einer for schleife machen, sodas es im datagrid durchläuft und prüft ob der Name vorhanden ist.Nur weiß ich nicht genau wie man die for Schleife dafür schreibt, kann auch sein das ich falsch liege.

13-04-2011, 07:48	#5 (permalink)
Max91 Neuer User Registriert seit: Mar 2011 Beiträge: 7	mit flexibler meinst du wohl die Filterfuktion oder gibt es noch eine flexiblere methode?