RemoteManager V2

[K-Grabowski]

denke mal hier ist er besser aufgehoben:

import mx.remoting.Connection;
import mx.remoting.Service;
import mx.rpc.RelayResponder;
import mx.rpc.ResultEvent;
import mx.rpc.FaultEvent;
import mx.remoting.debug.NetDebug;
 
class RemoteManager {
    
    private var queue:Array;
    private static var instance:RemoteManager = null;
    private var executing:Boolean;
    private var con:Connection;
    private var services:Array;
    private var user:String;
    private var pass:String;
    private var gatewayUrl:String;
    private var connected:Boolean;
    private var initialized:Boolean;
 
    
    private function RemoteManager () 
    {
        NetDebug.initialize();
        
        services = new Array();
        connected = false;
        queue = new Array();
        executing = false;
    }
    
    public function initialize (pGatewayUrl:String, pUser:String, pPass:String)
    {
        if (initialized) return;
        
        
        
        gatewayUrl = pGatewayUrl;
        user = pUser;
        pass = pPass;
        
    }
    private function addService (pService:String):Void 
    {
        
        if (getService(pService) != null) return;
        
        var o:Object = new Object();
        o.name = pService;
        o.responder = new RelayResponder(this,"onResult","onStatus");
        o.service = new Service(null,null,pService,con, o.responder);
        
        services.push(o);
        
        
    }
    private function getService (pService:String):Object
    {
        var i:Number = services.length;
        
        while (--i > -1) {
            if (services[i].name == pService) {
                return services[i];
            }
        }
        return null;
    }
    
    private function connect () :Void
    {
        if (connected) return;
        con = new Connection();
        con.connect(gatewayUrl);
        con.setCredentials(user,pass);
        connected = true;
    }
    
    private function disconnect () :Void
    {
        if (!connected) return;
        con.close();
        connected = false;
    }
    
    public static function getInstance ():RemoteManager {
        
        if (instance == null) {
            instance = new RemoteManager();
        }
        return instance;
        
    }
    
    public function addRemoteCall(pService:String, pMethodName:String , pResponder:Object):Void {
        
        if (arguments.length < 3) {
            trace ("invalid Number of Arguments");
            return;
        }
        
        if (!connected) connect();
        
        addService(pService);
        
        queue.push({s:getService(pService).service, f: pMethodName, r: pResponder, a:arguments.splice(3,arguments.length)});
        remoteCall();
 
    }
    
    private function remoteCall ():Void {
        
        if ( executing)  return;
        
        if (queue.length == 0) {
            disconnect();
            return;
        } 
        
        executing = true;
        var c:Object = queue[0];
        c.s[c.f].apply( c.s , c.a );
    
    }
    
    private function informResponder (responderFunction:String, result:Object):Void 
    {
        if (queue[0].r != null) {
            queue[0].r[responderFunction](result);
        }
        queue.shift();
        executing = false;
        remoteCall();
        
    }
    
    public function onResult (re:ResultEvent):Void {
        
        informResponder("onResult", re.result);
 
    }
    
    public function onStatus (fe:FaultEvent):Void {
        informResponder("onFault", fe.fault);
 
    }
 
} 

vereinfacht die Remote-Calls und führt die Aufrufe hintereinander aus.

Anwendung:

rm = RemoteManager.getInstance();
rm.initialize("http://www.deineur.de/gateway.php","deinUsername","deinPassword");
 
// Passwort und Username werden für geschützte Remote-Funktionen benötigt.
 
o = {};
o.onResult = function (result) {
    trace(result);
}
o.onError = function (fault) {
    trace (fault.faultstring);
}
 
rm.addRemoteCall("deinService","getName",o, "zackzack"); 

erste Arg ist der Service, zweiter der Funktionsname, dritter der Listener,
hinter dem dritten argument kommen die Arguments für die PHP-Funktion.

müssten noch nen paar dinge rein, z.b. das verhalten wenn der Service nicht existiert etc.

[messingfeld]

Ich habe bis jetzt noch nicht so die Zeit gefunden, einen eigenen zu schreiben.
Aber an die connect und disconnect - Methoden habe ich auch schon gedacht. Sonst super.

Was ich mir sonst noch so gedacht haben:
Wie wäre es wenn man mehrere Service-Methoden zu einer Gruppe zusammenfassen würde.

Beispiel: Gästebuch.
Da trägt man sich ein (service.write()) und dann werden alle Einträge gelesen (service.read()).

Das man das zusammenpack in z.B.:
rm.addRemoteCall("Gästebuch", "schreibeLese")
Und da intern service.write() & service.read() nacheinander ausgeführt werden.

