Problem beim Auslesen einer XML Datei

[resu]

Ich habe folgendes Problem:

Ich lese mit Hilfe eines XML Objektes eine entsprechende Datei aus. Durch eine onLoad Funktion des Objektes komme ich an den Dateiinhalt (über childNodes), und das ohne Probleme. Nun ich habe schon alle möglichen Themen hier durchgelesen, doch mir hilft nichts explizit weiter.

Das Problem: Ich kann die Daten zwar auslesen, aber keiner lokalen oder globalen Variablen zuweisen, damit ich die Daten für andere Zwecke verwenden kann. Könnte eventuell daran liegen, dass beim onLoad ein eigenes referenziertes Objekt zurgeliefert wird, aber wie umgehe ich das? Einige Themen über static functions + Variables haben mir nicht weitergeholen.

Hier ist der Code:

var xarray:Array;
var yarray:Array;
var Traffic:Array;
 
// create XML object
var contentXML:XML = new XML(); 
// ignore carriage returns betweens lines
contentXML.ignoreWhite = true; 
// load the XML document into the XML object
contentXML.load("global.xml"); 
 
// specify function to call once XML is loaded
contentXML.onLoad = function(success) {
    if (success) {
        //X-Achse auslesen
        xarray = new Array(this.childNodes[0].childNodes[0].childNodes.length);
        for (var x:Number = 0; x < this.childNodes[0].childNodes[0].childNodes.length; x++) {
            xarray.push(this.childNodes[0].childNodes[0].childNodes[x].attributes["value"]);
        }
        //Y-Achse auslesen
        yarray = new Array(this.childNodes[0].childNodes[1].childNodes.length);
        for (var y:Number = 0; y < this.childNodes[0].childNodes[1].childNodes.length; y++) {
            yarray.push(this.childNodes[0].childNodes[1].childNodes[y].attributes["value"]);
        }
        
        //Trafficwerte auslesen  
        Traffic = new Array(this.childNodes[1].childNodes.length);
        for (var i:Number = 0; i < this.childNodes[1].childNodes.length; i++) {
            Traffic[i] = new Array(5);
            Traffic[i][0] = this.childNodes[1].childNodes[i].attributes["value"];   //Anzahl Pakete
            Traffic[i][1] = this.childNodes[1].childNodes[i].childNodes[0].attributes["value"]; //from
            Traffic[i][2] = this.childNodes[1].childNodes[i].childNodes[1].attributes["value"]; //to
        }   
    }
}
 
trace(xarray);  //ergibt undefined 
 

Detail: die Zuweisung der childNodes-Inhalte an die Arrays funktioniert wunderbar, solange ich die Daten nur im onLoad Teil verwenden will. Möchte ich aber danach das "trace(xarray)" ausserhalb ausführen, kommt nur "undefined" heraus und nicht die gewünschten Daten.

Ich hoffe, mir kann jemand helfen, benötige dringend eine Lösung für unser Projekt. Danke!

[hgseib]

herzlichen glückwunsch, du bist der 3millionste forumbesucher mit exakt dieser frage.

du führst dein
trace(xarray); //ergibt undefined
aus, bevor flash überhaupt eine chance gehabt hatte die daten zu laden.

if (success) {
ab da stehen die daten zur verfügung.

beachte den zeitlichen ablauf und nicht, weil irgendetwas weiter unten im script steht würde es auch später ausgeführt. die function onLoad (wozu wäre die auch sonst da) wird erst ausgeführt, nachdem die daten geladen wurden.

var xarray:Array;
var yarray:Array;
var Traffic:Array;
// create XML object
var contentXML:XML = new XML();
// ignore carriage returns betweens lines
contentXML.ignoreWhite = true;
// load the XML document into the XML object
contentXML.load("global.xml");
// specify function to call once XML is loaded
contentXML.onLoad = function(success) {
    if (success) {
        //X-Achse auslesen
        var x_xml = this.childNodes[0].childNodes[0].childNodes;
        xarray = [];
        for (var x = 0; x<x_xml.length; x++) {
            xarray.push(x_xml[x].attributes.value);
        }
        //Y-Achse auslesen
        var y_xml = this.childNodes[0].childNodes[1].childNodes;
        yarray = [];
        for (var y = 0; y<y_xml.length; y++) {
            yarray.push(y_xml[y].attributes.value);
        }
        //Trafficwerte auslesen
        var t_xml = this.childNodes[1].childNodes;
        Traffic = [];
        for (var i = 0; i<t_xml.length; i++) {
            Traffic[i] = [];
            Traffic[i].push(t_xml[i].attributes.value);
            //Anzahl Pakete
            Traffic[i].push(t_xml[i].childNodes[0].attributes.value);
            //from
            Traffic[i].push(t_xml[i].childNodes[1].attributes.value);
            //to
        }
         fJetztGehtsLos();
    } else {
// fehlermeldung, keine daten bekommen!
}
 
};
function fJetztGehtsLos() {
    trace(xarray);
} 

[resu]

Danke, so etwas habe ich mir schon fast gedacht, bin nur irgendwie nicht drauf gekommen, wie ich das lösen könnte. Werde mir anhand deiner Lösung etwas basteln.

[resu]

Ich habe noch eine weitere Frage.

Das Ganze versuche ich nun in eine eigene Klasse einzubetten. Ich kann die Daten zwar wieder problemlos laden, jedoch kann ich dann innerhalb der Klasse nicht zu einer weitere funktion springen:

private function buildMatrix() {
        trace("build");
        var tempXML:XML = new XML();
        tempXML.ignoreWhite = true;
        switch(_global.state) {
            case "global":  tempXML.load("global.xml");
                            break;
        }
        tempXML.onLoad = function(success) {
            if  (success) {
                //X-Achse auslesen
                var x_xml = this.childNodes[0].childNodes[0].childNodes;
                AbszisseTo = [];
                for (var x = 0; x<x_xml.length; x++) {
                        AbszisseTo.push(x_xml[x].attributes.value);
                }
                trace(AbszisseTo);
                loadedMatrix();
                delete(tempXML);
            } else {
                trace("error");
            }
        }
    }
    
    private function loadedMatrix() {
        trace("loaded");
        trace(AbszisseTo);
    } 

das erste Trace funktioniert, aber er ruft "loadedMatrix" nicht auf. Wie kann ich das zurechtbiegen, ohne zum Beispiel alles in statischen Funktionen zu schreiben?

Die Referenzierung ist ja auch auf das XML objekt, und nicht mehr auf das erstellte Objekt. Wie komme ich zu diesem zurück?

danke für die Hilfe...



Edit: Habe es jetzt dadurch gelöst, dass meine Klasse ein extends XML hat und ich das onLoad innerhalb überschreibe und von dort aus eine private funktion aufrufe. So funktioniert es. Weshalb das andere nicht funktioniert bleibt mir ein Rätsel...