Funktion nach event aufrufen...

[Mole23]

Hi zusammen,

ich versuche gerade einen Emailanhang Base64 zu codieren. Hierzu habe ich auch eine ganz gute App. in diesem Forum gefunden und bin dabei diese anzupassen.

Zur Zeit besteht die Funktion aus drei Buttons (Browse, Laden, Codieren), was etwas unpraktisch ist. Ich möchte gerne das die Funktionen Laden und Codieren direkt nach auswählen der Datei ausgeführt werden. Hat jemand eine Idee wie ich das anstellen kann?

Ich muss ja an sich nur sagen, dass wenn er die Funktion "browse" durchlaufen hat, er "load" und "dump" ausführen soll. Oder stelle ich mir das leichter vor als es ist?

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" width="800" height="600">
	<mx:Script>
		<![CDATA[
			import mx.utils.Base64Encoder;
		
			[Bindable]
			private var fileRef:FileReference;
			
			private function browse():void
			{
				if (fileRef)
				{
					fileRef = null;
					txt.text = "";
				}
				fileRef = new FileReference();
				fileRef.browse();
			}
			
			private function load():void
			{
				fileRef.load();
			}
			
			private function dump():void
			{
				var bytes:ByteArray = fileRef.data;
				var encoder:Base64Encoder = new Base64Encoder();
				encoder.encodeBytes(bytes);
				txt.text = encoder.drain();
			}
			
			
		]]>
	</mx:Script>
	<mx:Button label="Browse" click="browse()"/>
	<mx:Button label="Laden" click="load()"/>
	<mx:Button label="Base64 konvertieren" click="dump()"/>
	<mx:TextArea id="txt" width="600" height="400"/> 
</mx:WindowedApplication>

[Nico B.]

Oha - schon mal was von "EventListener" gehört?


In diesem Falle

fileRef = new FileReference();
fileRef.addEventListener(Event.SELECT, load);
fileRef.browse();
 
private function load(event:Event):void
{
// tu Irgendwas
} 

Achja, ist die richtige Methode auf der File-instanz nicht "browseForOpen" ?

[Mole23]

ah danke!

[Nico B.]

Würde mir evtl. nen par Basics reinziehen, bevor Du anfängst irgendwelche Dateien zu codieren ^^

[Mole23]

Cool, habs hinbekommen! Jetzt verstehe ich auch wo für das Ding da ist!


Hab vielen Dank! Hast mich n großen Schritt voran gebracht!

[Mole23]

Kannst du mir noch sagen was ich bei der Funktion dump falsch gemacht habe?

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" width="800" height="600">
	<mx:Script>
		<![CDATA[
			import mx.utils.Base64Encoder;
		
			[Bindable]
			private var fileRef:FileReference;
			
			private function browse():void {
				
				if (fileRef) {
					fileRef = null;
					txt.text = "";
				}
				fileRef = new FileReference();
				fileRef.browse();
				
				fileRef.addEventListener(Event.SELECT, load);
			}
			
			private function load(event:Event):void
			{
				fileRef.load();
				fileRef.addEventListener(Event.SELECT, dump);
			}
			
			private function dump(event:Event):void
			{
				var bytes:ByteArray = fileRef.data;
				var encoder:Base64Encoder = new Base64Encoder();
				encoder.encodeBytes(bytes);
				txt.text = encoder.drain();
			}
			
			
		]]>
	</mx:Script>
	<mx:Button label="Browse" click="browse()"/>
	<mx:TextArea id="txt" width="600" height="400"/> 
</mx:WindowedApplication>

[Nico B.]

Ähm, ich glaube Du hast da was missverstanden.

Es gibt X verschiedene Arten von Events (eigentlich unendlich viele, da man sich selbst auch welche schreiben kann)


Event.SELECT ist nur sinnvoll, wenn du eben etwas "selectest", sprich auswählst. (Wie im Datei-öffnen Dialog)

In der "load" function macht SELECT aber überhaupt keinen Sinn!