Ich hoffe du verstehts meine Gedanken.
Bei meinem Beispiel (Gästenbuch) hält sich das noch in Grenzen.
Aber es gibt bestimmt Anwendugen wo man mehrere Service - Methoden immer und immer wieder hintereinander aufrufen muss.
Da wäre das doch eine Erleichterung.

cu messingfeld

[K-Grabowski]

wäre es nicht sinnvoller das dann individuell auszulagern?

function readAndWrite () {
re.addRemoteCall("Gästebuch","write");
re.addRemoteCall("Gästebuch","read");
}
 
readAndWrite(); 

[messingfeld]

Wäre schon, war auch nur so ein Gedanke.

Aber trotzdem könnte man dann einen gemeinsamen Responder für diese Gruppe definieren.

Wo bei dir bisher für jede Service-Methode dieser einzeln wäre:

if (arguments.length < 3) {
            trace ("invalid Number of Arguments");
            return;
        } 

Da du für jede Methode eine "Ergebnisverarbeitung" verlangst. Das könnte man dann intern regeln. Und dann ein Ergebnis für die Gruppe zurückgeben.

Naja könnte dann alles ein wenig OverKill wirken.
Aber sind ja nur alle Gedankenblitze von mir.

Think different

cu messingfeld

[K-Grabowski]

ja gut, ich kann ja entweder arguments auf 2 beschränken, dann könnte man auch einen Remote-Call ohne Responder machen, oder ich kann ja einfach null übergeben.

[messingfeld]

Zitat von K-Grabowski

ja gut, ich kann ja entweder arguments auf 2 beschränken, dann könnte man auch einen Remote-Call ohne Responder machen, oder ich kann ja einfach null übergeben.

Da bleibt dann das Prob das man an einer Service-Methode den Responder wieder dran "hängen" muss.

Ich habe mehr an sowas oder ähnliches gedacht.

// Think different - Beispiel ;-)
rm.createRemoteGroup("Service", "Gästebuch", "Responder");
rm.addToRemoteGroup("Gästebuch", "write");
rm.addToRemoteGroup("Gästebuch", "read");
rm.callRemoteGroup("Gästebuch"); 

Ich werde mich wohl mal nächste Woche dran setzen und auch mal was versuchen.
Aber vielleicht werde ich dann merken das ich auf der falschen Pfärte bin.

Auf jeden Fall macht es Spaß das hier der Remoting (besser AmfPHP) - Bereich wächst.

cu messingfeld

[K-Grabowski]

jau, musst mal zeigen wie du es gemacht hast, hab meinen auch noch einen bisschen umgebaut, ist aber noch nicht ganz fertig, muss noch optimiert werden. Aber hab zurzeit kaum zeit dafür.

[K-Grabowski]

V2.01

habs jetzt auch in zwei Klassen gesplittet.

RemoteManager Klasse

import mx.remoting.Connection;
import mx.remoting.Service;
import mx.rpc.RelayResponder;
import mx.rpc.ResultEvent;
import mx.rpc.FaultEvent;
import mx.remoting.debug.NetDebug;
import de.hh.remote.*;
 
 
class de.hh.remote.RemoteManager {
    
    private var queue:Array;
    private static var instance:RemoteManager = null;
    private var executing:Boolean;
    private var con:Connection;
    private var services:Array;
    private var user:String;
    private var pass:String;
    private var gatewayUrl:String;
    private var connected:Boolean;
    private var initialized:Boolean;
    private var responder:RelayResponder;
 
    
    private function RemoteManager () 
    {
        NetDebug.initialize();
        
        services = new Array();
        connected = false;
        queue = new Array();
        executing = false;
        responder = new RelayResponder(this,"onResult","onFault");
    }
    
    public function setGatewayUrl (pGatewayUrl:String):Void
    {
        gatewayUrl = pGatewayUrl;
    }
    
    public function removeCredentials ():Void 
    {
        user = pass = null;
    }
    
    public function setCredentials ( pUser:String , pPass:String ):Void
    {
        user = pUser;
        pass = pPass;
    }
    
    private function addService (pService:String):Void 
    {
        
        removeService(pService);
        
        var s:Service = new Service(null,null,pService,con, responder);
        
        services.push(s);
        
        
    }
    
    private function removeService (pService:String):Void 
    {
        var i:Number = services.length;
        
        while (--i > -1) {
            if (services[i].name == pService) {
                services.splice(i,1);
            }
        }
        
    }
        
    private function getService (pService:String):Service
    {
        var i:Number = services.length;
        
        while (--i > -1) {
            if (services[i].name == pService) {
                return services[i];
            }
        }
        return null;
    }
    
