onRelease funktioniert nicht

[shoper]

XML daten werden ausgelesen, jpg-Bilder richtig in "ibildclip" (Movieclip aus der Bibliothek) geladen jetzt möchte ich aber die Bilder als Links zur externe Seiten verlinken was aber leider nicht funktioniert. Mit "onPress" funkt auch nicht. Also keine Reaktion auf Klicks.
Kann mit bitte jemand sagen wo ich dabei Fehler mache.

PHP-Code:

for (var i=0; i<anzahl; i++){
    
    mc_bild = _root.attachMovie("ibildclip", "ibild" + i, i);
    mc_bild.loadMovie (image[i],"ibildclip");
    breite = parseFloat(breit[i]);
    mc_bild._x=(240-breite)/2;
    mc_bild._y= i*220+30;
    mc_bild.onRelease = function() {
         trace("onRelease");
    
    } 


Danke

Du kannst erst einen onRelease-Event setzen, wenn das Bild auch nachgeladen ist. Dazu benötigst du einen Preloader, bspw. statt eines loadMovie lädst du mit der MovieClipLoader-Klasse nach und im onLoadInit-Event des MovieClipLoaders setzt du den onRelease-Event.

Dazu empfehle ich dir aber, die Bilder nacheinander und nicht gleichzeitig zu laden.

[shoper]

Zitat von agedoubleju

Du kannst erst einen onRelease-Event setzen, wenn das Bild auch nachgeladen ist. Dazu benötigst du einen Preloader, bspw. statt eines loadMovie lädst du mit der MovieClipLoader-Klasse nach und im onLoadInit-Event des MovieClipLoaders setzt du den onRelease-Event.

Dazu empfehle ich dir aber, die Bilder nacheinander und nicht gleichzeitig zu laden.

Danke für deine Antwort.
Ich habe mit Flash nicht soviel Erfahrung. Wie soll man so was umsetzen? ich erwarte nicht kompletten Code aber für ein paar Schritte wäre ich dankbar.

Ok, hier hast du einen Ansatz:

PHP-Code:

//Zähler
var index:Number = 0;

//Liste der Bilder
var urls:Array = new Array("bild1.jpg", "bild2.jpg","bild3.jpg");

//Liste der MCs
var mcs:Array = new Array();
var len:Number = urls.length;

//leere MCs erzeugen
for(var i=1;i<=len;i++){
   this.mcs.push(this.createEmptyMovieClip("con"+i,i));
   this["con"+i]._x = (i*100);//evtl. positionieren
}

//erstes Bild laden
var mclListener:Object = new Object();
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(mclListener);
mcLoader.loadClip(urls[index], mcs[index]);


//während des Ladens bspw. um Ladebalken o.ä. zu aktualisieren
mclListener.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void {
    trace(target + ".onLoadProgress with " + bytesLoaded + " bytes of " + bytesTotal);
    var prozent = bytesLoaded*100/bytesTotal;
   _root.meineTextfeldinstanz.text = ""+prozent+" %"; 
}


//fertiggeladen
mclListener.onLoadInit = function(mc:MovieClip) {
   
   //jetzt den onRelease-Event setzen:
   mc.onRelease = function(){
      trace("Klick, this="+this);
   }

   index++;
   if (index < len) {//sind noch weitere zu laden?
       mcLoader.loadClip(urls[index], mcs[index]);
   }
}

this.stop();