externe bilder per Xml einlesen: onrelease problem

[rohrspecht]

hallo zusammen,

ich habe sehr lange und ausgiebig die suchfunktion benutzt und bin nicht fündig geworden.

ich lade mir per xml einen "bilderstreifen", also einzelne kleine bilder, die in einer reihe in einem container plaziert sind.
wenn man auf eins der bilder klickt, soll irgendwas passieren. in meinem fall soll die schöne webseite google.de aufgerufen werden.

irgendwie scheint aber folgendes nicht zu funktionieren:

PHP-Code:

            _root.container["bild"+i].onRelease = function() {
                _root.container["bild"+i].getURL("http://www.google.de", "_self");
            }; 


liegt das daran, dass die ganze chose in einer onLoad-funktion steckt?
oder dass die einzelnen "bild"+i-movieclips keine explizite breite haben?


hier nochmal der ganze quelltext:

PHP-Code:

stop();
// Allgemeine Variablen initialisieren
_root.cbreite = 0;
_root.scrollbalkenabstand = 0;
var XMLbildlader = new XML();
// Leerzeichen ignorieren
XMLbildlader.ignoreWhite = true;
XMLbildlader.load("xml/bildlader.xml");
XMLbildlader.onLoad = function(funktioniert) {
    if (funktioniert) {
        // Hauptvariablen holen
        abstand = parseFloat(XMLbildlader.firstChild.attributes.bilderabstand);
        _root.scrollbalkenabstand = parseFloat(XMLbildlader.firstChild.attributes.scrollbalkenabstand);
        breite = abstand;
        // Einzelne Unterknoten abklappern
        for (i=0; i<XMLbildlader.firstChild.childNodes.length; i++) {
            _root.container.createEmptyMovieClip(("bild"+i), (10+i));
            _root.container["bild"+i]._x = breite;
            _root.container["bild"+i]._y = abstand;
            _root.container["bild"+i].loadMovie(XMLbildlader.firstChild.childNodes[i].attributes.pfad);
            _root.container["bild"+i].onRelease = function() {
                _root.container["bild"+i].getURL("http://www.google.de", "_self");
            };
            // Aktuelle Breite des Containers hochsetzen
            breite = parseFloat(XMLbildlader.firstChild.childNodes[i].attributes.breite)+parseFloat(abstand)+parseFloat(breite);
            _root.cbreite = breite;
        }
    }
}; 


die xml-datei sieht so aus:

PHP-Code:

<?xml version="1.0" encoding="utf-8"?>
<bildlader bilderabstand="20" scrollbalkenabstand="150">
    <bild pfad="img/01.jpg" breite="80" hoehe="80" />
    <bild pfad="img/02.jpg" breite="80" hoehe="80" />
    <bild pfad="img/03.jpg" breite="80" hoehe="80" />
    <bild pfad="img/04.jpg" breite="80" hoehe="80" />
    <bild pfad="img/05.jpg" breite="80" hoehe="80" />
    <bild pfad="img/06.jpg" breite="80" hoehe="80" />
    <bild pfad="img/07.jpg" breite="80" hoehe="80" />
    <bild pfad="img/08.jpg" breite="80" hoehe="80" />
</bildlader>

vielen dank im voraus,

christian

[bloba]

zum bilder anladen brauchst du loadMovie, ggfls die Moviecliploader klasse, aber nicht getUrl

[rohrspecht]

hallo,

danke für die schnelle antwort.
die kleinen thumbnails lade ich mit

PHP-Code:

 _root.container["bild"+i].loadMovie(XMLbildlader.firstChild.childNodes[i].attributes.pfad); 


mit dem getUrl probiere ich nur aus, ob das mit dem onRelease funktioniert, was ja leider nicht der fall ist.

[Omega Psi]

Die onRelease Funktioniert nicht, weil du sie initialisierst bevor das bIld komplett geladen ist. Du musst:

1. XML laden
2. XML Verarbeiten (Beispielsweise Pfade auslesen und speichern)
3. Die Bilder dann mit loadMovie oder MovieClipLoader.loadClip laden
4. Dann formatieren udn Listener zuweisen.

Am besten nutzt du den MovieClipLoader, weil du dann nur den onLoadInit Event abwarten musst.

Alternativ könntest du auch noch einen weiteren MovieClip zur Verschachtelung hinzuziehen und dann auf den oberen den Listener legen und in den inneren das Bild laden.

[rohrspecht]

danke für die antwort.
ich habe es erstmal ohne den moviecliploader probiert, obwohl das sicherlich eine bessere lösung ist und ich diese auf jeden fall implimentieren werde.

allerdings bin ich der meinung, dass es so auch funktionieren sollte:

PHP-Code:

