Daten aus CSV-Datei in Flash einlesen

[salomon80]

Hi,

ich habe eine CSV-Datei mit der Struktur

1;3;5;9;14
2;4;8;16;25

Um in Flash mit diesen Werten zu arbeiten, nutze ich derzeit diesen (anscheinend fehlerhaften) Code:

function loadCSV(file:String):Void{
var lv:LoadVars = new LoadVars();
lv.onLoad = function(success:Boolean) {
if(success){
splitCSV(this.csv);
}
}
lv.load(file);
}

function splitCSV(csv:String):Void{
var rows:Array = csv.split("\n");
var values:Array = new Array(rows.length);
for(var i:Number=0; i<rows.length; i++){
values[i] = rows[i].split(";");
}
for(var i:Number=0; i<values.length; i++){
for(var j:Number=0; j<values[i].length; j++){
trace("Zeile "+(i+1)+", Spalte "+(j+1)+": "+values[i][j]);
}
}
}

loadCSV("test.csv");

Wäre schön, wenn mir jemand bei dem Problem helfen könnte. Vielen Dank schon einmal!

[shin10]

servus salomon,

so sollte es funktionieren

PHP-Code:

function loadCSV(file:String):Void {
    var lv:LoadVars = new LoadVars();
    lv.onLoad = function(success:Boolean) {
        if (success) {
            splitCSV(unescape(lv.toString()).split("=&onLoad=[type Function]")[0]);//da war der fehler
        }
    };
    lv.load(file);
}

function splitCSV(csv:String):Void {
    var rows:Array = csv.split("\r\n").join("\n").split("\r").join("\n").split("\n");//damit sollte linux, mac und win funktionieren
    var values:Array = new Array(rows.length);
    for (var i:Number = 0; i < rows.length; i++) {
        values[i] = rows[i].split(";");
    }
    for (var i:Number = 0; i < values.length; i++) {
        for (var j:Number = 0; j < values[i].length; j++) {
            trace("Zeile " + (i + 1) + ", Spalte " + (j + 1) + ": " + values[i][j]);
        }
    }
}

loadCSV("test.csv"); 


mfg

sx

[salomon80]

Vielen Dank!

Das funktioniert im Grunde einwandfrei.

Doch leider schaffe ich es noch immer nicht, mit den Werten, die nun im Ausgabefenster angezeigt werden, zu arbeiten. Wie spreche ich diese nun an?

Danke nochmals!

[shin10]

kann ich dir erst sagen, wenn ich weiß was du vorhast.
visitenkarten, stundenpläne... ?

beschreibs ruhig ausführlich - ich geh jetzt schlafen

mfg

sx

[salomon80]

Vorab schon mal Danke für Deine Mühe!

Ich betreibe einen ausschließlich Flash-basierten Web-Auftritt meiner Fußball-Mannschaft. U. a. gehören dazu Spielerportraits, die sich in einem eigenem Fenster/Tab öffnen. Bislang standen da so Dinge drin wie Geburtsort, Lieblingsverein, ehemalige Vereine, etc... Es zeigte sich jedoch, dass man den Leuten ständig hinterrennt, um derartige Informationen einzuholen. Also möchte ich dort beispielsweise auflisten, wie viele Spiele jemand gemacht, wie viele Tore er geschossen hat und ähnliche Dinge, die sich aber selbstverständlich wöchentlich ändern können.

Deshalb schwebt mir vor, die Änderungen in eine Excel-Tabelle einzugeben und mir diese als csv-Datei in der oben beschriebenen Form ausspucken zu lassen. Im Flash-Code stünde dann der Verweis auf den Ort der sich ggf. wöchentlich ändernden Variable und ich bräuchte nichts weiter zu tun, als im Wochenrhytmus die csv-Datei anzupassen. Andernfalls müsste ich im selben Zeitraum kleinteilig mindestens 20 Flash-Files anpassen; und das kann ja keiner wollen.

Danke nochmals für Deine Anregungen!

[shin10]

na gut,

und wo hakt es? wie soll das dann aussehen? offenbar hast du schon ne seite. poste doch einfach mal nen link. dann kann man sich am leichtesten ein bild davon machen.

mfg

sx

[salomon80]

Gerne: home (Wenn Du Dir die Spielerportraits anschaust, dann bitte das von Bardies El-Mahgzangy, da dieses bereits nach den neuen Maßgaben geformt ist)

Mein aktuelles Problem besteht darin, dass die Daten aus der csv-Datei zwar eingelesen werden, ich diese aber nicht mit einem Namen ansprechen kann.

Diesen benötige ich jedoch, um in einem zu erzeugendem Textfeld den Wert widerzugeben. Also wäre es schön, wenn der eingelesene Wert einer Variable zugeordnet wird.

PHP-Code:

function splitCSV(csv:String):Void {
    var rows:Array = csv.split("\r\n").join("\n").split("\r").join("\n").split("\n");
    var values:Array = new Array(rows.length);
    for (var i:Number = 0; i < rows.length; i++) {
        values[i] = rows[i].split(";");
    }
    for (var i:Number = 0; i < values.length; i++) {
        for (var j:Number = 0; j < values[i].length; j++) {
            trace("Zeile " + (i + 1) + ", Spalte " + (j + 1) + ": " + values[i][j]);
            var ["z"+(i)+"s"+(j)]=values[i][j];//Hier habe ich eine Zeile ergänzt
        }
    }
} 


Deshalb habe ich den Code wie angezeigt ergänzt. Da erhalte ich dann aber folgende Fehlermeldung:

