[AMFPHP] tutorial für AS2.0

[madflanderz]

nach dem installieren des flashremoting_comp_as20 wollte ich nun endlich mal amfphp ausprobieren.

alle beispiele fangen so an:

PHP-Code:

#include "NetServices.as" 


aber flash meint diese datei nicht zu finden.

**Fehler** Szene=Szene 1, Ebene=Ebene 1, Bild=1:Fehler beim Öffnen der Include-Datei NetServices.as: Datei nicht gefunden.

in der doku zu netServices stand auch das NetServices.as veraltet ist. gibt es irgendwo ein tutorial für amfphp mit AS 2.0 ??? oder wie soll ich jeze an die sache rangehen ?

[nky]

ja so ein tutorial wär echt mal ne feine sache !

[madflanderz]

einfach nur ein


!!! HELLO WORLD !!!

[Alienhunter]

Versuch doch das einmal ... für AS 2.0

import mx.remoting.NetServices;
import mx.remoting.NetServiceProxy;
import mx.remoting.Connection; 

Zudem würde ich in der Flash Help für Remoting einmal reinschauen.

und auf flash-db.com findest du ein Beispiel für ein Hello World.
Ist auf AS 1.0 aber eine gute Basis um es auf AS 2.0 umzubauen.
http://www.flash-db.com/remoting/?se...category=Basic

gruss @all

alien

[madflanderz]

ohhhh, man - ich hatte vergessen die RemotingClasses komponente auf die bühne zu ziehen. obwohl ich davon ausgegangen bin, daß wenn ich ein import schreibe ich nicht auch noch irgendwas auf die bühne ziehen muß, naja danke, werd ma mein glück versuchen.

[madflanderz]

hab jeze dies gemacht.

PHP-Code:

import mx.remoting.NetServices;
import mx.remoting.NetServiceProxy;
import mx.remoting.Connection;
import mx.remoting.debug.NetDebug;
 

NetDebug.initialize();


var serverConn =  NetServices.createGatewayConnection("http://localhost/flashservices/gateway.php");
var servD = serverConn.getService("HelloWorld", this);

servD.sayHelloWorld();
trace(servD) 


die funktion sayHelloWorld liefert den string "HelloWorld" zurück. WIE komme ich nun daran. ich verstehe noch nicht ganz wo und wie die eintreffenden daten gespeichert werden. !!! HILFE !!!


edit: was bedeutet dieser fehler:

Status (object #2)
.....code: "NetConnection.Call.BadVersion"
.....description: ""
.....details: ""
.....level: "error"

[JoshXP]

import mx.remoting.NetServices;
import mx.remoting.NetServiceProxy;
import mx.remoting.Connection;
import mx.remoting.debug.NetDebug;


NetDebug.initialize();


var serverConn = NetServices.createGatewayConnection("http://localhost/flashservices/gateway.php");
var servD = serverConn.getService("HelloWorld", this);

var ergebnis = servD.sayHelloWorld();
trace (ergebnis);

sollte gehen.

bad call version bedeutet das du einen fehler in der php datei hast.

mfg

[madflanderz]

wie kann ich denn rauskriegen wo der fehler dort liegt?? ist ja nicht grade aussagekräftig die meldung. hab fogendes:

in der fla

PHP-Code:

import mx.remoting.NetServices;
import mx.remoting.NetServiceProxy;
import mx.remoting.Connection;
import mx.remoting.debug.NetDebug;
 

  NetDebug.initialize();
  
  
serviceResult = new Object(); 
serviceResult.onResult = function(result){ 

    // wird komischerweise NIE aufgerufen, ok - vielleicht wegen badCall

    country_txt.text = result; 
    trace("hallo");
}
  
var serverConn =  NetServices.createGatewayConnection("http://localhost/flashservices/gateway.php");
var servD = serverConn.getService("HelloWorld", serviceResult);

var erg = servD.sayHelloWorld();
trace(erg);  // liefert false 


in HelloWorld.php

PHP-Code:

<?php

class HelloWorld {

    function HelloWorld() {
      $this->methodTable = array (
        'sayHelloWorld' => array (
          'description' => 'Writes "Hello World" to Flash',
          'access' => 'remote',
          'roles' => 'HelloGroup',
          'arguments' => array()
        )
      );
    }

    function sayHelloWorld() {
      return 'Hello World';
    }
  }
?>

wo soll in den paar zeilen bitte der fehler sein? kann es vielleicht auch an irgendwelchen apache-einstellungen liegen?

[JoshXP]

probiers mal mit kleinen dateinamen

[Alienhunter]

hi @ all vielleicht so..
ich habe es nur ergänzt aber nicht getested.
in der help steht etwas von einem PendingCall und responder..vielleicht geht es so ???

import mx.remoting.NetServices;
import mx.remoting.NetServiceProxy;
import mx.remoting.Connection;
import mx.remoting.debug.NetDebug;
 
 
  NetDebug.initialize();
  
 /* 
serviceResult = new Object();
serviceResult.onResult = function(result){
    // wird komischerweise NIE aufgerufen, ok - vielleicht wegen badCall
    country_txt.text = result;
    trace("hallo");
}
  */
var serverConn =  NetServices.createGatewayConnection("http://localhost/flashservices/gateway.php");
var servD = serverConn.getService("HelloWorld", serviceResult);
 
//var erg = servD.sayHelloWorld();
var erg:PendingCall = servD.sayHelloWorld();
//trace(erg);  // liefert false 
 
//responder definieren
erg.responder = new RelayResponder( this, "onConfigData", "onConfigFault" );
 
/* output von onConfigData*/
function onConfigData(rs:ResultEvent):Void{
trace(rs.result)    
}
/* Error */
function onConfigFault(fault:FaultEvent){   
trace(fault)
} 

Denn Panel NetConnetion Debugger sollte dann etwas zeigen was abgeht.
amf checkbox reinhängen

gruss @all

alienhunter

[madflanderz]

!!!! YUHUUUUUUU !!!!

ich habe meinen ersten service erreicht !

danke für die hilfe alienhunter. habe noch ien bischen rumgekuckt und z.b. hier noch ein paar nützliche hinweise gefunden, z.b. daß man bei windows alle datei -, classen - und methodennamen klein schreiben soll.

ich habe jeze folgendes und das klappt auch:

in der fla:

PHP-Code:

import mx.remoting.NetServices;
import mx.remoting.NetServiceProxy;
import mx.remoting.Connection;
import mx.remoting.debug.NetDebug;
 

  NetDebug.initialize();
  
  
serviceResult = new Object(); 
serviceResult.onResult = function(result){ 
    country_txt.text = result; 
    trace("hallo");
    trace(result);     // hier kommt die ausgabe, z.B. 2
}

var serverConn =  NetServices.createGatewayConnection("http://localhost/flashservices/gateway.php");
var servD = serverConn.getService("counter", serviceResult);
var erg = servD.addone(); 


und die datei counter.php

PHP-Code:

<?php 
/* 
* Counter service 
* Author: Jorge Solis 
* Site:  [url]www.flash-db.com/remoting/[/url] 
*/ 

class counter{ 

      function counter(){ 
        $this->methodTable = array( 
            "addone" => array( 
              "description" => "Increment counter in the txt file", 
              "access" => "remote", // available values are private, public, remote 
              "argument" =>array("file"), 
              "returntype" => "String" 
            ) 
        ); 
      } 
       
      function addone(){ 
          //Open first in read mode 
        if($fp = fopen("counter.txt", "r")) { 
            while(!feof($fp)) $oldCant = fgets($fp, 4096); 
            fclose($fp); 
            //Open in write mode 
            $fp = fopen("counter.txt", "w");             
            $newCant = $oldCant+1; 
            fwrite($fp, $newCant); 
            fclose($fp); 
            return $newCant; 
        } else return "Error opening the file"; 
      }   
} 
?>

erst als ich ALLES klein geschrieben habe hat es funktioniert.


edit: toll Josh, hab grade erst dein beitrag mit den dateiname gelesen, hihi, auch an dich ein dankeschön und rauch nich soviel, geb lieber was ab

[Alienhunter]

hi @maddin79

to fast for me .... subi !!

Das sieht ja richtig klasse aus!!!

use the force maddin79

alien

[JoshXP]

So hier mal noch eine variante. Is auch eine gute variante

mfg.

Remoting Class
http://www.amfphp.org/components/

PHP-Code:


import org.amfphp.remoting.NetServices;

serviceResult = new Object();
serviceResult.onResult = function(result) {
    trace("Input");
};

var serverConn = NetServices.createGatewayConnection("http://www.supertoll.net/gateway.php");
var servD = serverConn.getService("site", serviceResult);
var erg = servD.getPixelMenu(1);

trace(erg); 


[madflanderz]

hi josh,

emtweder ich bin vom WE noch zu verpeilt oder ich seh grad null unterschied (falls es überhaupt einen gibt) zur mx.remoting.NetServices klasse.

kannste mal bitte kurz erläutern, was nun an der org.amfphp.remoting.NetServices der vorteil ist und warum ich lieber diese klasse verwenden sollte???

[messingfeld]

Tach, ich habe mal die verschiedenen Verbindungsaufbauverfahren und Nutzungsarten unter Flash MX 2004 mit den dazugehörigen Komponenten auseinander gesetzt.
Wenn ihr mal testen wollt, dann überall die gatewayURL ändern.
Der Service remoteKlasse steht unten. Ist aber nur ein kleines Testscript.
remoteKlasse müsst ihr natürlich in euren Service-Ordner packen.

Ich habe ausserdem ein *.rar drangehangen wo alle Scripts drin sind.

Scripte runterladen

1. Verfahren: new Connection()
Vorteile:
- Verbindung kann beliebig aufgebaut und getrennt werden
- Service kann man ohne Probs wechseln da der Aufruf über Service.Methode geht

Nachteile
- keine Fehlerverarbeitung
(- keine vollständige zentrale Ergebnis- und Fehlerverarbeitung)
(- Parameter werden „unüblich übergeben)

Beispiel 1:
connection.fla

import mx.remoting.Connection;
import mx.rpc.RelayResponder;
import mx.rpc.ResultEvent;
import mx.rpc.FaultEvent;
mx.remoting.debug.NetDebug.initialize();
//
// Gateway - URL
var gatewayURL:String = "http://localhost/remote/gateway/gateway.php";
// neue Verbindung
var con:Connection = new Connection();
// Ergebnis- oder Fehlerverarbeitung
var dataResp:RelayResponder = new RelayResponder(this, "erfolgreich", "fehlerhaft");
// Erstelle Verbindung zum Gateway
con.connect(gatewayURL);
// Rufe Methode auf (Service.Methode)
// deshalb muss kein Service vorher definiert werden
con.call("remoteKlasse.methode1", dataResp);
// Argumente werden hinten dran gehangen
// GEFÄLLT MIR ABER NICHT
con.call("remoteKlasse.methode3", dataResp, "Ich bin gut!");
// Schließt Verbindung
con.close();
// Wird nie ausgeführt da keine Verbindung besteht
con.call("remoteKlasse.methode2", dataResp);
//
// bei Erfolg wird die Funktion aufgerufen:
function erfolgreich(meinErgebnis:ResultEvent) {
    trace("Ergebnis: "+meinErgebnis);
}
// Bei Fehler diese:
// Wird aber nie aufgerufen, da über
// Connection irgendwie keine Fehler
// verarbeitet werden
// NACHTEIL!!!
function fehlerhaft(meinFehler:FaultEvent) {
    trace("Fehler: "+meinFehler.fault.faultstring);
    trace("Code: "+meinFehler.fault.faultcode);
    trace("Typ: "+meinFehler.fault.type);
    trace("Detail: "+meinFehler.fault.detail);
} 

2. Verfahren: new Service();
Vorteile:
- Fehlerverarbeitung
- vollständige zentrale Ergebnis- und Fehlerverarbeitung
- auch individuelle Ergebnis- und Fehlerverarbeitung möglich
- Parameter werden normal übergeben

Nachteil:
- Verbindung kann nicht beliebig aufgebaut und getrennt werden
- Service muss man manuell definieren.

Beispiel 2: individuelle Ergebnis- und Fehlerverarbeitung
service1.fla

import mx.remoting.Service;
import mx.remoting.PendingCall;
import mx.rpc.RelayResponder;
import mx.rpc.ResultEvent;
import mx.rpc.FaultEvent;
mx.remoting.debug.NetDebug.initialize();
//
// Gateway - URL und Service
var gatewayURL:String = "http://localhost/remote/gateway/gateway.php";
var meinService:String = "remoteKlasse";
// Erstelle Verbindung und weise Service zu
var serv:Service = new Service(gatewayURL, null, meinService);
// Rufe Service-Methoden auf
var aufruf1:PendingCall = serv.methode1();
// Argumentübergabe ist logischer
var aufruf2:PendingCall = serv.methode3("Ich bin gut");
//weise Ergebnis- oder Fehlerverarbeitungsfunktionen zu 
// Nur vorteilhaft wenn unterschiedlich Ergebnise, wie Object, Array
// oder String zurückgegeben wird, worauf unterschiedlich reagiert werden muss
// SONST ZU AUFWENDIG
aufruf1.responder = new RelayResponder(this, "erfolgreich", "fehlerhaft");
aufruf2.responder = new RelayResponder(this, "erfolgreich", "fehlerhaft");
//
// MAN KANN DIE VERBINDUNG ABER NICHT UNTERBRECHEN
// ODER ICH HABE ES NOCH NICHT GEFUNDEN
//
// bei Erfolg wird die Funktion aufgerufen:
function erfolgreich(meinErgebnis:ResultEvent) {
    trace("Ergebnis: "+meinErgebnis.result);
}
// Bei Fehler diese:
function fehlerhaft(meinFehler:FaultEvent) {
    trace("Fehler: "+meinFehler.fault.faultstring);
    trace("Code: "+meinFehler.fault.faultcode);
    trace("Typ: "+meinFehler.fault.type);
    trace("Detail: "+meinFehler.fault.detail);
} 

Beispiel 2.1: zentrale Ergebnis- und Fehlerverarbeitung
service2.fla

import mx.remoting.Service;
import mx.rpc.RelayResponder;
import mx.rpc.ResultEvent;
import mx.rpc.FaultEvent;
mx.remoting.debug.NetDebug.initialize();
//
// Gateway - URL und Service
var gatewayURL:String = "http://localhost/remote/gateway/gateway.php";
var meinService:String = "remoteKlasse";
// zentrale Ergebnis- oder Fehlerverarbeitung
var dataResp:RelayResponder = new RelayResponder(this, "erfolgreich", "fehlerhaft");
// Erstelle Verbindung und weise Service zu
var serv:Service = new Service(gatewayURL, null, meinService, null, dataResp);
// Rufe Service-Methoden auf
serv.methode1();
serv.methode2();
// Argumentübergabe ist logischer
serv.methode3("Ich bin gut");
//
// MAN KANN DIE VERBINDUNG ABER NICHT UNTERBRECHEN
// ODER ICH HABE ES NOCH NICHT GEFUNDEN
//
// bei Erfolg wird die Funktion aufgerufen:
function erfolgreich(meinErgebnis:ResultEvent) {
    trace("Ergebnis: "+meinErgebnis.result);
}
// Bei Fehler diese:
function fehlerhaft(meinFehler:FaultEvent) {
    trace("Fehler: "+meinFehler.fault.faultstring);
    trace("Code: "+meinFehler.fault.faultcode);
    trace("Typ: "+meinFehler.fault.type);
    trace("Detail: "+meinFehler.fault.detail);
} 

3. Verfahren: new Connection(); + new Service();
Vorteile:
- alle von new Connection(); + new Service();

Nachteile:
- Service muss man manuell definieren.

Beispiel 3:
connection-service.fla

import mx.remoting.Connection;
import mx.remoting.Service;
import mx.rpc.RelayResponder;
import mx.rpc.ResultEvent;
import mx.rpc.FaultEvent;
mx.remoting.debug.NetDebug.initialize();
//
// Gateway - URL und Service
var gatewayURL:String = "http://localhost/remote/gateway/gateway.php";
var meinService:String = "remoteKlasse";
// neue Verbindung
var con:Connection = new Connection();
// zentrale Ergebnis- oder Fehlerverarbeitung
var dataResp:RelayResponder = new RelayResponder(this, "erfolgreich", "fehlerhaft");
// Erstelle Verbindung zum Gateway
con.connect(gatewayURL);
// Definiere Service
var serv:Service = new Service(null, null, meinService, con, dataResp);
// Rufe Methoden auf
serv.methode1();
serv.methode3("Ich bin der Beste!");
// Schließt Verbindung
con.close();
// Wird nie ausgeführt da keine Verbindung besteht
serv.methode2();
// Verbinde wieder
con.connect(gatewayURL);
serv.methode3("methode2 übersprungen");
//
// bei Erfolg wird die Funktion aufgerufen:
function erfolgreich(meinErgebnis:ResultEvent) {
    trace("Ergebnis: "+meinErgebnis.result);
}
// Bei Fehler diese:
function fehlerhaft(meinFehler:FaultEvent) {
    trace("Fehler: "+meinFehler.fault.faultstring);
    trace("Code: "+meinFehler.fault.faultcode);
    trace("Typ: "+meinFehler.fault.type);
    trace("Detail: "+meinFehler.fault.detail);
} 

Service:
remoteKlasse.php

PHP-Code:

<?php    
class remoteKlasse
{

    function remoteKlasse()
    {        
        $this->methodTable = array(
        "methode1" => array(
                "access" => "remote", 
                "returns" => "string"
            ),
      "methode2" => array(
                "access" => "remote",
                "returns" => "string"
            ),
      "methode3" => array(
                "access" => "remote",
        "arguments" => array("arg"),
                "returns" => "string"
            )
        );
    }
    function methode1() {
    return "Flash Remoting funzt!";
  }
  function methode2() {
    return "Flashforum.de";
  }
  function methode3($arg) {
    return "Argument: ".$arg;
  }
}
?>

Wenn ihr in der Flashumbegebung den NetConnection - Debugger einblendet könnt ihr die Aufrufe und die Ergebnisse verfolgen (RemotingDebugClasses aus Bibliothek auf die Bühne ziehen).

Wenn Fehler in Script (PHP, AS) sind, werden die abgefangen (ausser bei der Beispiel 1). Durch die Ausgabe.
Es wird auch ein Fehlercode eingeblendet. meinFehler.fault.faultcode

Der Fehlercode steht in der Datei flashservices\exception\Exceptions.php .

Macht mal einen Fehler in das Service-PHP-Script (remoteKlasse.php) und ihr seht es.

So wäre es möglich eine eigene Fehlerklasse zu erstellen.
z.b. Fehlercode 256 ist ein Scriptfehler

Ich würde mich freuen wenn ihr dazu noch etwas beitragen könntet.
Oder mir meine Fehler nennen könnt, wenn welche drin sind.
Habe aber keine gefunden.

Viel Spaß!

cu messingfeld

Scripte runterladen

EDIT:
Ergänzung des Types :ResultEvent bei manchen Scripts.
Habe ich in der Eile vergessen.
(Datei wurde auch aktualisiert)