stop();
// Allgemeine Variablen initialisieren
_root.cbreite = 0;
_root.scrollbalkenabstand = 0;
_root.bilder_anzahl = 0;
_root.bilder_breite = [];
var XMLbildlader = new XML();
// Leerzeichen ignorieren
XMLbildlader.ignoreWhite = true;
XMLbildlader.load("xml/bildlader.xml");
XMLbildlader.onLoad = function(funktioniert) {
    if (funktioniert) {
        // Hauptvariablen holen
        abstand = parseFloat(XMLbildlader.firstChild.attributes.bilderabstand);
        _root.scrollbalkenabstand = parseFloat(XMLbildlader.firstChild.attributes.scrollbalkenabstand);
        breite = abstand;
        // Einzelne Unterknoten abklappern
        for (i=0; i<XMLbildlader.firstChild.childNodes.length; i++) {
            _root.container.createEmptyMovieClip(("bild"+i), (10+i));
            _root.container["bild"+i].createEmptyMovieClip("holder", 35);
            _root.container["bild"+i]._x = breite;
            _root.container["bild"+i]._y = abstand;
            _root.container["bild"+i].onPress = function() {
                getURL(XMLbildlader.firstChild.childNodes[i].attributes.adresse);
            };
            _root.container["bild"+i].holder.loadMovie(XMLbildlader.firstChild.childNodes[i].attributes.pfad);
            // Aktuelle Breite des Containers hochsetzen
            breite = parseFloat(XMLbildlader.firstChild.childNodes[i].attributes.breite)+parseFloat(abstand)+parseFloat(breite);
            _root.cbreite = breite;
        }
    }
}; 


ich lade das bild jetzt in einen extra holder-movieclip.

jetzt habe ich leider das problem, dass er

PHP-Code:

XMLbildlader.firstChild.childNodes[i].attributes.adresse 


diesen wert nicht zu mögen scheint. wenn ich aus

PHP-Code:

_root.container["bild"+i].onPress = function() {
                getURL(XMLbildlader.firstChild.childNodes[i].attributes.adresse);
            }; 


ein

PHP-Code:

_root.container["bild"+i].onPress = function() {
                getURL("http://www.google.de");
            }; 


mache, klappts. wo hakts denn jetzt???


edit:
hier noch meine xml-datei:

PHP-Code:

<?xml version="1.0" encoding="utf-8"?>
<bildlader bilderabstand="20" scrollbalkenabstand="150">
    <bild pfad="img/01.jpg" breite="80" hoehe="80" adresse="http://www.google.de" ziel ="_blank" />
    <bild pfad="img/02.jpg" breite="80" hoehe="80" adresse="http://www.heise.de" ziel ="_blank" />
    <bild pfad="img/03.jpg" breite="80" hoehe="80" adresse="http://www.apple.de" ziel ="_blank" />
    <bild pfad="img/04.jpg" breite="80" hoehe="80" adresse="http://www.google.de" ziel ="_blank" />
    <bild pfad="img/05.jpg" breite="80" hoehe="80" adresse="http://www.heise.de" ziel ="_blank" />
    <bild pfad="img/06.jpg" breite="80" hoehe="80" adresse="http://www.apple.de" ziel ="_blank" />
    <bild pfad="img/07.jpg" breite="80" hoehe="80" adresse="http://www.google.de" ziel ="_blank" />
    <bild pfad="img/08.jpg" breite="80" hoehe="80" adresse="http://www.heise.de" ziel ="_blank" />
</bildlader>

[readme.txt]

Der Fehler liegt jetzt offensichtlich woanders (du hast, bewusst oder unbewusst, einen der Workarounds deiner ursprünglichen Problematik gefunden).

Ein Grundproblem das du schonmal hast ist, dass du in dem onPress (übrigens würde ich für Schaltflächen an deiner stelle eher onRelease verwenden) i benutzt.

die for-Schleife ist an der Stelle aber immer schon komplett durchgelaufen was nix anderes Bedeutet als das i immer den maximalen Wert haben wird.

Das lässt sich wie folgt umgehen:

PHP-Code:

for (i=0; i<XMLbildlader.firstChild.childNodes.length; i++) {
  var mc:MovieClip = _root.container.createEmptyMovieClip(("bild"+i), (10+i));          
  var holder:MovieClip = mc.createEmptyMovieClip("holder", 35);
            
  mc.id  = i;
  mc._x = breite;
  mc._y = abstand;
  
  mc.onPress = function() {
    getURL(XMLbildlader.firstChild.childNodes[this.id].attributes.adresse);
  };
                
  holder.loadMovie(XMLbildlader.firstChild.childNodes[i].attributes.pfad);
    breite = parseFloat(XMLbildlader.firstChild.childNodes[i].attributes.breite)+parseFloat(abstand)+parseFloat(breite);
            _root.cbreite = breite;
} 


Das mit mc ist nur ein Tip, damit sparst du dir Schreibarbeit. In dem onPress versuch mal einen Trace zu setzen (ausgegangen davon das du offline Testest):

PHP-Code:

  mc.onPress = function() {
    trace(XMLbildlader.firstChild.childNodes[this.id].attributes.adresse);
    getURL(XMLbildlader.firstChild.childNodes[this.id].attributes.adresse);
  }; 


Was gibt dir das denn aus? undefined?