[Flash CS4] Überprüfung einer Funktion

[cosmoses]

Hallo zusammen,

habe folgende Funktion:

function irgendeinefunktion():void {
	test();
trace("weiter");
}

nun hätte ich gern das trace erst ausgeführt wird, wenn test() (bzw. die Programmierung in der Funktion) komplett ausgeführt wurde.

Wie stelle ich das an?

Danke

[~pyropete~]

Gegenfrage: was genau hast Du vor?

Welche AS-Version? 3.0 oder?

[thomas_E]

so, und nur so, arbeitet flash. was lässt dich annehmen, dass es anders sei?
und was steht in test?

wenn ich raten müsste, wurde ich vermuten, dass du Events noch nicht verstanden hast.

[~pyropete~]

Wenn Du irgendwo asynchrone Abläufe hast (externe Inhalte laden), kannst Du
den Ablauf durch die jew. Callback-Funktionen (z.B. MovieClipLoader.onLoadInit usw.)
beeinflussen.

Zitat von thomas_E

wenn ich raten müsste, wurde ich vermuten, dass du Events noch nicht verstanden hast.

Im obigen Fall arbeitet Flash sowieso alles nacheinander ab (erst alles was in test steht, dann
den trace).

Von daher muss er Events erstmal nicht kennen ...

[cosmoses]

Ich arbeite mit as3.
Ein Button ruft test auf, wo eine xml geladen und anschließend pro XML-Knoten ein Textfeld erstellt wird. Wenn man den Button wieder betätigt wird, wird innerhalb test überprüft ob die Textfelder schon erstellt wurden, so wird ein wiederholtes Laden der XML verhindert.

Zudem habe ich einen Tween den ich ausführen möchte, sobald alle Textfelder erstellt wurden (im Beispiel vorher habe ich es durch das trace ersetzt). Ich kann den Tween leider nicht an das Ende von test setzten, da ich diesen Tween auch ausführen möchte, wenn die Textfelder schon Existieren.

also im Ganzen würde es ca. so aussehen:

function clickHandler(evt:MouseEvent):void {
	loadXML("datei.xml");

	if(----wenn die xml geladen wurde oder die Textfelder schon existieren ----)
	var mcTween:Tween = new Tween(mc, "x", Strong.easeOut, mc.x, 0, 2, true);
}
function loadXML(Uri:String):void {
	if(!mc.getChildByName(mc2)) {
---- xml wird geladen und Textfelder erstellt ----
	}}

[thomas_E]

also, das laden von externen Dateien läuft asynchron ab:
du sagst dem Loader, dass er laden soll, der leiert das an, und der Code läuft weiter (bis zu deinem trace).
Irgendwann (oder auch nie) feuert der ein Event.COMPLETE, und gibt damit an, dass die Daten jetzt da sind, und abgeholt werden können.
wenn der Loader synchron laufen würde, würde diene komplette Anwendung einfrieren, bis die Datei fertig geladen wurde, und wenn die Datei nicht erfolgreich geladen wurde hättest du an der Stelle ein Problem, da dein code weiter wartet. (und nichtmal versucht die Datei neu zu laden)

also, ein grundsätzlicher Aufbau für deinen Code:
(nur eine mögliche Variante)

PHP-Code:

var xmlLoader:URLLoader;
var mc:Sprite;
function clickHandler(e:MouseEvent):void
{
    if(mc)
        effekt();
    else if(!xmlLoader)
        loadXML();
}

function loadXML():void
{
    //starte das Laden der XML-Datei
    xmlLoader = new URLLoader();
    xmlLoader.addEventListener(Event.COMPLETE, onXMLLoaded);
    xmlLoader.load(new URLRequest("datei.xml"));
}

function onXMLLoaded(e:Event):void
{
    //die XML-Datei wurde geladen
    mc = new Sprite();    //ein Sprite reicht hier vollkommen aus
    //create Buttons;    
    //pipapo
    
    effekt();
    
    //aufräumen nicht vergessen:
    xmlLoader.removeEventListener(Event.COMPLETE, onXMLLoaded);
    xmlLoader = null;
}

function effekt():void
{
    new Tween(mc, "x", Strong.easeOut, mc.x, 0, 2, true);
} 


Hier dienen die Variablen xmlLoader auch dazu um anzuzeigen, ob das laden der xml-Datei bereits begonnen hat (nützt ja auch nix die mehrmals paralell runterzuladen, nur weil der User wie ein Irrer auf dem Button rumklickt)


Und mc zeigt auch gleichzeitig an, ob das laden bereits abgeschlossen wurde, und etwas zum Tweenen da ist.

Noch eine Anmerkung: die Flash-eigene Tweening-Klasse ist nicht so dolle. also wenn du paar mehr Tweens verwendest, solltest du dich nach einer Alternative umsehen.
Am verbreitetsten sind TweenLite, Caurina Tweener und Tweensy; aber dazu gibbet eigentlich genügend Beiträge hier im Forum

[cosmoses]

Danke, so wollt ichs