PHP-Code:

**Error** Scene=Scene 1, layer=Layer 1, frame=1:Line 20: Identifier expected
                 var ["z"+(i)+"s"+(j)]=values[i][j];

**Error** Scene=Scene 1, layer=Layer 1, frame=1:Line 23: Unexpected '}' encountered
     }

Total ActionScript Errors: 2      Reported Errors: 2 


Ich hoffe, Du kannst mir auch dabei helfen. Mein Dank ist Dir in jedem Fall abermals gewiss.

[shin10]

ok,

so wie ich das aus dem code rauslese möchtest du die daten mit zeilen und spalten nummer ansprechen können.

PHP-Code:

var ["z"+(i)+"s"+(j)]=... 


funktioniert nicht. man kann keine variablen dynamisch definieren.
du kannst aber alles in ein objekt schreiben bzw. ein zweidimensionales array

z.b.:

PHP-Code:

function splitCSV(csv:String):Void {
    var tabelle:Array = csv.split("\r\n").join("\n").split("\r").join("\n").split("\n");
    for (var i:Number = 0; i < tabelle.length; i++) {
        tabelle[i] = tabelle[i].split(";");//ersetzt den string wieder durch ein array, wie zuvor schon oben
    }
} 


dann kannst du bspw. mit

PHP-Code:

var zeile= 1;
var spalte= 2;
trace(tabelle[zeile][spalte]) 


die daten einer zelle (hier zeile 2, reihe 3 (es wird ja mit 0 begonnen)) ausgeben/ansprechen

ich hoffe ich hab mich nicht vertippt.
ist das was du willst?

mfg

sx

[salomon80]

Ja, genau so soll das am Ende möglich sein. Schön handlich!

Doch leider bekomme ich derzeit immer nur ein "undefined" ausgegeben. Ich habe den von Dir in Deinem letztem Post genommen erst trivial eingefügt, dann an verschiedenen Stellen eingesetzt. Das "undefined" blieb leider fortwährend.

Ich muss allerdings auch zugeben, dass meine Erfolgsaussichten eher mau waren, da das Array-Konzept für mich quasi neu ist (Wir hatten das mal im Schul-Informatik-Unterricht; das ist aber schon ein Weilchen her).

Wenn es für Dich nicht zu unübersichtlich ist, poste ich meinen aktuellen Code und bitte Dich ihn durchzuschauen. Vielen Dank zum wiederholten Male!

PHP-Code:

function loadCSV(file:String):Void {
    var lv:LoadVars = new LoadVars();
    lv.onLoad = function(success:Boolean) {
        if (success) {
            splitCSV(unescape(lv.toString()).split("=&onLoad=[type Function]")[0]);//da war der fehler
        }
    };
    lv.load(file);
}

function splitCSV(csv:String):Void {
    var rows:Array = csv.split("\r\n").join("\n").split("\r").join("\n").split("\n");
    var values:Array = new Array(rows.length);
    var tabelle:Array = csv.split("\r\n").join("\n").split("\r").join("\n").split("\n");
    for (var i:Number = 0; i < tabelle.length; i++) {
        tabelle[i] = tabelle[i].split(";")
    }
    for (var i:Number = 0; i < rows.length; i++) {
        values[i] = rows[i].split(";");
    }
    for (var i:Number = 0; i < values.length; i++) {
        for (var j:Number = 0; j < values[i].length; j++) {
            trace("Zeile " + (i + 1) + ", Spalte " + (j + 1) + ": " + values[i][j]);
        }
    }
}

loadCSV("test.csv"); 

this.createTextField("test",getNextHighestDepth(),0,0,100,20);
var zeile=0;
var spalte=0;
trace (tabelle[zeile][spalte]);
test.text=tabelle[zeile][spalte]; 


[shin10]

liegt daran, dass die datei noch nicht geladen war
der aufruf ist natürlich erst danach erfolgreich

PHP-Code:

function loadCSV(file:String):Void {
    var lv:LoadVars = new LoadVars();
    lv.onLoad = function(success:Boolean) {
        if (success) {
            splitCSV(unescape(lv.toString()).split("=&onLoad=[type Function]")[0]);//da war der fehler
        }
    };
    lv.load(file);
}
var zeile=0;
var spalte=0;
var tabelle:Array;
function splitCSV(csv:String):Void {
    tabelle = csv.toString().split("\r\n").join("\n").split("\r").join("\n").split("\n");
    for (var i:Number = 0; i < tabelle.length; i++) {
        tabelle[i] = tabelle[i].split(";")
    }
    test.text=tabelle[zeile][spalte]; 
}

loadCSV("test.csv"); 

this.createTextField("test",getNextHighestDepth(),0,0,100,20);

//nur mal zum test für dich: erst gibt er immer undefined raus,
//wenn die datei geladen und verarbeitet wurde den wert
onEnterFrame = function(){
    trace(tabelle[zeile][spalte]);
} 


[salomon80]

Sorry, dass ich mich erst so spät zurückmelde. Aber über mich trifft gerade Umzugs-/Renovierungsstress herein. Ich habe es aber schon mal kurz anschauen können und glaube, damit jetzt meine Vorhaben umsetzen zu können. Dafür und für den schon zuvor beschrittenen Weg vielen Dank (abermals ). Sollten nochmals Hindernisse auftreten, hoffe ich, mich nochmals bei Dir melden zu können. In jedem Fall für die kompetente und stets unmittelbare Hilfe Danke!

[shin10]

gern geschehen,
wenn was ist meld dich einfach.

bis denne und viel spass beim umzug

sx