Error #1009 beim einbinden einer swf-datei mit player-funktionalität

[flash44]

Hi,

habe folgendes Problem:

Ich würde gerne eine Animation als swf in ein Flex projekt (Flash Builder 4) einbinden.
Dies funktioniert auch, wenn ich nur eine swf ohne actionscript verwende:

PHP-Code:

<mx:SWFLoader source="@Embed('../ani/animation1_deutsch_ohne_player.swf')"> 


Um einen Player für die animation zu implementieren habe ich in Flash 5.5 ein paar Buttons und einen Slider für einen Player erstellt. Dieser soll zu vordefinierten Frames vor- und zurückspringen können und die Geschwindigkeit über einen slider variieren.
Ein einfachs öffnen der swf direkt im browser funktioniert.
Binde ich jedoch die swf in mein flexprojekt (mit dem gleichen Befehl wie oben) erscheint der Fehler:

TypeError: Error #1009: Der Zugriff auf eine Eigenschaft oder eine Methode eines null-Objektverweises ist nicht möglich.

Hier der actionscript code:
----------------------------------------

PHP-Code:

import flash.events.MouseEvent;
import fl.controls.Slider;
import fl.events.SliderEvent;
import fl.controls.SliderDirection;

slider.addEventListener(SliderEvent.CHANGE, speedslider);

slider.value=stage.frameRate; // Wert des Sliders auf den Wert der Stage Geschwindigkeit setzen
slider.minimum=5;
slider.maximum=100;
slider.snapInterval=10;
slider.liveDragging=true;

function stopHandler(e:MouseEvent):void {
 stop();
}

function playHandler(e:MouseEvent):void {
 play();
 
}
/* zahl = zahl + 60;
 if (zahl >= 676) {
  gotoAndStop(1);
 } else {
 gotoAndPlay(zahl);
 trace(zahl);
 trace(zahl >= 676);
 }*/


function backHandler(e:MouseEvent):void{
 
 if((this.currentFrame >= 0)&&(this.currentFrame <= 310)){
  gotoAndPlay(310);
  trace(this.currentFrame);
 } else if((this.currentFrame >= 310)&&(this.currentFrame <= 501)){
  gotoAndPlay(501);
 } else
.
. <<weitere Sprünge wurden übersichtlichkeitshalber entfernt>>
.
}

function speedslider(event:SliderEvent){
 stage.frameRate = event.target.value;

}

function backReturnHandler(e:MouseEvent):void {
 if((this.currentFrame >= 0)&&(this.currentFrame <= 310)){
  gotoAndStop(0);
  trace(this.currentFrame);
 } else if((this.currentFrame >= 310)&&(this.currentFrame <= 501)){
  gotoAndStop(309);
 } else
.
. <<weitere Sprünge wurden übersichtlichkeitshalber entfernt>>
.
}

function backEndHandler(e:MouseEvent):void {
 gotoAndPlay(0);
}

stopButton.addEventListener(MouseEvent.CLICK, stopHandler);
playButton.addEventListener(MouseEvent.CLICK, playHandler);
backButton.addEventListener(MouseEvent.CLICK, backHandler);
backButtonreturn.addEventListener(MouseEvent.CLICK, backReturnHandler);
backEndButton.addEventListener(MouseEvent.CLICK, backEndHandler); 


Hat jemand ne idee, woran das liegen könnte?
Danke schon mal für Hilfen von euch!

[Martin Kraft]

Willkommen im Forum!

Ich hab Dir Deinen Code mal als solchen markiert. So ist er für uns alle besser lesbar.

Ursache:
In der SWF wird auf stage zugegriffen. Diese ist aber erst dann definiert, wenn die SWF auch tatsächlich in der DisplayList hängt. Da das noch nicht der Fall ist, wenn dieses Script ausgeführt wird kommt's zu dieser Fehlermeldung.

Lösung:
Auf stage sollte erst aus einer Listener-Funktion herauszugegriffen werden, die auf das Event.ADDED_TO_STAGE wartet.

Mehr dazu findest Du in der Suchfunktion oder über die Referenz (Link s.u.).

[flash44]

Super schon mal vielen Dank für die Antwort.
Könntest du mir das vllt. genauer erklären ? Wo muss ich das Event dispatchen in Flash im AS Teil oder in Flex wenn ich meine SWF per SWFLoader lade ?
Vielen Dank für die Hilfe.
Grüße

[Martin Kraft]

Zitat von flash44

Könntest du mir das vllt. genauer erklären ? Wo muss ich das Event dispatchen in Flash im AS Teil oder in Flex wenn ich meine SWF per SWFLoader lade ?

Du musst in der SWF einfach alles, was nicht in einer Funktion steht, in eine Funktion schieben und diese dann bei Event.ADDED_TO_STAGE aufrufen:

PHP-Code:

import flash.events.MouseEvent;
import flash.events.Event;
import fl.controls.Slider;
import fl.events.SliderEvent;
import fl.controls.SliderDirection;

function init(event:Event = null):void{
    slider.addEventListener(SliderEvent.CHANGE, speedslider);
    slider.value=stage.frameRate; // Wert des Sliders auf den Wert der Stage Geschwindigkeit setzen
    slider.minimum=5;
    slider.maximum=100;
    slider.snapInterval=10;
    slider.liveDragging=true;
    stopButton.addEventListener(MouseEvent.CLICK, stopHandler);
    playButton.addEventListener(MouseEvent.CLICK, playHandler);
    backButton.addEventListener(MouseEvent.CLICK, backHandler);
    backButtonreturn.addEventListener(MouseEvent.CLICK, backReturnHandler);
    backEndButton.addEventListener(MouseEvent.CLICK, backEndHandler); 
}

if(stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);

// Die anderen Funktionen 


[flash44]

Ich danke dir wirklich über alles.
Super das war genau was ich gesucht habe.
Du hast gutes Karma.
Also nochmal vielen vielen Dank.
Einen schönen Abend noch.