Mit dem EventListener "horcht" man ja darauf, wann etwas passiert. Das kann ein Mausclick, ein Select oder auch ein fertiges Laden von einem Objekt sein.

Würde mir wirklich erstmal AS3-Basics reinziehen - Flex ist manchmal schon kompliziert genug. Da sollten EventListener mind. sitzen - Im Schlaf!


Achja, was soll in deiner "dump" function falsch sein? Oder wird sie, wie oben vermutet, gar nicht aufgerufen?

[Mole23]

Exact! Wird garnicht ausgeführt! Wenn ich die über ein Button aufrufe geht diese. Also denke ich mal die wird nicht aufgerufen.

[Nico B.]

Kann ja nicht funktionieren^^

Wie oben bereits geschrieben, benutzt Du das 2. "SELECT" völlig falsch. Da findet kein Select statt - ergo wird auch keine Funktion aufgerufen.


Ich weiß jetzt nicht ausm Kopf wie file.load() genau funktioniert, aber irgendwie wirste da auch drauf "warten" können.

WOher hast Du die Scripte?

[Mole23]

Habs mit COMPLETE hinbekommen... Aber THX nochmal!

Falls es jemand Quick and Dirty braucht:

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" width="800" height="600">
	<mx:Script>
		<![CDATA[
			import mx.utils.Base64Encoder;
		
			[Bindable]
			private var fileRef:FileReference;
			
			private function browse():void {
				
				if (fileRef) {
					fileRef = null;
					txt.text = "";
				}
				fileRef = new FileReference();
				fileRef.browse();
				
				fileRef.addEventListener(Event.SELECT, load);
				
				fileRef.addEventListener(Event.COMPLETE, dump);
			}
			
			private function load(event:Event):void
			{
				fileRef.load();
				
			}
			
			private function dump(event:Event):void
			{
				var bytes:ByteArray = fileRef.data;
				var encoder:Base64Encoder = new Base64Encoder();
				encoder.encodeBytes(bytes);
				txt.text = encoder.drain();
			}
			
			
		]]>
	</mx:Script>
	<mx:Button label="Browse" click="browse()"/>
	<mx:TextArea id="txt" width="600" height="400"/> 
</mx:WindowedApplication>

[Nico B.]

Hatte es auch grad getestet - complete ist richtig.

Da ich mir gerade die Mühe gemacht habe es "nachzu scripten", wollte ich es mind. auch posten

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       
                       creationComplete="init(event)"
                       >
    <fx:Script>
        <![CDATA[
            import flash.events.Event;
            import flash.utils.ByteArray;
            
            import mx.events.FlexEvent;
            import mx.utils.Base64Encoder;
 
            
            private var _directory:File;
            
            protected function init(event:FlexEvent):void
            {
                this._directory = new File();
                this._directory.addEventListener(Event.SELECT, fileSelect);
                this._directory.browseForOpen("Öffne mich");
            }
            
            
            
            protected function fileSelect(event:Event):void
            {
                this._directory.removeEventListener(Event.SELECT, fileSelect);
                this._directory.addEventListener(Event.COMPLETE, dump );
                this._directory.load();
            }
            
            protected function dump(event:Event):void
            {
                this._directory.removeEventListener(Event.COMPLETE, dump );
                var bytes:ByteArray = this._directory.data;
                var encoder:Base64Encoder = new Base64Encoder();
                encoder.encodeBytes(bytes);
                trace( encoder.drain() );
            }
 
        ]]>
    </fx:Script>
    
    
</s:WindowedApplication> 

[Mole23]

Hast du das in flash gemacht, oder woher stammt der Code?

(Rein aus Interesse)

[Nico B.]

Ähm,

ich benutze derzeit Flashbuilder Beta2. (Leider bisschen buggy). In der Flash-IDE (Cs4) zu scripten macht ja keinen Spaß.
(Für reine As3 Projekte ==> FlashDevelop! )

Grüße, Nico

[Mole23]

Aha! Danke! Man lernt ja nicht aus! Netter Blog übrigens!

[Szdnez]

Und das interessanteste am ganzen Thread ist der für mich bis dato unbekannte BBCode AS