    private function connect () :Void
    {
        if (connected) return;
        con = new Connection();
        if (!con.connect(gatewayUrl)) trace ("can't connect to the gateway, or gateway isn't set");
        if (user != null && pass != null) {
            con.setCredentials(user,pass);
        }
        connected = true;
    }
    
    private function disconnect () :Void
    {
        if (!connected) return;
        con.close();
        connected = false;
    }
    
    public static function getInstance ():RemoteManager {
        
        if (instance == null) {
            instance = new RemoteManager();
        }
        return instance;
        
    }
    
    public function addCall(pService:String, pMethodName:String , pResponder:RelayResponder):Void 
    {
        if (!connected) connect();
        
        addService(pService);
        
        queue.push( new RemoteCall( getService(pService), pMethodName, pResponder, arguments.splice(3,arguments.length) ) );
        doCall();
 
    }
    
    private function doCall ():Void {
        
        if ( executing)  return;
        
        if (queue.length == 0) {
            disconnect();
            return;
        } 
        executing = true;
        var c:RemoteCall = queue[0];
        c.getService()[ c.getMethod() ].apply( c.getService() , c.getArgs() );
    
    }
    
    private function informResponder (responderFunction:String, result:Object):Void 
    {
        if (queue[0].getResponder() != null) 
        {
            queue[0].getResponder()[responderFunction](result);
        }
        queue.shift();
        executing = false;
        doCall();
        
    }
    
    public function onResult (re:ResultEvent):Void 
    {
        informResponder("onResult", re);
 
    }
    
    public function onFault (fe:FaultEvent):Void 
    {
 
        informResponder("onFault", fe);
 
    }
 
} 

RemoteCall Klasse

import mx.remoting.Service;
import mx.rpc.*;
 
class de.hh.remote.RemoteCall 
{
    
    private var method:String;
    private var args:Array;
    private var responder:RelayResponder;
    private var service:Service;
    
    public function RemoteCall (p_service:Service, p_method:String, p_responder:RelayResponder, p_args:Array)
    {
        service = p_service;
        method = p_method;
        responder = p_responder;
        args = p_args;
    }
    
    public function getMethod ():String 
    {
        return method;
    }
    
    public function getArgs ():Array
    {
        return args;
    }
    
    public function getResponder ():RelayResponder
    {
        return responder;
    }
    
    public function getService ():Service
    {
        return service;
    }
    
} 

Anwendung:

import de.hh.remote.*;
import mx.rpc.*;
 
var rm:RemoteManager = RemoteManager.getInstance();
rm.setGatewayUrl("http://www.meineDomain.de/gateway.php");
rm.setCredentials("userName","pass"); // wird nur benötigt falls man rechte braucht
 
 
 
var o:Object = {};
o.onResult = function (e:ResultEvent) {
    trace(e.result.items[0].P_Headline);
}
o.onFault = function (e:FaultEvent) {
    trace (e.fault.faultstring);
    trace (e.fault.description);
    trace (e.fault.faultcode);
}
 
rm.addCall("meineServiceKlasse","meineMethode",new RelayResponder(o,"onResult","onFault"), "argument1", "argument2");
rm.addCall("meineServiceKlasse","meineMethode2",null, "argument1"); // falls kein Responder nötig
rm.addCall("meineServiceKlasse","meineMethode3",new RelayResponder(o,"onResult","onFault"), "argument1", "argument2"); 

[patte04]

hy

import de.hh.remote.*; ??

ich habe das jetzt so verstanden:
ich lege zwei scripte an: einmal den RemoteManager.as und RemoteCall.as

lege dann im Ordner flashMX/de/firstRun/classes/
die Ordner de/hh/remote
und lege dort die 2 Scripte rein?

ich bekomm jedenfalls den fehler: die klasse konnte nicht geladen werden.
was mach ich falsch??

[K-Grabowski]

ich hab die in nem eigenen klassen-order mit der struktur
de/hh/remote

müsste zwar eigentlich auch gehen wenn du die in den firstrun - classes order packst, aber sonst versuch folgendes:

mach dir nen order und nenne den classes oder so.
dadrinne machste nen de ordner, worein du nen hh order machst, darein nen remote ordner und darein legste die beiden klassen.

in Flash-MX-2004 setzt du unter bearbeiten/voreinstellungen/actionscript/actionscript2 einstellungen einen zusätzlichen klassenpfad auf diesen classes ordner. dann sollte es gehen.

[patte04]

