Video im loop rückwärz laufen lassen

[ZKdesign]

Hallo Zusammen,

bin ein Flash Anfänger und habe folgendes Problem.
Ich soll für eine Firma ein Rotations Objekt als Flash-
Movie erstellen. Das heißt ich habe z.B. einen Würfel
in Rotation gerendert. So, nun ist es kein Problem den
Würfel per Buttons drehen zu lassen. Das heiß wenn
ich auf den vorwärz button klicke spielt er das Movie
im Loop vorwärz ab. Soweit so gut, nur sobald ich es
Rückwärz laufen lassen will, geschieht das nicht im loop
sondern bleibt nach einer Umdrehung stehen.

Deswegen zeig ich hier mal nur das Script für den Rück-
wärz Button an:
------------------------------------------------------------------
on (press) {
this.onEnterFrame = function() {
if (this._parent.socke._parent._currentframe>1) {
this._parent.socke._parent.gotoAndPlay(this._paren t.socke._parent._currentframe-2);
}
};
this.onRelease = function() {
delete this.onEnterFrame;
};
}
on (release) {
this._parent.socke._parent.stop();
}
--------------------------------------------------------------------

Wäre froh wenn Jemand eine Antwort weiß!
Danke im Vorraus.

mfg
Zkdesign

[Decrone]

Willkommen

kannst ja mal schauen ob du damit klar kommst?

PHP-Code:

_global.speed = 2
mc_Film.stop();
mc_Button_prev.onPress = function(){
    this.onEnterFrame = function() {
        trace(this._parent.mc_Film._currentframe);
        if (this._parent.mc_Film._currentframe>speed) {
            this._parent.mc_Film.gotoAndStop(this._parent.mc_Film._currentframe-speed);
        }else{
            this._parent.mc_Film.gotoAndStop(this._parent.mc_Film._totalframes);
        }
    }
};
mc_Button_prev.onRelease = function(){
    delete this.onEnterFrame;
}
    
mc_Button_next.onPress = function(){
    this.onEnterFrame = function() {
        trace(this._parent.mc_Film._currentframe);
        if (this._parent.mc_Film._currentframe<this._parent.mc_Film._totalframes) {
            this._parent.mc_Film.gotoAndStop(this._parent.mc_Film._currentframe+speed);
        }else{
            this._parent.mc_Film.gotoAndStop(1);
        }
    }
};
mc_Button_next.onRelease = function(){
    delete this.onEnterFrame;
} 


Siehe Anhang...

Gruss Dec

[ZKdesign]

Hi Decrone,

danke erstmal für deine Hilfe.
Ich hab mir dein ZIP runtergeladen und
mir die Szene angeschaut. Leider hat es bei
meinem Projekt nicht viel genützt. Ich denke
das liegt daran das Du bei dir ein Bewegungs-
tween als Movie hast und ich ein *.flv Film habe.
Weiß jetzt nicht wirklich ob das der Grund ist.
Wie gesagt das Problem ist, das der Film
nicht durchläuft, also im loop. Egal ob vor-
wärz oder rückwärz.
Ich hab dir jetzt auch mal meine Szene
gezippt. Wenn es geht kannst Du Sie dir mal an-
schauen, um zu sehen was ich meine.
Falls du auch nicht weiter weißt kannst du mir
vielleicht sagen an wen ich mich da wenden kann.
Dankeschön....


mfg
Zkdesign

[Decrone]

wenn möglich, speichere mal in FlashMX ab. Hab hier leider kein Flash MX2004!

Gruss Dec

Schau mal in dieses Tutorial.

[ZKdesign]

Hallo zusammen,

danke nochmal für die Tips. Aber
leider hats noch nicht so geklappt.
Ich weiß auch nicht so wirklich woran
es liegt. Hab jetzt mal die Datei als
"Flash Mx" und nicht als "Flash MX 2004"
abgespeichert.
Wäre echt nett wenn ihr euch das mal
anschaut, weil das Problem zu beschreiben
ist nicht so einfach
Ich warte schon ungeduldig, bzw. mein Chef
Danke.....


grüße
Zkdesin

[Decrone]

ich hab Dir eigentlich alles schon auf dem Weg mitgegeben aber schade das du es nicht umsetzen konntest. Ich hoffe du versuchst zu verstehen wieso, weshalb, warum!

Das du mit dem Tipp von @agedoubleju auch nichts anfangen konnstest, ist mir jetzt auch klar...es ist das gleiche Prinzip wie bei meinem Beispiel.

Schau mal im Anhang, dann hoffe ich wirst Du verstehen und wenn nicht ...na dann bis demnächst!

Gruss Dec

[.:morpher:.]

btw: vorwärts und rückwärts

[Decrone]

Änderung/Ergänzung:

PHP-Code:

mc_Button_prev.onRelease = mc_Button_prev.onReleaseOutside = function(){ 
    delete this.onEnterFrame; 
} 
//und
mc_Button_next.onRelease = mc_Button_next.onReleaseOutside = function(){ 
    delete this.onEnterFrame; 
} 


Gruss dec

[ZKdesign]

Hallo miteinander,

danke nochmals für eure Hilfe. Werd mir das Script mal
genauer anschauen um es zu verstehen. Was mir
aufgefallen ist, das Decrone z.B. das Script seperat in einer
Ebene geschrieben hast. Nun frag ich mich ob das
irgendwelche Vorteile mit sich bringt wie z.B. Ge-
schwindigkeit oder etwas anderes?

Ok, dann bis demnächst Leute.

grüße
Zkdesign

P.S.: schön gemachte Seite von Morpher. Und der Spruch über die
Brit & Chris ist cool

[Decrone]

Zitat von ZKdesign

Was mir
aufgefallen ist, das Decrone z.B. das Script seperat in einer
Ebene geschrieben hast. Nun frag ich mich ob das
irgendwelche Vorteile mit sich bringt wie z.B. Ge-
schwindigkeit oder etwas anderes?

Ob dein Script davon schneller wird, hängt von dem Aufbau deines Scriptes ab. In erster Linie liegt dein Script nicht verstreut in irgendwelche MC's rum. Ist halt alles übersichtlicher!

Hier noch mal ne andere Variante:

PHP-Code:

mc_Film.stop(); 
MovieClip.prototype.prev = function (speed){
    this.onEnterFrame = function() {
        this._currentframe>speed ? this.gotoAndStop(this._currentframe-speed) : this.gotoAndStop(this._totalframes);
    }
}
MovieClip.prototype.next = function (speed){
    this.onEnterFrame = function() {
        this._currentframe<this._totalframes ? this.gotoAndStop(this._currentframe+speed) : this.gotoAndStop(1); 
    }
}
mc_Button_prev.onPress = function(){ 
    this._parent.mc_Film.prev(2);
}; 
mc_Button_prev.onRelease = mc_Button_prev.onReleaseOutside = function(){  
    delete this._parent.mc_Film.onEnterFrame;  
}  
     
mc_Button_next.onPress = function(){ 
    this._parent.mc_Film.next(2);
}; 
mc_Button_next.onRelease = mc_Button_next.onReleaseOutside = function(){  
    delete this._parent.mc_Film.onEnterFrame;  
} 


Gruss Dec