Galerie mit fliessenden Übergängen Preloaden?

[diebertadiebera]

Zitat von jeypack

Auf jeden Fall kann man sowas komplett programmieren.

Mit as gesteuerte Animationen lassen sich wesentlich
genauer und vielseitiger einstellen.

Tja, das glaube ich ja auch, drum bin ich ja hier, wenn ich nur wüsste wie das geht ...

Zitat von jeypack

Außerdem macht deine Keyframe-Animation genau das, was du
nicht möchtest, nämlich ruckeln!

es ruckelt, weil Anfang und End Bild im Tweening nicht sauber liegen.
Aber das war ja auch nie das Problem (Rabääääh ... schnüff)
Ich weiss gar nicht mehr, wie ich das erklären soll. Schau doch mal load_images.fla an, was in Flash MX unter samples zu finden ist. Das war die Grundlage. Nun will ich aber nicht, dass jedes Bild über weiss gefadet wird, sondern eben direkt über das nächste Bild.

[Der Frager]

Hallo!

Hatte gestern schon was Ähnliches. Noch schnell den Fade mit reingehauen...

PHP-Code:

var tl = this;
var i = -1;
var anz = 4;
// Aanzahl Bilder
var bildpause = 2;
// Pause zwischen dem Laden
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic() {
    i = i<anz ? ++i : 0;
    clearInterval(tl.iv);
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie("image"+i+".jpg");
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 5;
            } else {
                delete this.onEnterFrame;
                tl.iv = setInterval(nextPic, bildpause*1000);
            }
        }
    };
}
// 
nextPic(); 


[diebertadiebera]

Hallo derFrager,

du bist derHeld!

Das wars, viiiielen Dank!

[darwin26]

sorry@derFrager...
aber die Syntax hier prägt sich einfach nicht ein...
habs schon öfter gefragt... aber irgendwie stolpere ich da noch drüber...

PHP-Code:

i = i<anz ? ++i : 0; 


wie sieht das in einer for-Schleife aus???


Danke schonmal. grz.chris

[Der Frager]

for? Du meinst (wie immer) if, oder?

PHP-Code:

if(i<anz)
i++
else
i = 0 


[darwin26]

yep...nix for...sondern if...


chris

[Nofi]

PHP-Code:

var tl = this;
var i = -1;
var anz = 4;
// Aanzahl Bilder
var bildpause = 2;
// Pause zwischen dem Laden
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic() {
    i = i<anz ? ++i : 0;
    clearInterval(tl.iv);
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie("pic_"+i+"_.jpg");
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 5;
            } else {
                delete this.onEnterFrame;
                tl.iv = setInterval(nextPic, bildpause*1000);
            }
        }
    };
}
// 
nextPic(); 


Leere fla --> AS rein --> fertig.

Nix Ebenen, MCs oder was auch immer...

Ok, dann besser hier. Also es funktioniert auch so nicht, liegt das an meiner Version (8), meinem Player? Weil ich gerade sehe, dass der Code eigentlich für MX ist.

[darwin26]

Deine Bildernamen sind richtig und liegen im_root-Verzeichnis???
pic_0_.jpg
pic_1_.jpg
pic_2_.jpg
pic_3_.jpg
pic_4_.jpg
pic_5_.jpg


grz.chris

[Der Frager]

...weiß auch nicht, was genau du da machst. Also bei mir läuft das:

[Nofi]

Es funktioniert, nochmals vielen Dank! Ich habe bei meinen Bildernamen kein pic_0_.jpg gehabt und anscheinend muss dies dabei sein. So ein dummer Fehler! (Dummheit tut weh ). Danke!

[darwin26]

@derFrager...
spiel grad damit rum... und schon funzts nimma???
Nur weil ich n Array eingebaut hab... *grmpf* ...
1 Mal werden die Bilder schön gefadet... Nach dem ersten Durchgang
ist Schluss... hmm... warum ???

PHP-Code:

var tl = this;
var i = -1;
//
var bilder = ['image0.jpg', 'image1.jpg', 'image2.jpg', 'image3.jpg', 'image4.jpg']; // Array
var anz = bilder.length;
// 
var bildpause = 1;
//
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic() {
    i = i<anz ? ++i : 0;
    clearInterval(tl.iv);
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie(bilder[i]); // lade die Bilder aus dem Array
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 5;
            } else {
                delete this.onEnterFrame;
                tl.iv = setInterval(nextPic, bildpause*1000);
            }
        }
    };
}
// 
nextPic() 


Danke schonmal. grz.chris

[darwin26]

Mann manchmal ist aber auch jedes Array doof...

Lösung:

PHP-Code:

var anz = bilder.length-1; 


chris

[Nofi]

Und ich habe das ganze jetzt nochmal mit einer xml-Datei versucht, funktioniert aber nicht. Was mache ich falsch?

PHP-Code:

xmli = new XML();
xmli.ignoreWhite = true;
xmli.load("img.xml");
xmli.onLoad = function(status){
    if(status && this.loaded){
    anzahl = xmli.firstChild.childNodes.length;
    geladen = true;
    aktbild = 0;
    }
};

var tl = this;
var i = -1;
//
var bilder = xmli.firstChild.childNodes[paktBild].attributes.pic; // mein Child als Variable
var anz = bilder.length-1;
// 
var bildpause = 1;
//
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic() {
    i = i<anz ? ++i : 0;
    clearInterval(tl.iv);
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie(bilder[i]); // Child laden?
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 5;
            } else {
                delete this.onEnterFrame;
                tl.iv = setInterval(nextPic, bildpause*1000);
            }
        }
    };
}
// 
nextPic() 


XML:

PHP-Code:

<?xml version"1.0"?>
<Bilder>
<Bild pic="image0.jpg"></Bild>
<Bild pic="image1.jpg"></Bild>
<Bild pic="image2.jpg"></Bild>
<Bild pic="image3.jpg"></Bild>
</Bilder>

[Der Frager]

PHP-Code:

xmli = new XML();
xmli.ignoreWhite = true;
xmli.load("img.xml");
xmli.onLoad = function(status) {
    if (status && this.loaded) {
        anz = xmli.firstChild.childNodes.length;
        nextPic();
    }
};
var tl = this;
var i = -1;
// 
var bildpause = 1;
// 
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic() {
    i = i<anz-1? ++i : 0;
    clearInterval(tl.iv);
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie(xmli.firstChild.childNodes[i].attributes.pic);
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 5;
            } else {
                delete this.onEnterFrame;
                tl.iv = setInterval(nextPic, bildpause*1000);
            }
        }
    };
} 


[grit]

hallo @ der frager,

ich habe deine fade.fla gestestet und funktioniert wunderbar. tolle sache, danke dafür!

ich habe aber noch verständnisfragen:
- weshalb werden bei diesem beispiel externe bilder angezeigt?

- kann ich auch bilder aus der bibliothek zum abspielen bringen?

ich möchte ein komplettes .swf erzeugen, das ich vorladen und ersetzen kann:
1. habe die bilder imageX.jpg in je einen mc in der bibliothek gepackt, diesen mc verknüpft und einen instanznamen vergeben.
2. im as der variablen bilder die instanznamen genannt: var bilder = ['image0', 'image1', 'image2'];
3. und in der funktion nextPic() loadMovie ersetzt durch attachMovie.

-könnte das so funktionieren oder bin ich völlig auf dem holzweg?

thx
margarete