käferanimation soll maus folgen

[dimmid]

also: ich hab einen kleinen käfer, den ich auf meinen
seiten zum laufen bringen will. folgende punkte sind
mir wichtig:
1. er soll der maus folgen
2. er soll dies im gleichmäßigen tempo tun (nicht mal
schnell, mal langsam)
3. er muß sich der maus zuwenden (also rotieren)
4. er darf nur auf einer begrenzten fläche laufen

so weit so gut, hab also mit meinem bescheidenen
wissen über actionscript begonnen punkt eins zu
realisieren. sieht so aus:
onClipEvent (enterFrame) {
_x = _x+_xmouse/150;
_y = _y+_ymouse/150;
}

jetzt häng ich fest. hab zwar was zu rotation und
begrenzung gefunden, kann das aber nicht mit dem
bisheringen script verbinden.

für alle die helfen können:
>> hier der bisherige stand
>> hier zum downloaden

[ludabruda]

Hi,

du kannst den Winkel zwischen zwei Punkten mit Math.atan2(dy,dx) berechnen. Den musst du nur noch ins Gradmaß umrechnen und der _rotation zuweisen...

Zusätzlich packst du in dein onEnterFrame vor der Zuweisung der _x und _y Werte eine Abfrage a la: if(_x < 100 && _x > 0 && _y > 0 && _y < 100) { ... }

Grüße
Sascha

[dimmid]

danke, hab die begrenzung mal wie beschrieben probiert.
sieht jetzt so aus:
onClipEvent (enterFrame) {
if (_x < 500 && _x > 50 && _y >0 && _y < 500){
_x = _x+_xmouse/150;
_y = _y+_ymouse/150;}
}

geht leider nur bedingt so. sobald der käfer die begrenzung
erreicht, bleibt er stehen und macht gar nix mehr.

zur rotation hab ich das gefunden:
posX = _root._xmouse-_x;
posY = _root._ymouse-_y;
_rotation = -(Math.atan2(posX,posY)*(180/Math.PI));
}

weiß leider nicht, wie ich es richtig ins script setze!

[dimmid]

falls es jemanden interessiert ... ich habs soweit geschafft,
daß der käfer in gleichmäßigem tempo dem mauszeiger folgt
und immer schön mim kopf vorran läuft

hier die lösung:
auf einem mc auf der hauptbühne liegt dieses script:
onClipEvent (load) {
v = 3;
}
onClipEvent (mouseMove) {
sollX = _root._xmouse;
sollY = _root._ymouse;
deltaX = sollX-_x;
deltaY = sollY-_y;
deltaS = Math.sqrt(deltaX*deltaX+deltaY*deltaY);
frame = int(deltaS/v);
index = 0;
lauf = true;
faktorX = deltaX/frame;
faktorY = deltaY/frame;
}
onClipEvent (enterFrame) {
if (index++ != frame && lauf) {
_x += faktorX;
_y += faktorY;
} else {
_x = sollX;
_y = sollY;
lauf = false;
}
}

und in diesen mc kommt mein animierter käfer-mc rein.
auf den leg ich dann dieses script:
onClipEvent (mouseMove) {
_rotation = Math.atan2(_parent._y-_root._ymouse, _parent._x-_root._xmouse)/Math.PI*180-90;
}

jetzt muß ich nurnoch die bewegungs-begrenzung hinbekom-
men. also wenn jemand weiter weiß ... ich würd mich freuen

[ludabruda]

Für die Begrenzung frag am besten nicht den aktuellen Wert sondern den Wert nach Addition ab:

newX = _x+_root._xmouse/150;
newY = _y+_root._ymouse/150;
if (newX < 500 && newX > 50 && newY >0 && newY < 500){
...
} 

Dann sollte es gehen.

Grüße
Sascha

[dimmid]

danke, ich habs!

[Decrone]

Hi

ich hab mal ein bisschen Lust gehabt das ganze im MX-Style zu ändern

//Code auf Frame 1 / Hzl
MovieClip.prototype.krabbeln = function(v){
    this.onEnterFrame = function(){
        this.newX = this._x+_root._xmouse/150; 
        this.newY = this._y+_root._ymouse/150; 
        if (this.newX < 540 && this.newX > 70 && this.newY >30 && this.newY < 510){ 
            this.play();
            if (this.index++ != this.frame && this.lauf) {
                this._x += this.faktorX;
                this._y += this.faktorY;
            } else {
                this._x = this.sollX;
                this._y = this.sollY;
                this.lauf = false;
                this.gotoAndStop("stoppen");
            }
        }else{
            this.gotoAndStop("stoppen");
        }
    }
    this.onMouseMove = function(){
        this._rotation = Math.atan2(this._y-_root._ymouse, this._x-_root._xmouse)/Math.PI*180-90;
        this.sollX = _root._xmouse;
        this.sollY = _root._ymouse;
        this.deltaX = this.sollX-this._x;
        this.deltaY = this.sollY-this._y;
        this.deltaS = Math.sqrt(this.deltaX*this.deltaX+this.deltaY*this.deltaY);
        this.frame = int(this.deltaS/v);
        this.index = 0;
        this.lauf = true;
        this.faktorX = this.deltaX/this.frame;
        this.faktorY = this.deltaY/this.frame;
    }
}
kaefer1.krabbeln(3);//Hiermit rufst Du das ganze auf!
kaefer2.krabbeln(4); 

Anbei hab ich im Anhang ein zweites Krabbeltierchen intrigiert. Sieht lustig aus das ganze Siehe Download!

Und hier zum Downloaden

bye