Eine Funktion aus einer anderen Komponente aufrufen - wie?

[fabbsen]

Tag auch,

ich stehe vor folgendem Problem:

Ich hab zwei Komponenten "compA" und "compB"

compB zeigt ein klickbares Bild an.
compA ruft in einer Funktion (hier "func" genannt) compB auf und übergibt die URL für das Bild.

Nun würde ich gerne aus compB die Funktion "func" aufrufen.

Soweit ich weiß, ist das am besten mit einem Listener und eventDispatcher zu lösen. Aber irgendwie blockiert da meine Hirnlogik - sprich: ich blick das nich
Kann mir da jemand n bisschen Hilfestellung geben?

Danke im Voraus und Grüße vom F.

[Omega Psi]

package fs.examples
{
 
    import flash.events.Event;
 
    import fs.examples.Parent;
 
    import mx.core.UIComponent;
 
    public class Parent extends UIComponent
    {
 
        private var _child:Child;
 
        public function Parent()
        {
            super();
        }
 
 
        override protected function createChildren():void
        {
            super.createChildren();
            if (!_child)
            {
                _child = new Child();
                _child.addEventListener(Event.COMPLETE, eventListener);
                _child.someChildishMethod();
                addChild(_child);
            }
        }
 
        private function eventListener(event:Event):void
        {
            trace(event.target, event.type);
        }
    }
} 

package fs.examples
{
 
    import flash.events.Event;
 
    import mx.core.UIComponent;
 
    [Event("complete", type="flash.events.Event")]
 
    public class Child extends UIComponent
    {
 
        public function Child()
        {
            super();
        }
 
        public function someChildishMethod():void
        {
            dispatchEvent(new Event(Event.COMPLETE));
        }
    }
} 

So als rudimentäres Beispiel.

[fabbsen]

hm - leicht verständlich ... so als "rudimentäres Beispiel"
Naja - ich schau mich mal weiter im Netz um. Trotzdem danke.

[Omega Psi]

Was ist denn daran nicht zu verstehen? Der Dispatcher muss in der Klasse bekannt sein, da der Dispatcher selbst einen Listener registrieren muss.