Falsche Position bei schnellem Click

[michey]

Hallo

Kann mir jemand sagen warum bei dieser Gallerie die Position der Bilder verschoben wird wenn zu schnell geclickt wird und ob es eine Möglichkeit gibt dies zu verhindern?

Danke.

michey

spacing = 10;
containerMC._alpha = 0;
var pArray = new Array();
var tArray = new Array();
MovieClip.prototype.loadPic = function(pic) {
    containerMC._alpha = 0;
    cur = pic;
    this.loadMovie(pArray[pic]);
    this._parent.onEnterFrame = function() {
        var t = containerMC.getBytesTotal(), l = containerMC.getBytesLoaded();
        bar._visible = 1;
        per = Math.round((l/t)*100);
        if (t != 0 && Math.round(l/t) == 1 && containerMC._width != 0) {
            var w = containerMC._width+spacing, h = containerMC._height+spacing;
            border.resizeMe(w, h, pic);
            bar._visible = 0;
            loadText.text = "";
            delete this.onEnterFrame; // falsch: delete this.onEnterFrame;
        } else {
            bar._width = per;
            // gives the bar a max width 100. För att få 250 px t.ex: bar._width = per*2.5;
            loadText.text = per+" % ";
        }
    };
};
MovieClip.prototype.resizeMe = function(w, h, pic) {
    var speed = 3;
    containerMC._xscale = containerMC._yscale = 0; // Skalierung auf 0% setzen.
    this.onEnterFrame = function() {
        this._width += (w-this._width)/speed;
        this._height += (h-this._height)/speed;
        nav._y = Math.round(border._y+border._height/2+10);
        prevb._x = nav._x-5;
        nextb._x = nav._x+this._width+5;
        nextb._y = prevb._y=this._y-this._height/2;
        picinfo._y = 70;
        picinfo.info.text = tArray[pic];
        picinfo._x = border._x-picinfo._width/2;
        if (Math.abs(this._width-w)<1 && Math.abs(this._height-h)<1) {
            this._width = w;
            this._height = h;
            containerMC._x = this._x-this._width/2+spacing/2;
            containerMC._y = this._y-this._height/2+spacing/2;
            containerMC._xscale = containerMC._yscale += 7; // container Skalieren
            containerMC._alpha += 7;
            if (containerMC._alpha>90 || containerMC._xscale >= 100) { // Bedingung erweitert
                containerMC._alpha = 100;
                containerMC._xscale = containerMC._yscale = 100;
                delete this.onEnterFrame;
            }
        }
    };
};
var gallery_xml = new XML();
gallery_xml.ignoreWhite = true;
gallery_xml.onLoad = function(success) {
    if (success) {
        var gallery = this.firstChild;
        for (var i = 0; i<gallery.childNodes.length; i++) {
            tArray.push(gallery.childNodes[i].attributes.title);
            pArray.push(gallery.childNodes[i].attributes.source);
        }
        //loading first picture
        containerMC.loadPic(0);
    } else {
        title_txt.text = "Error!";
    }
};
gallery_xml.load("gallery.xml");
prevb.onRelease = function() {
    if (cur == 0) {
        containerMC.loadPic(pArray.length-1);
    } else {
        containerMC.loadPic(cur-1);
    }
};
nextb.onRelease = function() {
    if (cur == pArray.length-1) {
        containerMC.loadPic(0);
    } else {
        containerMC.loadPic(cur+1);
    }
}; 

[michey]

Hat keiner eine Ahnung?
Dürfte doch wohl für einen alten Hasen keine Sache sein!

[Der Frager]

Hallo.
Hab dir noch eine Variable reingesetzt, die prüft, ob das vorherige Bild noch läd:

MovieClip.prototype.loadPic = function(pic) {
    if (!laden) { // [B]Gucken ob nicht geladen wird[/B]
        laden = true;
        containerMC._alpha = 0;
        cur = pic;
        this.loadMovie(pArray[pic]);
        this._parent.onEnterFrame = function() {
            var t = containerMC.getBytesTotal(), l = containerMC.getBytesLoaded();
            bar._visible = 1;
            per = Math.round((l/t)*100);
            if (t != 0 && Math.round(l/t) == 1 && containerMC._width != 0) {
                var w = containerMC._width+spacing, h = containerMC._height+spacing;
                border.resizeMe(w, h, pic);
                bar._visible = 0;
                loadText.text = "";
                delete this.onEnterFrame;
                // falsch: delete this.onEnterFrame;
            } else {
                bar._width = per;
                // gives the bar a max width 100. För att få 250 px t.ex: bar._width = per*2.5;
                loadText.text = per+" % ";
            }
        };
    }
};
MovieClip.prototype.resizeMe = function(w, h, pic) {
    var speed = 3;
    containerMC._xscale = containerMC._yscale=0;
    // Skalierung auf 0% setzen.
    this.onEnterFrame = function() {
        this._width += (w-this._width)/speed;
        this._height += (h-this._height)/speed;
        nav._y = Math.round(border._y+border._height/2+10);
        prevb._x = nav._x-5;
        nextb._x = nav._x+this._width+5;
        nextb._y = prevb._y=this._y-this._height/2;
        picinfo._y = 70;
        picinfo.info.text = tArray[pic];
        picinfo._x = border._x-picinfo._width/2;
        if (Math.abs(this._width-w)<1 && Math.abs(this._height-h)<1) {
            this._width = w;
            this._height = h;
            containerMC._x = this._x-this._width/2+spacing/2;
            containerMC._y = this._y-this._height/2+spacing/2;
            containerMC._xscale = containerMC._yscale += 7;
            // container Skalieren
            containerMC._alpha += 7;
            if (containerMC._alpha>90 || containerMC._xscale>=100) {
                // Bedingung erweitert
                containerMC._alpha = 100;
                containerMC._xscale = containerMC._yscale=100;
                delete this.onEnterFrame;
                laden = false; // [B]Hier ist's dann geladen[/B]
            }
        }
    };
}; 

[michey]

Danke Frager!
Hat der Bug also damit zu tun dass bei schnellem clicken irgendwie von einer
Zwischenposition(vom ersten Click) ausgegangen wird um das neue Bild zu laden beim zweiten zu schnellen Click?

michey

[Der Frager]

Denke ich mal... Habe mir jetzt nicht das ganze Script durchgelesen.