Galerie mit fliessenden Übergängen Preloaden?

[hrsflash]

Muß nochmal nachfragen was jetzt falsch ist, habe festgestellt bei jedem nextPic werden die Bilder irgenwie addiert. Auch weitere Versuche und Varianten kein Erfolg.
Brauche unbedingt noch nen Hinweis.
Gruß hrsflash

[Der Frager]

Versuch mal, das Script wenigstens ewas zu verstehen :

PHP-Code:

var tl = this;
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic(i) {
    b1_MC.enabled = b2_MC.enabled=b3_MC.enabled=b4_MC.enabled=b5_MC.enabled=false;
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie("image"+i+".jpg");
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 10;
            } else {
                delete this.onEnterFrame;
                b1_MC.enabled = b2_MC.enabled=b3_MC.enabled=b4_MC.enabled=b5_MC.enabled=true;
            }
        }
    };
}
// 
nextPic(1);
//
b1_MC.onRelease = function() {
    nextPic(1);
};
b2_MC.onRelease = function() {
    nextPic(2);
};
b3_MC.onRelease = function() {
    nextPic(3);
};
b4_MC.onRelease = function() {
    nextPic(4);
};
b5_MC.onRelease = function() {
    nextPic(5);
}; 


[hrsflash]

Zitat von Der Frager

Versuch mal, das Script wenigstens ewas zu verstehen :

Im Nachhinein fragt man sich immer, warum nicht gleich so. Aber man lernt ja nie aus.
Dreh- und Angelpunkt am neuen Script ist für mich nextPic(i), deshalb kann var i = 0; usw. auch erzatzlos entfallen. Ich meine, das habe ich jetzt (bis zum nächsten Mal) so richtig verstanden.
Aber, herzlichen Dank
hrsflash

[Peadey]

Hallo,

danke für das Script - genau sowas habe ich gesucht. Ich arbeite mich gerade erst in AS ein und habe deshalb eine Frage, die sicherlich simpel ist, wenn man es weiß:

Was müsste dem Script hinzugefügt werden, um eine Funktion zu definieren, die einem Button erlaubt, eine Pause in die Bildabfolge zu legen, einem 2. Button, weiter zu spielen?

Danke und Gruß, Peter

[Peadey]

Habs gefunden.
2 buttons: einer "btn_pause", der andere "btn_play", dann:

PHP-Code:

btn_play._visible = false;

btn_pause.onRelease = function(){
    btn_play._visible = true;
    btn_pause._visible = false;
    clearInterval(tl.iv);
};

btn_play.onRelease = function(){
    btn_play._visible = false;
    btn_pause._visible = true;
    nextPic();
}; 


an das Script dranhängen.

Gruß, Peter

[Peadey]

Es ergibt sich ein sehr merkwürdiges Problem (hat nichts mit den Buttons zu tun).

Ich habe die Galerie in eine swf-datei eingebaut ("archiv"), die von einer übergeordneten swf ("index") geladen wird. Wenn ich die Galerie zum ersten Mal aufrufe, ist soweit alles in Ordnung, man kann alle Untergalerien aufrufen usw. Wenn ich zwischendurch einen anderen Link im index klicke und später wieder zur Galerie zurückkehre, gibt es ein heilloses Durcheinander in der Bildabfolge, es wirkt fast so, als wäre die Bildabfolge der vorherigen Aufrufe noch nicht beendet.

Suche wie verrückt nach einer Lösung, hab bisher aber noch nichts gefunden.

Ansehen kann man sich das hier.
Die fla. dateien sind hier , aber ohne die bilder-ordner.

Vielen Dank, falls sich jemand der Sache mal annimmt.

Peter

[Der Frager]

Habe mir deine Dateien nicht angeguckt. Aber du musst auf jeden Fall beim Wechseln der Seite den Intervall killen!

PS: "+++ Bitte keine Privat-Nachrichten bezüglich Flashfragen! +++"

[Peadey]

Nochmals Sorry wegen der PN und Danke für die Antwort, ich check das jetzt.

[Peadey]

Hm, ich find einfach nicht die Lösung.

Das Intervall hat ja den Paramter (tl.iv). Sollte ich den Kill zB auf nachfolgenden Seiten einbauen bei deren Aufruf? Aber wie wird das Intervall korrekt von anderen swf's angesprochen? Ich bin verwirrt...

[Der Frager]

Du wechselst doch über Buttons. Da schreibst du jeweils einfach

PHP-Code:

clearIntreval(tl.iv) 


mit drauf.

[Peadey]

Soweit verstanden. Diese Technik verwende ich, wenn ich zB die Bildabfolge per Pause-Button unterbrechen will.
Die Buttons zum Wechseln der Seite (seiten_loader auf index-swf wird entladen und bekommt ein anderes swf als inhalt) befinden sich aber auf _root. Die Galreie ist also untergeordnet.

Ich versuche gerade, die Links zum Seitenwechsel auf _root mit der Anweisung

PHP-Code:

on (release) {
    
    this.seiten_loader01.clearInterval(tl.iv);
    
} 


zu versehen, da passiert aber nichts in der Galerie-swf...

[Peadey]

Ich hab das jetzt so gelöst, dass tl=_root ist und dadurch können dann auch die _root buttons auf die steuerung zugreifen.

[Peadey]

Zusätzlich habe ich jetzt noch eingebaut, dass das vorherige Bild immer ausgeblendet wird, während das neue einblendet. Das ist wichtig bei Bildern unterschiedlicher Formate, da sonst das alte Bild immer nochsteht, während sich das neue drüberschiebt.

Keine Ahnung, ob das eleganter geht, das hier ist der komplette Code einschließlich der Pause/Play-Buttons.

Danke nochmal an DER FRAGER für die Gallery.

PHP-Code:

var tl = _root;
var i = 0;
var anz = 12;
// Anzahl Bilder
var bildpause = 2;
// Pause zwischen dem Laden
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("watcher2", 3);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
tl.loader1._x = 425
tl.loader1._y = 139
tl.loader2._x = 425
tl.loader2._y = 139

function nextPic() {
    i = i<anz ? ++i : 1;
    clearInterval(tl.iv);
    if (mc != tl.loader1) {
        mc = tl.loader1;
        mc2 = tl.loader2;
    } else {
        mc = tl.loader2;
        mc2 = tl.loader1;
    }
    
    //*******ausblenden des vorigen Bildes**********
    tl.watcher2.onEnterFrame = function() {
            if (mc2._alpha>0) {
                mc2._alpha -= 10;
            }else {
                delete this.onEnterFrame;
            }
    }
    //**********************************************

    
    
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie("bild"+i+".jpg");
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 10;
            } else {
                delete this.onEnterFrame;
                tl.iv = setInterval(nextPic, bildpause*1000);
            }
        }
    };
}
// 
nextPic();
//***Buttons für Play und für Pause (am besten übereinander legen)***

btn_play._visible = false;
btn_pause._visible = true;

btn_pause.onRelease = function(){
    btn_play._visible = true;
    btn_pause._visible = false;
    clearInterval(tl.iv);
};

btn_play.onRelease = function(){
    stop();
    btn_play._visible = false;
    btn_pause._visible = true;
    nextPic();
}; 


[Gerri84]

könnte mir vielleicht irgendwer sagen wie ich es hinbekomme das das erste bild am anfang alpawert 100% habe und der film danach normal weiterläuft !

Ein Ansatz wäre hier:

PHP-Code:

mc._alpha = 0; 


Setz die 0 testweise mal auf 100.