yessss
:-) funzt wunderbar. ich weiss jetzt auch warum das mit den ordnern bei mir nicht ging. aber nicht lachen:

man sollte flash einfach nochmal neu starten, so einfach kann es sein.

vielen dank für deine hilfe, und ich finde den RemoteManager perfekt für meine Zwecke. danke fürs freistellen.


vielleicht bekommt man das script von @messingfeld auch noch ans laufen.


thanx
patte

[fliponaut]

moin moin ...
ich benutze nun ja auch schon laengere zeit den remoteManager und eigentlich gab es noch keine probleme
heute wollte ich die ganze sache dann jedoch mal im "netconnection debugger" beobachten ... dabei sind mir ein paar sachen aufgefallen.

1) es kommt immer wieder die gleiche "warning"

PHP-Code:

number: 4
severity: "warning"
Trace: "createGatewayConnection - gatewayUrl is invalid"
who: "NetServices" 


kennt die jemand - oder weiss, was das zu sagen hat? es funktioniert ja alles, aber wundern tut mich das schon.

2) zudem disconnected sich der remotemanager ja immer, wenn keine calls mehr in der queue stehen. beim ersten mal laueft dann ja auch alles toll (im netconnection debugger). nachdem aber einmal das "close" aufgerufen wurde, zeigt der debugger nur noch warnings an, leider keine calls/results mehr!?

vielleicht koennt ihr mir da ja ein bisschen weiterhelfen?!

gruss, philipp

[greta_lee]

Hallo K-Grabowski,

hast Du mal getestet, ob folgender Code wirklich funktioniert?

...
con = new Connection();
if (!con.connect(gatewayUrl)) trace ("can't connect to the gateway, or gateway isn't set");
...

Bei mir gibt die Funktion connect() immer ein true zurück, auch wenn die Gateway-Url falsch ist. Es gibt erst eine Fehlermeldung, wenn zum ersten mal ein Call gemacht wird. Der geht aber dann leider nicht in die _status-Methode, sondern gibt nur einen Fehler in der Console aus.

Es würde mir sehr helfen, wenn Du dazu einen Rat hättest.

[K-Grabowski]

ne hatte es ehrlich gesagt nicht getestet und funzt auch nicht, es wird lediglich geprüft ob der gatewayurl-string ein "http:" oder ein "https:" enthält.

connect
connect( url: String) : Boolean


Definiert die Flash Remoting-URL, die von Flash Remoting-Servicefunktionsaufrufen verwendet wird. Diese Methode kommuniziert nicht mit dem Server. Wenn Flash Remoting einen Servicefunktionsaufruf ausführt, wird eine HTTP- oder HTTPS-Verbindung zu den Anwendungsservern hergestellt. Diese Verbindung bleibt nur solange bestehen, bis die Ergebnisse des Aufrufs an die Flash-Anwendung zurückgegeben werden. Hinweis: Wenn Sie eine Gateway-Verbindung herstellen und auf Remote-Servicefunktionen zugreifen möchten, sollten Sie das Serviceobjekt verwenden.
Parameter
url: String - Die Flash Remoting-URL [Protokoll://] Host [:Port] /Anwendungsname. Der Wert für Anwendungsname hängt von dem Gateway-Typ und der Flash Remoting-Konfiguration ab. Weitere Informationen finden Sie unter Die Flash Remoting Gateway-Verbindung herstellen. Wenn Sie Protokoll:// auslassen, geht Flash davon aus, dass Sie über das nicht sichere HTTP-Protokoll eine Verbindung zu einem Anwendungsserver herstellen möchten. Der zweite akzeptable Wert für Protokoll lautet https. Die folgenden URLs sind beispielsweise korrekt formatiert:

http://localhost:8500/flashservices/gateway
https://www.myCompany.com/myMainDire...moting/gateway



Zurückgegebene Daten
Der Boolesche Wert true, wenn der Protokollteil der URL (http: oder https gültig ist, anderenfalls false.

hab jetzt auf die schnelle auch keine Lösung parat.

[greta_lee]

Vielleicht fällt uns noch eine Lösung ein?! Es kann einfach nicht sein, dass man dem User eine Anwendung zur Verfügung stellt, die ihm nicht sagt, wenn z.B. kein Netz da ist. Denn dieser Fehler läßt sich einfach nicht abfangen und demnach kann man keine Fehlermeldung ausgeben.

Worin steht eigentlich die Doku, die zu zitierst? Ich suche schon so lange nach guter Doku. Meistens suche ich mir alles aus dem Netz zusammen. Einiges steht in den livedocs von Macromedia. Aber nur in englisch und nicht sehr ausführlich.